I_TH_AssetDisposalCube

DDL: I_TH_ASSETDISPOSALCUBE SQL: ITHASSTDSPSLCUBE Type: view COMPOSITE

Thailand: Disposal List Cube

I_TH_AssetDisposalCube is a Composite CDS View (Cube) that provides data about "Thailand: Disposal List Cube" in SAP S/4HANA. It reads from 3 data sources (I_FixedAssetForLedger, I_FixedAssetTransaction, I_StRpJournalEntryLog) and exposes 31 fields with key fields CompanyCode, AssetDepreciationArea, MasterFixedAsset, FixedAsset, Ledger.

3 data source(s) 31 fields

Data Sources (3)

SourceAliasJoin Type
I_FixedAssetForLedger FixedAssetForLedger left_outer
I_FixedAssetTransaction I_FixedAssetTransaction from
I_StRpJournalEntryLog ReportedItemsLog left_outer

Parameters (4)

NameTypeDefault
P_KeyDate fagl_keydate
P_AssetAccountingKeyFigureSet faa_key_figure_set
P_FiscalYear fis_gjahr
P_FiscalPeriod fis_poper

Annotations (15)

NameValueLevelField
AbapCatalog.sqlViewName ITHASSTDSPSLCUBE view
AbapCatalog.preserveKey true view
VDM.viewType #COMPOSITE view
Analytics.dataCategory #CUBE view
Analytics.internalName #LOCAL view
AbapCatalog.compiler.compareFilter true view
ClientHandling.algorithm #SESSION_VARIABLE view
AccessControl.authorizationCheck #CHECK view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XXL view
ObjectModel.usageType.dataClass #MIXED view
AccessControl.personalData.blocking #NOT_REQUIRED view
EndUserText.label Thailand: Disposal List Cube view
Metadata.ignorePropagatedAnnotations true view
Metadata.allowExtensions true view

Fields (31)

KeyFieldSource TableSource FieldDescription
KEY CompanyCode FixedAssetTransaction CompanyCode
KEY AssetDepreciationArea FixedAssetTransaction AssetDepreciationArea
KEY MasterFixedAsset FixedAssetTransaction MasterFixedAsset
KEY FixedAsset FixedAssetTransaction FixedAsset
KEY Ledger FixedAssetTransaction Ledger
KEY FiscalYear FixedAssetTransaction FiscalYear
KEY FiscalPeriod FiscalPeriod
KEY SubLedgerAcctLineItemType SubLedgerAcctLineItemType
KEY AssetAcctTransClassfctn AssetAcctTransClassfctn
KEY AssetAccountingKeyFigure AssetAccountingKeyFigure
KEY AssetAccountingKeyFigureSet AssetAccountingKeyFigureSet
KEY AccountingDocument FixedAssetTransaction AccountingDocument
KEY TransactionSubitem TransactionSubitem
KEY DebitCreditCode DebitCreditCode
KEY CurrencyRole CurrencyRole
DisplayCurrency DisplayCurrency
AssetAccountDetermination FixedAssetTransaction AssetAccountDetermination
AssetClass AssetClass
AssetCapitalizationDate FixedAssetTransaction AssetCapitalizationDate
FixedAssetDescription FixedAssetDescription
AssetDeactivationDate I_FixedAssetForLedger AssetDeactivationDate
RetirementAmountInDspCrcy RetirementAmountInDspCrcy
RetirementRevenueAmtInDspCrcy RetirementRevenueAmtInDspCrcy
RtrmtNetBookValueAmtInDspCrcy RtrmtNetBookValueAmtInDspCrcy
RetirementCostsAmtInDspCrcy RetirementCostsAmtInDspCrcy
RetirementGainAmtInDspCrcy RetirementGainAmtInDspCrcy
RetirementLossAmtInDspCrcy RetirementLossAmtInDspCrcy
StatryRptgEntity I_StRpJournalEntryLog StatryRptgEntity
StatryRptCategory I_StRpJournalEntryLog StatryRptCategory
StatryRptRunID I_StRpJournalEntryLog StatryRptRunID
AssetAuthorizationContext AssetAuthorizationContext 
@AbapCatalog.sqlViewName: 'ITHASSTDSPSLCUBE'
@AbapCatalog.preserveKey:true
@VDM.viewType: #COMPOSITE
@Analytics: { dataCategory: #CUBE,
              internalName:#LOCAL }
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MIXED
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Thailand: Disposal List Cube'
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions:true


define view I_TH_AssetDisposalCube
  with parameters
    P_KeyDate                     : fagl_keydate,
    P_AssetAccountingKeyFigureSet : faa_key_figure_set,
    P_FiscalYear                  : fis_gjahr,
    P_FiscalPeriod                : fis_poper
  as select from    I_FixedAssetTransaction (P_KeyDate: :P_KeyDate, P_AssetAccountingKeyFigureSet: :P_AssetAccountingKeyFigureSet) as FixedAssetTransaction
    left outer join I_FixedAssetForLedger                                                                                          as FixedAssetForLedger on  FixedAssetForLedger.CompanyCode      = FixedAssetTransaction.CompanyCode
                                                                                                                                                          and FixedAssetForLedger.MasterFixedAsset = FixedAssetTransaction.MasterFixedAsset
                                                                                                                                                          and FixedAssetForLedger.Ledger           = FixedAssetTransaction.Ledger
                                                                                                                                                          and FixedAssetForLedger.FixedAsset       = FixedAssetTransaction.FixedAsset
    left outer join I_StRpJournalEntryLog                                                                                          as ReportedItemsLog    on  ReportedItemsLog.CompanyCode        = FixedAssetTransaction.CompanyCode
                                                                                                                                                          and ReportedItemsLog.AccountingDocument = FixedAssetTransaction.AccountingDocument
                                                                                                                                                          and ReportedItemsLog.FiscalYear         = FixedAssetTransaction.FiscalYear

{
  key     FixedAssetTransaction.CompanyCode,
  key     FixedAssetTransaction.AssetDepreciationArea,
  key     FixedAssetTransaction.MasterFixedAsset,
  key     FixedAssetTransaction.FixedAsset,
  key     FixedAssetTransaction.Ledger,
  key     FixedAssetTransaction.FiscalYear,
  key     FiscalPeriod,
  key     SubLedgerAcctLineItemType,
  key     AssetAcctTransClassfctn,
  key     AssetAccountingKeyFigure,
  key     AssetAccountingKeyFigureSet,
  key     FixedAssetTransaction.AccountingDocument,
  key     TransactionSubitem,
  key     DebitCreditCode,
  key     CurrencyRole,
          @Semantics.currencyCode:true
          DisplayCurrency,
          FixedAssetTransaction.AssetAccountDetermination,
          AssetClass,
          FixedAssetTransaction.AssetCapitalizationDate,
          FixedAssetDescription,
          FixedAssetForLedger.AssetDeactivationDate,
          @DefaultAggregation: #SUM
          @Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
          RetirementAmountInDspCrcy,
          @DefaultAggregation: #SUM
          @Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
          RetirementRevenueAmtInDspCrcy,
          @DefaultAggregation: #SUM
          @Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
          RtrmtNetBookValueAmtInDspCrcy,
          @DefaultAggregation: #SUM
          @Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
          RetirementCostsAmtInDspCrcy,
          @DefaultAggregation: #SUM
          @Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
          RetirementGainAmtInDspCrcy,
          @DefaultAggregation: #SUM
          @Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
          RetirementLossAmtInDspCrcy,
          ReportedItemsLog.StatryRptgEntity,
          ReportedItemsLog.StatryRptCategory,
          ReportedItemsLog.StatryRptRunID,
          @Consumption.hidden: true
          AssetAuthorizationContext





}
where
      FixedAssetTransaction.FiscalYear   =  :P_FiscalYear
  and FixedAssetTransaction.FiscalPeriod <= :P_FiscalPeriod

Learn More