I_FIXEDASSETTRANSACTION
Asset Transactions
I_FIXEDASSETTRANSACTION is a CDS View in S/4HANA. Asset Transactions. It contains 2 fields. 12 CDS views read from this table.
CDS Views using this table (12)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_FixedAssetTransaction | view_entity | from | CONSUMPTION | Asset Transactions |
| I_AssetTransactionStatisticOvw | view | from | COMPOSITE | Asset Statistics Overview |
| I_AssetTransactionStatisticOvw | view | union | COMPOSITE | Asset Statistics Overview |
| I_AstAcqnAndRtrmtOverview | view | from | COMPOSITE | Asset Acquisitions and Retirements Overview |
| I_SG_BalanceAdjustmentCube | view | from | COMPOSITE | Singapore Balance Adjustment Report - Cube |
| I_TH_AssetDisposalCube | view | from | COMPOSITE | Thailand: Disposal List Cube |
| I_TH_AssetDisposalLog | view | from | COMPOSITE | Thailand Asset： Disposal List Log |
| P_AstUndrConstructionAging | view | from | COMPOSITE | |
| P_CN_CADEAssetRetirement | view | from | CONSUMPTION | |
| P_FixedAssetTransactionAging | view | from | COMPOSITE | |
| P_FixedAssetTransactionOvw | view | from | COMPOSITE | |
| P_FxdAstUndrConstrAcqDates | view | from | COMPOSITE |
Fields (2)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | CompanyCode | CompanyCode | 1 |
| KEY | Ledger | Ledger | 1 |
@EndUserText.label: 'Asset Transactions'
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: { usageType.serviceQuality: #C,
usageType.sizeCategory: #XXL,
usageType.dataClass: #MIXED }
@Metadata: {ignorePropagatedAnnotations: true}
define view entity I_FixedAssetTransaction
with parameters
@Consumption.hidden: true
@Environment.systemField: #SYSTEM_DATE
P_KeyDate : fagl_keydate,
P_AssetAccountingKeyFigureSet : faa_key_figure_set
as select from P_FixedAssetTransaction1(P_AssetAccountingKeyFigureSet: $parameters.P_AssetAccountingKeyFigureSet)
association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_DepreciationAreaForLedger as _DepreciationArea on $projection.CompanyCode = _DepreciationArea.CompanyCode
and $projection.Ledger = _DepreciationArea.Ledger
and $projection.AssetDepreciationArea = _DepreciationArea.AssetDepreciationArea
association [0..1] to I_MasterFixedAsset as _MasterFixedAsset on $projection.CompanyCode = _MasterFixedAsset.CompanyCode
and $projection.MasterFixedAsset = _MasterFixedAsset.MasterFixedAsset
association [0..1] to I_FixedAsset as _FixedAsset on $projection.CompanyCode = _FixedAsset.CompanyCode
and $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset
and $projection.FixedAsset = _FixedAsset.FixedAsset
association [0..1] to I_FiscalYearForCompanyCode as _FiscalYear on $projection.FiscalYear = _FiscalYear.FiscalYear
and $projection.CompanyCode = _FiscalYear.CompanyCode
association [0..1] to I_SubLedgerAccLineItemType as _SubLedgerAccLineItemType on $projection.SubLedgerAcctLineItemType = _SubLedgerAccLineItemType.SubLedgerAcctLineItemType
association [0..1] to I_MovementCategory as _AssetAcctTransClassfctn on $projection.AssetAcctTransClassfctn = _AssetAcctTransClassfctn.AssetAcctTransClassfctn
association [0..1] to I_LedgerGroup as _LedgerGroup on $projection.LedgerGroup = _LedgerGroup.LedgerGroup
association [0..1] to I_ChartOfDepreciation as _ChartOfDepreciation on $projection.ChartOfDepreciation = _ChartOfDepreciation.ChartOfDepreciation
association [1] to I_DebitCreditCode as _DebitCreditCode on $projection.DebitCreditCode = _DebitCreditCode.DebitCreditCode
association [0..1] to I_Ledger as _Ledger on $projection.Ledger = _Ledger.Ledger
association [0..1] to I_CurrencyRole as _CurrencyRole on $projection.CurrencyRole = _CurrencyRole.CurrencyRole
association [0..1] to I_AssetTransactionType as _AssetTransactionType on $projection.AssetTransactionType = _AssetTransactionType.AssetTransactionType
association [0..1] to I_ControllingArea as _ControllingArea on _ControllingArea.ControllingArea = $projection.ControllingArea
association [0..*] to I_CostCenter as _AssetCostCenter on _AssetCostCenter.ControllingArea = $projection.ControllingArea
and _AssetCostCenter.CostCenter = $projection.AssetCostCenter
association [0..*] to I_ProfitCenter as _AssetProfitCenter on _AssetProfitCenter.ControllingArea = $projection.ControllingArea
and _AssetProfitCenter.ProfitCenter = $projection.AssetProfitCenter
association [0..1] to I_BusinessArea as _AssetBusinessArea on _AssetBusinessArea.BusinessArea = $projection.AssetBusinessArea
association [0..1] to I_Plant as _AssetPlant on _AssetPlant.Plant = $projection.AssetPlant
association [0..1] to I_Segment as _AssetSegment on _AssetSegment.Segment = $projection.AssetSegment
association [0..1] to I_AssetTransactionVariant as _AssetTransactionVariant on _AssetTransactionVariant.AssetTransactionVariant = $projection.AssetTransactionVariant
association [0..1] to I_Location as _AssetLocation on $projection.assetlocation = _AssetLocation.Location
and $projection.AssetPlant = _AssetLocation.Plant
association [0..1] to I_AssetAcctDetermination as _AssetAccountDetermination on $projection.assetaccountdetermination = _AssetAccountDetermination.AssetAccountDetermination
association [1..1] to I_FiscalYearVariant as _FiscalYearVariant on $projection.FiscalYearVariant = _FiscalYearVariant.FiscalYearVariant
association [0..1] to I_FiscalYearForVariant as _LedgerFiscalYearForVariant on $projection.LedgerFiscalYear = _LedgerFiscalYearForVariant.FiscalYear
and $projection.FiscalYearVariant = _LedgerFiscalYearForVariant.FiscalYearVariant
association [0..1] to I_FiscalYearPeriodForVariant as _FiscalYearPeriodForVariant on $projection.FiscalYearPeriod = _FiscalYearPeriodForVariant.FiscalYearPeriod
and $projection.FiscalYearVariant = _FiscalYearPeriodForVariant.FiscalYearVariant
association [0..1] to I_FiscalPeriodForVariant as _FiscalPeriodForVariant on $projection.LedgerFiscalYear = _FiscalPeriodForVariant.FiscalYear
and $projection.FiscalPeriod = _FiscalPeriodForVariant.FiscalPeriod
and $projection.FiscalYearVariant = _FiscalPeriodForVariant.FiscalYearVariant
association [0..1] to I_Country as _Country on $projection.Country = _Country.Country
association [0..1] to I_FixedAssetCountryData as _FixedAssetCountryData on $projection.CompanyCode = _FixedAssetCountryData.CompanyCode
and $projection.MasterFixedAsset = _FixedAssetCountryData.MasterFixedAsset
and $projection.FixedAsset = _FixedAssetCountryData.FixedAsset
association [0..1] to I_FixedAssetNatlClfn as _FixedAssetNatlClfn on $projection.Country = _FixedAssetNatlClfn.Country
and $projection.nationalclassification = _FixedAssetNatlClfn.NationalClassification
association [0..1] to I_TaxDepreciationGroup as _TaxDepreciationGroup on $projection.Country = _TaxDepreciationGroup.Country
and $projection.taxdepreciationgroup = _TaxDepreciationGroup.TaxDepreciationGroup
association [0..1] to I_AssetKeyFigure as _AssetKeyFigure on $projection.AssetAccountingKeyFigure = _AssetKeyFigure.AssetAccountingKeyFigure
association [0..1] to I_AssetKeyFigureSet as _AssetKeyFigureSet on $projection.AssetAccountingKeyFigureSet = _AssetKeyFigureSet.AssetAccountingKeyFigureSet
association [0..1] to I_FunctionalArea as _FunctionalArea on $projection.FunctionalArea = _FunctionalArea.FunctionalArea
association [0..1] to I_FinancialManagementArea as _FinancialManagementArea on $projection.FinancialManagementArea = _FinancialManagementArea.FinancialManagementArea
association [0..1] to I_Fund as _Fund on $projection.FinancialManagementArea = _Fund.FinancialManagementArea
and $projection.Fund = _Fund.Fund
association [0..1] to I_BudgetPeriod as _BudgetPeriod on $projection.BudgetPeriod = _BudgetPeriod.BudgetPeriod
association [0..1] to I_AssetClass as _AssetClass on $projection.assetclass = _AssetClass.AssetClass
association [0..1] to I_JournalEntry as _JournalEntry on $projection.CompanyCode = _JournalEntry.CompanyCode
and $projection.FiscalYear = _JournalEntry.FiscalYear
and $projection.AccountingDocument = _JournalEntry.AccountingDocument
association [0..1] to I_DepreciationKey as _DepreciationKey on $projection.ChartOfDepreciation = _DepreciationKey.ChartOfDepreciation
and $projection.depreciationkey = _DepreciationKey.DepreciationKey
association [1] to I_SelectedCurrencyBranch as _SelectedCurrencyBranch on $projection.SelectedCurrencyBranch = _SelectedCurrencyBranch.SelectedCurrencyBranch
association [0..1] to I_Currency as _Currency on $projection.DisplayCurrency = _Currency.Currency
association [0..1] to I_UnitOfMeasure as _BaseUnit on $projection.baseunit = _BaseUnit.UnitOfMeasure
association [0..1] to I_JP_PrptyTxRptCity as _JP_PrptyTxRptCity on $projection.jp_prptytxrptcity = _JP_PrptyTxRptCity.JP_PrptyTxRptCity
association [0..1] to I_JP_PrptyTxRptClassfctnKey as _JP_PrptyTxRptClassfctnKey on $projection.jp_prptytxrptclassfctnkey = _JP_PrptyTxRptClassfctnKey.JP_PrptyTxRptClassfctnKey
association [0..1] to I_RU_AssetDepreciationGroup as _RU_AssetDepreciationGroup on $projection.ru_assetdepreciationgroup = _RU_AssetDepreciationGroup.RU_AssetDepreciationGroup
and $projection.Country = _RU_AssetDepreciationGroup.Country
and $projection.ru_assetokof = _RU_AssetDepreciationGroup.RU_AssetOKOF
association [0..1] to I_RU_AssetOKOF as _RU_AssetOKOF on $projection.ru_assetokof = _RU_AssetOKOF.RU_AssetOKOF
and $projection.Country = _RU_AssetOKOF.Country
association [0..*] to I_DeprAreaForLedgerText as _DepreciationAreaText on $projection.CompanyCode = _DepreciationAreaText.CompanyCode
and $projection.Ledger = _DepreciationAreaText.Ledger
and $projection.AssetDepreciationArea = _DepreciationAreaText.AssetDepreciationArea
association [0..*] to I_AssetClassText as _AssetClassText on $projection.assetclass = _AssetClassText.AssetClass
association [0..*] to I_AssetTransactionTypeText as _AssetTransactionTypeText on $projection.AssetTransactionType = _AssetTransactionTypeText.AssetTransactionType
association [0..*] to I_SubLedgerAccLineItemTypeT as _SubLedgerAccLineItemTypeText on $projection.SubLedgerAcctLineItemType = _SubLedgerAccLineItemTypeText.SubLedgerAcctLineItemType
association [0..*] to I_FixedAssetNatlClfnText as _FixedAssetNatlClfnText on $projection.Country = _FixedAssetNatlClfnText.Country
and $projection.nationalclassification = _FixedAssetNatlClfnText.NationalClassification
association [0..*] to I_LedgerText as _LedgerText on $projection.Ledger = _LedgerText.Ledger
association [0..*] to I_AssetTransactionVariantText as _AssetTransactionVariantText on $projection.AssetTransactionVariant = _AssetTransactionVariantText.AssetTransactionVariant
association [0..*] to I_TaxDepreciationGroupText as _TaxDepreciationGroupText on $projection.Country = _TaxDepreciationGroupText.Country
and $projection.taxdepreciationgroup = _TaxDepreciationGroupText.TaxDepreciationGroup
association [1..*] to I_FinancialManagementAreaText as _FinancialManagementAreaText on $projection.FinancialManagementArea = _FinancialManagementAreaText.FinancialManagementArea
association [0..*] to I_FunctionalAreaText as _FunctionalAreaText on $projection.FunctionalArea = _FunctionalAreaText.FunctionalArea
association [0..*] to I_FundText as _FundText on $projection.FinancialManagementArea = _FundText.FinancialManagementArea
and $projection.Fund = _FundText.Fund
association [0..*] to I_BudgetPeriodText as _BudgetPeriodText on $projection.BudgetPeriod = _BudgetPeriodText.BudgetPeriod
association [0..*] to I_DepreciationKeyText as _DepreciationKeyText on $projection.ChartOfDepreciation = _DepreciationKeyText.ChartOfDepreciation
and $projection.depreciationkey = _DepreciationKeyText.DepreciationKey
association [0..*] to I_BusinessAreaText as _AssetBusinessAreaText on _AssetBusinessAreaText.BusinessArea = $projection.AssetBusinessArea
association [0..*] to I_SegmentText as _AssetSegmentText on $projection.Segment = _AssetSegmentText.Segment
association [0..*] to I_AssetAcctDeterminationText as _AssetAcctDeterminationText on $projection.assetaccountdetermination = _AssetAcctDeterminationText.AssetAccountDetermination
association [0..*] to I_MovementCategoryText as _AssetAcctTransClassfctnText on $projection.AssetAcctTransClassfctn = _AssetAcctTransClassfctnText.AssetAcctTransClassfctn
association [0..*] to I_JP_PrptyTxRptCityT as _JP_PrptyTxRptCityText on $projection.jp_prptytxrptcity = _JP_PrptyTxRptCityText.JP_PrptyTxRptCity
association [0..*] to I_JP_PrptyTxRptClassfctnKeyT as _JP_PrptyTxRptClassfctnKeyText on $projection.jp_prptytxrptclassfctnkey = _JP_PrptyTxRptClassfctnKeyText.JP_PrptyTxRptClassfctnKey
association [0..*] to I_RU_AssetDepreciationGroupT as _RU_AssetDepreciationGroupText on $projection.ru_assetdepreciationgroup = _RU_AssetDepreciationGroupText.RU_AssetDepreciationGroup
and $projection.Country = _RU_AssetDepreciationGroupText.Country
and $projection.ru_assetokof = _RU_AssetDepreciationGroupText.RU_AssetOKOF
association [0..*] to I_RU_AssetOKOFText as _RU_AssetOKOFText on $projection.ru_assetokof = _RU_AssetOKOFText.RU_AssetOKOF
and $projection.Country = _RU_AssetOKOFText.Country
association [1] to I_AssetRedesignSwitchStatus as _AssetRedesignSwitchStatus on _AssetRedesignSwitchStatus.AssetRedesignSwitchIsActive = ''
or _AssetRedesignSwitchStatus.AssetRedesignSwitchIsActive = 'X'
association [0..1] to I_FixedAssetForLedger as _FixedAssetForLedger on $projection.CompanyCode = _FixedAssetForLedger.CompanyCode
and $projection.MasterFixedAsset = _FixedAssetForLedger.MasterFixedAsset
and $projection.FixedAsset = _FixedAssetForLedger.FixedAsset
and $projection.Ledger = _FixedAssetForLedger.Ledger
association [0..1] to I_FixedAssetAssgmt as _FixedAssetAssgmt on _FixedAssetAssgmt.CompanyCode = $projection.CompanyCode
and _FixedAssetAssgmt.MasterFixedAsset = $projection.MasterFixedAsset
and _FixedAssetAssgmt.FixedAsset = $projection.FixedAsset
and _FixedAssetAssgmt.ValidityStartDate <= $parameters.P_KeyDate
and _FixedAssetAssgmt.ValidityEndDate >= $parameters.P_KeyDate
association [0..1] to I_AssetValuationForLedger as _AssetValuationForLedger on _AssetValuationForLedger.CompanyCode = $projection.CompanyCode
and _AssetValuationForLedger.MasterFixedAsset = $projection.MasterFixedAsset
and _AssetValuationForLedger.FixedAsset = $projection.FixedAsset
and _AssetValuationForLedger.Ledger = $projection.Ledger
and _AssetValuationForLedger.AssetRealDepreciationArea = $projection.AssetDepreciationArea
and _AssetValuationForLedger.ValidityStartDate <= $parameters.P_KeyDate
and _AssetValuationForLedger.ValidityEndDate >= $parameters.P_KeyDate
association [0..1] to I_GlobAssetAssignment as _GlobAssetAssignment on _GlobAssetAssignment.CompanyCode = $projection.CompanyCode
and _GlobAssetAssignment.MasterFixedAsset = $projection.MasterFixedAsset
and _GlobAssetAssignment.FixedAsset = $projection.FixedAsset
and _GlobAssetAssignment.ValidityStartDate <= $parameters.P_KeyDate
and _GlobAssetAssignment.ValidityEndDate >= $parameters.P_KeyDate
// Association to Extension View
association [1..1] to E_FixedAsset as _Extension on $projection.MasterFixedAsset = _Extension.MasterFixedAsset
and $projection.FixedAsset = _Extension.FixedAsset
and $projection.CompanyCode = _Extension.CompanyCode
{
@ObjectModel.foreignKey.association: '_CompanyCode'
key P_FixedAssetTransaction1.CompanyCode,
@ObjectModel.foreignKey.association: '_DepreciationArea'
key P_FixedAssetTransaction1.AssetDepreciationArea,
@ObjectModel.foreignKey.association: '_MasterFixedAsset'
key P_FixedAssetTransaction1.MasterFixedAsset,
@ObjectModel.foreignKey.association: '_FixedAsset'
key P_FixedAssetTransaction1.FixedAsset,
@ObjectModel.foreignKey.association: '_Ledger'
key P_FixedAssetTransaction1.Ledger,
@ObjectModel.foreignKey.association: '_FiscalYear'
key P_FixedAssetTransaction1.FiscalYear,
@ObjectModel.foreignKey.association: '_FiscalPeriodForVariant'
key P_FixedAssetTransaction1.FiscalPeriod,
@ObjectModel.foreignKey.association: '_SubLedgerAccLineItemType'
key P_FixedAssetTransaction1.SubLedgerAcctLineItemType,
@ObjectModel.foreignKey.association: '_AssetAcctTransClassfctn'
key P_FixedAssetTransaction1.AssetAcctTransClassfctn,
@ObjectModel.foreignKey.association: '_AssetKeyFigure'
key P_FixedAssetTransaction1.AssetAccountingKeyFigure,
@ObjectModel.foreignKey.association: '_AssetKeyFigureSet'
key P_FixedAssetTransaction1.AssetAccountingKeyFigureSet,
@ObjectModel.foreignKey.association: '_JournalEntry'
key P_FixedAssetTransaction1.AccountingDocument,
key P_FixedAssetTransaction1.LedgerGLLineItem,
key P_FixedAssetTransaction1.TransactionSubitem,
@ObjectModel.foreignKey.association: '_DebitCreditCode'
key P_FixedAssetTransaction1.DebitCreditCode,
@ObjectModel.foreignKey.association: '_CurrencyRole'
key cast(P_FixedAssetTransaction1.CurrencyRole as fins_curtype) as CurrencyRole,
@ObjectModel.foreignKey.association: '_LedgerGroup'
P_FixedAssetTransaction1.LedgerGroup,
@ObjectModel.foreignKey.association: '_LedgerFiscalYearForVariant'
@Semantics.fiscal.year: true
P_FixedAssetTransaction1.LedgerFiscalYear,
@ObjectModel.foreignKey.association: '_FiscalYearVariant'
@Semantics.fiscal.yearVariant: true
P_FixedAssetTransaction1.FiscalYearVariant,
@ObjectModel.foreignKey.association: '_FiscalYearPeriodForVariant'
@Semantics.fiscal.yearPeriod: true
P_FixedAssetTransaction1.FiscalYearPeriod,
@Consumption.hidden: true
_FixedAsset.AssetAuthorizationContext,
_FixedAsset.FixedAssetExternalID,
_CompanyCode.CompanyCodeName,
P_FixedAssetTransaction1.GroupMasterFixedAsset,
P_FixedAssetTransaction1.GroupFixedAsset,
@ObjectModel.foreignKey.association: '_ChartOfDepreciation'
P_FixedAssetTransaction1.ChartOfDepreciation,
P_FixedAssetTransaction1.AccountingDocumentCreationDate,
P_FixedAssetTransaction1.CreationTime,
P_FixedAssetTransaction1.PostingDate,
P_FixedAssetTransaction1.DocumentDate,
P_FixedAssetTransaction1.AssetValueDate,
P_FixedAssetTransaction1.AccountingDocCreatedByUser,
@ObjectModel.foreignKey.association: '_AssetTransactionType'
P_FixedAssetTransaction1.AssetTransactionType,
@ObjectModel.foreignKey.association: '_AssetTransactionVariant'
P_FixedAssetTransaction1.AssetTransactionVariant,
P_FixedAssetTransaction1.AssignmentReference,
P_FixedAssetTransaction1.DocumentItemText,
P_FixedAssetTransaction1.ReferenceDocumentType,
P_FixedAssetTransaction1.ReferenceDocument,
P_FixedAssetTransaction1.LogicalSystem,
P_FixedAssetTransaction1.ReferenceDocumentContext,
P_FixedAssetTransaction1.ReversalReferenceDocumentCntxt,
P_FixedAssetTransaction1.ReversalReferenceDocument,
P_FixedAssetTransaction1.ReversalTransactionSubitem,
P_FixedAssetTransaction1.IsReversal,
P_FixedAssetTransaction1.IsReversed,
P_FixedAssetTransaction1.BusinessArea,
P_FixedAssetTransaction1.Segment,
P_FixedAssetTransaction1.FinancialAccountType,
@ObjectModel.foreignKey.association: '_ControllingArea'
P_FixedAssetTransaction1.ControllingArea,
_FixedAsset.InvestmentProjectWBSElement,
@ObjectModel.foreignKey.association: '_FinancialManagementArea'
P_FixedAssetTransaction1.FinancialManagementArea,
@ObjectModel.foreignKey.association: '_Fund'
P_FixedAssetTransaction1.Fund,
P_FixedAssetTransaction1.GrantID,
@ObjectModel.foreignKey.association: '_FunctionalArea'
P_FixedAssetTransaction1.FunctionalArea,
@ObjectModel.foreignKey.association: '_BudgetPeriod'
P_FixedAssetTransaction1.BudgetPeriod,
@ObjectModel.foreignKey.association: '_Country'
P_FixedAssetTransaction1.Country,
@ObjectModel.foreignKey.association: '_FixedAssetNatlClfn'
_FixedAssetCountryData.NationalClassification,
@ObjectModel.foreignKey.association: '_TaxDepreciationGroup'
_FixedAssetCountryData.TaxDepreciationGroup,
@ObjectModel.foreignKey.association: '_JP_PrptyTxRptCity'
_FixedAssetCountryData.JP_PrptyTxRptCity,
@ObjectModel.foreignKey.association: '_JP_PrptyTxRptClassfctnKey'
_FixedAssetCountryData.JP_PrptyTxRptClassfctnKey,
@ObjectModel.foreignKey.association: '_RU_AssetOKOF'
_GlobAssetAssignment.RU_AssetOKOF,
@ObjectModel.foreignKey.association: '_RU_AssetDepreciationGroup'
_GlobAssetAssignment.RU_AssetDepreciationGroup,
@ObjectModel.foreignKey.association: '_SelectedCurrencyBranch'
P_FixedAssetTransaction1.SelectedCurrencyBranch,
@ObjectModel.foreignKey.association: '_Currency'
P_FixedAssetTransaction1.DisplayCurrency,
@DefaultAggregation:#SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
P_FixedAssetTransaction1.AmountInDisplayCurrency,
@DefaultAggregation:#SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
case when P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07000' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07040' or //Cumulative Acquisition Costs or Acquisition Costs Related to Current Year
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07001' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07041' or //Cumulative Down Payments or Down Payments Related to Current Year
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07002' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07042' or //Cumulative Investment Support or Investment Support Related to Current Year
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07003' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07043' or //Cumulative Revaluation of Acquisition Costs or Revaluation of Acquisition Costs Related to Current Year
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07203' or //Revaluation of Acquisition Costs Posted Periodically
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07028' or //Transfer of Reserves Related to Prior Year <<<<<Fixed with 1708/1709
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07023' or //Revaluation of Acquisition Costs Related to Prior Year "Fixed by note
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07103' or
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07123' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07143' or
(P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07025' and P_FixedAssetTransaction1.AssetTransactionVariant <> '1'
and P_FixedAssetTransaction1.AssetTransactionVariant <> '2'
and P_FixedAssetTransaction1.AssetTransactionVariant <> '3') //Ordinary Depreciation Related to Prior Year
then cast(P_FixedAssetTransaction1.AmountInDisplayCurrency as fis_apcamount)
else
cast('0' as fis_apcamount)
end as AcqnProdnAmtInDspCrcy,
@DefaultAggregation:#SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
case when P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07005' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07045' or //Cumulative Ordinary Depreciation or Ordinary Depreciation Related to Current Year
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07007' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07204' or //Write-Down to Going-Concern Value Accumulated or Revaluation of Ordinary Depreciation Posted Periodically
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07044' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07024' or //Fixed by Note
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07004' or
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07006' or //Cumulative Special Depreciation
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07046' or //Special Depreciation Related to Current Year "Fixed by note
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07047' or //Current-Value Depreciation Related to Current Year
(P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07025' and
(P_FixedAssetTransaction1.AssetTransactionVariant = '1' or
P_FixedAssetTransaction1.AssetTransactionVariant = '2' or
P_FixedAssetTransaction1.AssetTransactionVariant = '3')) or //Ordinary Depreciation Related to Prior Year
(P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07026' and
(P_FixedAssetTransaction1.AssetTransactionVariant = '1' or
P_FixedAssetTransaction1.AssetTransactionVariant = '2' or
P_FixedAssetTransaction1.AssetTransactionVariant = '3')) or //Special Depreciation Related to Prior Year "Fixed by note
(P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07027' and
(P_FixedAssetTransaction1.AssetTransactionVariant = '1' or
P_FixedAssetTransaction1.AssetTransactionVariant = '2' or
P_FixedAssetTransaction1.AssetTransactionVariant = '3')) or //Write-Down to Going-Concern Value Rel. to Prior-Year Acquis
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07107' or
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07127' or
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07147'
then cast(P_FixedAssetTransaction1.AmountInDisplayCurrency as fis_valueadjamt)
else
cast('0' as fis_valueadjamt)
end as ValueAdjustmentAmtInDspCrcy,
@DefaultAggregation:#SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
case when P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07900' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07940' //Revenue Related to Prior Year or Revenue Relating to Current Year Acquisitions
then cast(P_FixedAssetTransaction1.AmountInDisplayCurrency as fis_retirementrevenueamount)
else
cast('0' as fis_retirementrevenueamount)
end as RetirementRevenueAmtInDspCrcy,
@DefaultAggregation:#SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
case when P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07901' //Retirement Costs
then cast(P_FixedAssetTransaction1.AmountInDisplayCurrency as fis_retirementcostsamount)
else
cast('0' as fis_retirementcostsamount)
end as RetirementCostsAmtInDspCrcy,
@DefaultAggregation:#SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
case when P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07902' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07904' //Loss or Net Book Value
then cast(P_FixedAssetTransaction1.AmountInDisplayCurrency *-1 as fis_retirementlossamount)
else
cast('0' as fis_retirementlossamount)
end as RetirementLossAmtInDspCrcy,
@DefaultAggregation:#SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
case when P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07903' //Gain
then cast(P_FixedAssetTransaction1.AmountInDisplayCurrency *-1 as fis_retirementgainamount)
else
cast('0' as fis_retirementgainamount)
end as RetirementGainAmtInDspCrcy,
@DefaultAggregation:#SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
case when P_FixedAssetTransaction1.AssetTransactionVariant = '2'
//case when AssetAcctTransClassfctn = '12' or AssetAcctTransClassfctn = 'A8' or AssetAcctTransClassfctn = 'B8'
then case when P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07025' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07045' or //Ordinary Depreciation Related to Prior Year or Ordinary Depreciation Related to Current Year
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07026' or //Special Depreciation Related to Prior Year "Fixed by note
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07027' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07005' or //Current-Value Depreciation Related to Prior Year or Cumulative Ordinary Depreciation
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07046' or
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07047' or
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07007' or //Cumulative Current-Value Depreciation
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07004' or
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07006'
then cast(P_FixedAssetTransaction1.AmountInDisplayCurrency as fis_retirementdepramount)
else
cast('0' as fis_retirementdepramount)
end
else
cast('0' as fis_retirementdepramount)
end as RetirementDeprAmtInDspCrcy,
@DefaultAggregation:#SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
case when P_FixedAssetTransaction1.AssetTransactionVariant = '2'
//case when AssetAcctTransClassfctn = '12' or AssetAcctTransClassfctn = 'A8' or AssetAcctTransClassfctn = 'B8'
then case when P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07000' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07040' or //Cumulative Acquisition Costs or Acquisition Costs Related to Current Year
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07003'
then cast(P_FixedAssetTransaction1.AmountInDisplayCurrency as fis_retirementamount)
else
cast('0' as fis_retirementamount)
end
else
cast('0' as fis_retirementamount)
end as RetirementAmountInDspCrcy,
@DefaultAggregation:#SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
case when P_FixedAssetTransaction1.AssetTransactionVariant = '2'
//case when AssetAcctTransClassfctn = '12' or AssetAcctTransClassfctn = 'A8' or AssetAcctTransClassfctn = 'B8'
then case when P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07000' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07040' or //Cumulative Acquisition Costs or Acquisition Costs Related to Current Year
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07025' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07045' or //Ordinary Depreciation Related to Prior Year or Ordinary Depreciation Related to Current Year
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07026' or //Special Depreciation Related to Prior Year "Fixed by note
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07027' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07005' or //Current-Value Depreciation Related to Prior Year or Cumulative Ordinary Depreciation
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07046' or
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07047' or
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07007' or //Cumulative Current-Value Depreciation
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07003' or
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07004' or
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07006'
then cast(P_FixedAssetTransaction1.AmountInDisplayCurrency as fis_retirementnbv)
else
cast('0' as fis_retirementnbv)
end
else
cast('0' as fis_retirementnbv)
end as RtrmtNetBookValueAmtInDspCrcy,
@DefaultAggregation:#SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
case when P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07005' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07025' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07045' or
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07205'
then cast(P_FixedAssetTransaction1.AmountInDisplayCurrency as fis_ordinarydepramt)
else
cast('0' as fis_ordinarydepramt)
end as OrdinaryDeprAmtInDspCrcy,
@DefaultAggregation:#SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
case when P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07006' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07026' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07046' or
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07206'
then cast(P_FixedAssetTransaction1.AmountInDisplayCurrency as fis_specialdepramt)
else
cast('0' as fis_specialdepramt)
end as SpecialDeprAmtInDspCrcy,
@DefaultAggregation:#SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
case when P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07007' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07027' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07047' or
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07207'
then cast(P_FixedAssetTransaction1.AmountInDisplayCurrency as fis_unplanneddepramt)
else
cast('0' as fis_unplanneddepramt)
end as UnplannedDeprAmtInDspCrcy,
@DefaultAggregation:#SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
case when P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07008' or P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07028' or
P_FixedAssetTransaction1.SubLedgerAcctLineItemType = '07208'
then cast(P_FixedAssetTransaction1.AmountInDisplayCurrency as fis_transferedreserveamt)
else
cast('0' as fis_transferedreserveamt)
end as TransferredReserveAmtInDspCrcy,
@ObjectModel.foreignKey.association: '_BaseUnit'
_FixedAsset.BaseUnit,
@DefaultAggregation: #SUM
@Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
P_FixedAssetTransaction1.Quantity,
P_FixedAssetTransaction1.IsStatisticalDocument,
/* ANLA */
@ObjectModel.foreignKey.association: '_AssetClass'
_FixedAsset.AssetClass,
_FixedAssetForLedger.AssetCapitalizationDate,
@Semantics.text
_FixedAsset.FixedAssetDescription,
@Semantics.text
cast(_FixedAsset.AssetAdditionalDescription as fis_txa50_more) as AssetAdditionalDescription,
@ObjectModel.foreignKey.association: '_AssetAccountDetermination'
_FixedAsset.AssetAccountDetermination,
_FixedAsset.Inventory,
/* ANLZ */
@ObjectModel.foreignKey.association: '_AssetCostCenter'
cast(_FixedAssetAssgmt.CostCenter as faa_kostl) as AssetCostCenter,
@ObjectModel.foreignKey.association: '_AssetBusinessArea'
cast(_FixedAssetAssgmt.BusinessArea as faa_gsber) as AssetBusinessArea,
@ObjectModel.foreignKey.association: '_AssetPlant'
cast(_FixedAssetAssgmt.Plant as faa_werks) as AssetPlant,
@ObjectModel.foreignKey.association: '_AssetProfitCenter'
cast(_FixedAssetAssgmt.ProfitCenter as faa_prctr) as AssetProfitCenter,
@ObjectModel.foreignKey.association: '_AssetSegment'
cast(_FixedAssetAssgmt.Segment as faa_fb_segment) as AssetSegment,
@ObjectModel.foreignKey.association: '_AssetLocation'
_FixedAssetAssgmt.AssetLocation,
/* ANLB */
@ObjectModel.foreignKey.association: '_DepreciationKey'
_AssetValuationForLedger.DepreciationKey,
_AssetValuationForLedger.PlannedUsefulLifeInYears,
_AssetValuationForLedger.PlannedUsefulLifeInPeriods,
_AssetValuationForLedger.OriglAstUsefulLifeInYears,
_AssetValuationForLedger.OriglAstUsefulLifeInPerds,
_AssetValuationForLedger.DepreciationStartDate,
_AssetValuationForLedger.DeprKeyChangeoverYear,
_AssetValuationForLedger.DeprKeyChangeoverPeriod,
_AssetValuationForLedger.VintageYear,
_AssetValuationForLedger.VintageMonth,
_AssetValuationForLedger.ReplacementValueIndexSers,
_AssetValuationForLedger.RplcmtValueAgingIndexSers,
/* Associations */
_DepreciationArea,
_CompanyCode,
_MasterFixedAsset,
_FixedAsset,
_FiscalYear,
_SubLedgerAccLineItemType,
_LedgerGroup,
_Ledger,
_ChartOfDepreciation,
_AssetTransactionType,
_AssetTransactionVariant,
_AssetAcctTransClassfctn,
_DebitCreditCode,
_CurrencyRole,
_AssetClass,
_ControllingArea,
_AssetCostCenter,
_AssetProfitCenter,
_AssetBusinessArea,
_AssetPlant,
_AssetSegment,
_FiscalYearVariant,
_LedgerFiscalYearForVariant,
_FiscalYearPeriodForVariant,
_FiscalPeriodForVariant,
_FixedAssetCountryData,
_FixedAssetNatlClfn,
_TaxDepreciationGroup,
_Country,
_FunctionalArea,
_FinancialManagementArea,
_Fund,
_BudgetPeriod,
_JournalEntry,
_DepreciationKey,
_SelectedCurrencyBranch,
_AssetKeyFigure,
_AssetKeyFigureSet,
_AssetAccountDetermination,
_AssetLocation,
_Currency,
_BaseUnit,
_JP_PrptyTxRptCity,
_JP_PrptyTxRptClassfctnKey,
_RU_AssetDepreciationGroup,
_RU_AssetOKOF,
/*Text Associations */
_AssetBusinessAreaText,
_AssetSegmentText,
_DepreciationAreaText,
_AssetClassText,
_AssetTransactionTypeText,
_SubLedgerAccLineItemTypeText,
_FixedAssetNatlClfnText,
_LedgerText,
_FunctionalAreaText,
_FundText,
_BudgetPeriodText,
_DepreciationKeyText,
_AssetTransactionVariantText,
_TaxDepreciationGroupText,
_FinancialManagementAreaText,
_AssetAcctDeterminationText,
_AssetAcctTransClassfctnText,
_JP_PrptyTxRptCityText,
_JP_PrptyTxRptClassfctnKeyText,
_RU_AssetDepreciationGroupText,
_RU_AssetOKOFText,
@Consumption.hidden: true
_AssetRedesignSwitchStatus //for DCL
}