I_CFinAAPurchasingPosting

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'CFinAA Purchasing Posting'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XXL,
  dataClass: #TRANSACTIONAL
}
define view entity I_CFinAAPurchasingPosting
  as select distinct from I_CFinAAAcqnIntegrationPosting
    inner join            I_JournalEntry on  I_JournalEntry.ReferenceDocumentType          = I_CFinAAAcqnIntegrationPosting.ReferenceDocumentType
                                         and I_JournalEntry.OriginalReferenceDocument      = I_CFinAAAcqnIntegrationPosting.OriginalReferenceDocument
                                         and I_JournalEntry.ReferenceDocumentLogicalSystem = I_CFinAAAcqnIntegrationPosting.ReferenceDocumentLogicalSystem

  association [0..1] to I_CompanyCode                as _CompanyCode                on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_ReferenceDocumentTypeText  as _ReferenceDocumentTypeText  on  $projection.ReferenceDocumentType   = _ReferenceDocumentTypeText.ReferenceDocumentType
                                                                                    and _ReferenceDocumentTypeText.Language = $session.system_language
  association [0..1] to I_LedgerGroupText            as _LedgerGroupText            on  $projection.LedgerGroup   = _LedgerGroupText.LedgerGroup
                                                                                    and _LedgerGroupText.Language = $session.system_language
  association [0..1] to I_AccountingDocumentTypeText as _AccountingDocumentTypeText on  $projection.AccountingDocumentType   = _AccountingDocumentTypeText.AccountingDocumentType
                                                                                    and _AccountingDocumentTypeText.Language = $session.system_language
{

  key cast( I_JournalEntry.CompanyCode as fis_bukrs preserving type )           as CompanyCode,
  key I_JournalEntry.AccountingDocument,
  key I_JournalEntry.FiscalYear,
  key cast( I_JournalEntry.ReferenceDocumentType as awtyp preserving type )     as ReferenceDocumentType,
  key cast( I_JournalEntry.OriginalReferenceDocument as awkey preserving type ) as OriginalReferenceDocument,
  key I_JournalEntry.ReferenceDocumentLogicalSystem,
  key I_CFinAAAcqnIntegrationPosting.PurchasingDocument,
  key I_CFinAAAcqnIntegrationPosting.PurchasingDocumentItem,
      /* start suppress warning shlporigin_not_inherited */
      I_JournalEntry.AccountingDocumentType,
      I_JournalEntry.LedgerGroup,
      /* end suppress warning shlporigin_not_inherited */
      I_JournalEntry.AccountingDocumentClass,
      I_JournalEntry.ReverseDocument,
      I_JournalEntry.ReverseDocumentFiscalYear,
      I_JournalEntry.IsReversed,
      I_JournalEntry.IsReversal,
      I_JournalEntry.SenderLogicalSystem,
      I_JournalEntry.SenderCompanyCode,
      I_JournalEntry.SenderAccountingDocument,
      I_JournalEntry.SenderFiscalYear,
      I_CFinAAAcqnIntegrationPosting.MasterFixedAsset,
      I_CFinAAAcqnIntegrationPosting.FixedAsset,
      I_CFinAAAcqnIntegrationPosting.FiscalPeriod,
      I_CFinAAAcqnIntegrationPosting.DocumentDate,
      I_CFinAAAcqnIntegrationPosting.PostingDate,

      _CompanyCode,
      _ReferenceDocumentTypeText,
      _LedgerGroupText,
      _AccountingDocumentTypeText
}
where
     I_JournalEntry.JournalEntryReprocessingStatus = ''
  or I_JournalEntry.JournalEntryReprocessingStatus = '3'