I_CFinAAPurchasingItemPosting

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'CFinAA Purchasing Item Posting'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #XXL,
  dataClass: #TRANSACTIONAL
}
define view entity I_CFinAAPurchasingItemPosting
  as select distinct from I_CFinAAPurchasingValidItem
    inner join(
                          I_OperationalAcctgDocItem
        inner join        I_JournalEntry on  I_JournalEntry.ReferenceDocumentType            = I_OperationalAcctgDocItem.ReferenceDocumentType
                                         and I_JournalEntry.OriginalReferenceDocument        = I_OperationalAcctgDocItem.OriginalReferenceDocument
                                         and I_JournalEntry.ReferenceDocumentLogicalSystem   = I_OperationalAcctgDocItem.ReferenceDocumentLogicalSystem
                                         and (
                                            I_JournalEntry.JournalEntryReprocessingStatus    = ''
                                            or I_JournalEntry.JournalEntryReprocessingStatus = '3'
                                          )
    )
    on  I_CFinAAPurchasingValidItem.SenderLogicalSystem            = I_OperationalAcctgDocItem.ReferenceDocumentLogicalSystem
    and I_CFinAAPurchasingValidItem.CFinRpldPurchasingDocument     = I_OperationalAcctgDocItem.PurchasingDocument
    and I_CFinAAPurchasingValidItem.CFinRpldPurchasingDocumentItem = I_OperationalAcctgDocItem.PurchasingDocumentItem

  association [0..1] to I_CompanyCode                as _CompanyCode                on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_ReferenceDocumentTypeText  as _ReferenceDocumentTypeText  on  $projection.ReferenceDocumentType   = _ReferenceDocumentTypeText.ReferenceDocumentType
                                                                                    and _ReferenceDocumentTypeText.Language = $session.system_language
  association [0..1] to I_LedgerGroupText            as _LedgerGroupText            on  $projection.LedgerGroup   = _LedgerGroupText.LedgerGroup
                                                                                    and _LedgerGroupText.Language = $session.system_language
  association [0..1] to I_AccountingDocumentTypeText as _AccountingDocumentTypeText on  $projection.AccountingDocumentType   = _AccountingDocumentTypeText.AccountingDocumentType
                                                                                    and _AccountingDocumentTypeText.Language = $session.system_language
{
  key I_CFinAAPurchasingValidItem.SenderLogicalSystem,
  key I_CFinAAPurchasingValidItem.CFinRpldPurchasingDocument,
  key I_CFinAAPurchasingValidItem.CFinRpldPurchasingDocumentItem,
      /* start suppress warning shlporigin_not_inherited */
  key I_JournalEntry.CompanyCode,
      /* end suppress warning shlporigin_not_inherited */
  key I_JournalEntry.FiscalYear,
  key I_JournalEntry.AccountingDocument,
      I_JournalEntry.FiscalPeriod,
      I_JournalEntry.DocumentDate,
      I_JournalEntry.PostingDate,
      /* start suppress warning shlporigin_not_inherited */
      I_JournalEntry.AccountingDocumentType,
      I_JournalEntry.LedgerGroup,
      /* end suppress warning shlporigin_not_inherited */
      cast( I_JournalEntry.ReferenceDocumentType as awtyp preserving type )     as ReferenceDocumentType,
      cast( I_JournalEntry.OriginalReferenceDocument as awkey preserving type ) as OriginalReferenceDocument,
      I_JournalEntry.ReferenceDocumentLogicalSystem,
      I_JournalEntry.AccountingDocumentClass,
      I_JournalEntry.ReverseDocument,
      I_JournalEntry.ReverseDocumentFiscalYear,
      I_JournalEntry.IsReversed,
      I_JournalEntry.IsReversal,
      I_JournalEntry.SenderCompanyCode,
      I_JournalEntry.SenderAccountingDocument,
      I_JournalEntry.SenderFiscalYear,
      I_CFinAAPurchasingValidItem.CFinAAPurchasingValidItemUUID,
      I_CFinAAPurchasingValidItem.CFinAAManagedAssetUUID,
      I_CFinAAPurchasingValidItem.CFinAAPurchasingItemStatus,
      I_CFinAAPurchasingValidItem.MaterialGroup,
      I_CFinAAPurchasingValidItem.AccountAssignmentCategory,
      I_CFinAAPurchasingValidItem.CFinAAAssetCompanyCode,
      I_CFinAAPurchasingValidItem.CFinAAPurgConfignIsConsistent,
      I_CFinAAPurchasingValidItem.MasterFixedAsset,
      I_CFinAAPurchasingValidItem.FixedAsset,
      I_CFinAAPurchasingValidItem.CFinAAHasAssetCreationMessage,
      I_CFinAAPurchasingValidItem.CFinAAHasAssetPostingMessage,
      I_CFinAAPurchasingValidItem.CFinAAHasPurgItemUpdateMessage,

      _CompanyCode,
      _ReferenceDocumentTypeText,
      _LedgerGroupText,
      _AccountingDocumentTypeText
}