@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Asset Transactions'
@VDM.viewType: #CONSUMPTION
@ObjectModel: { usageType.serviceQuality: #D,
usageType.sizeCategory: #XXL,
usageType.dataClass: #MIXED }
@Search.searchable: true
@Metadata: {ignorePropagatedAnnotations: true, allowExtensions:true}
@Consumption.dbHints: [
'JOIN_THRU_AGGR',
'USE_OLAP_PLAN',
'PREAGGR_BEFORE_UNION'
]
@UI.presentationVariant: [
{ qualifier: 'VH_AssetClass',
sortOrder: [ {by: 'AmountInDisplayCurrency', direction: #DESC } ],
visualizations: [{ type: #AS_CHART, qualifier: 'AmountByAssetClass' }]
},
{
qualifier: 'MainContentPV',
sortOrder: [ {by: 'MasterFixedAsset', direction: #ASC }, {by: 'FixedAsset', direction: #ASC }],
groupBy: [ 'CompanyCode', 'AssetTransactionType' ],
requestAtLeast: ['LedgerFiscalYear'],
visualizations: [{ type: #AS_LINEITEM, qualifier: 'MainContent' }]
},
{
qualifier: 'MainChartPV',
visualizations: [{ type: #AS_CHART, qualifier: 'MainChart' }]
}
]
//Column chart for the lineItem
@UI.chart:[{chartType: #COLUMN,
title: '',
dimensions: ['AssetTransactionType', 'AssetDepreciationArea','CompanyCode'],
measures: ['ValueAdjustmentAmtInDspCrcy', 'AcqnProdnAmtInDspCrcy'],
qualifier: 'MainChart'
},
//Bar chart for visual filter Top 3 by Asset Class
{chartType: #BAR,
dimensions: [ 'AssetClass' ],
measures: [ 'AmountInDisplayCurrency' ],
qualifier: 'AmountByAssetClass'
}]
@UI.textArrangement: #TEXT_LAST
define view entity C_FixedAssetTransaction
with parameters
@Environment.systemField: #SYSTEM_DATE
P_KeyDate : fagl_keydate,
P_AssetAccountingKeyFigureSet : faa_key_figure_set
as select from I_FixedAssetTransaction(P_KeyDate: $parameters.P_KeyDate, P_AssetAccountingKeyFigureSet: $parameters.P_AssetAccountingKeyFigureSet) as Transaction
association [0..1] to I_LedgerCompanyCodeCrcyRolesVH as _CurrencyRoleVH on _CurrencyRoleVH.Ledger = $projection.Ledger
and _CurrencyRoleVH.CompanyCode = $projection.CompanyCode
and _CurrencyRoleVH.CurrencyRole = $projection.CurrencyRole
association [0..1] to I_CompanyCodeAsset as _CompanyCodeVH on _CompanyCodeVH.CompanyCode = $projection.CompanyCode
association [0..1] to I_DepreciationKey as _DepreciationKeyVH on $projection.ChartOfDepreciation = _DepreciationKeyVH.ChartOfDepreciation
and $projection.DepreciationKey = _DepreciationKeyVH.DepreciationKey
association [0..1] to I_Ledger as _LedgerVH on $projection.Ledger = _LedgerVH.Ledger
association [0..1] to I_WBSElementByExternalID as _WBSElement on $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
//The following assoications are neeeded for the semantic date range control
association [0..1] to I_FiscCalendarDateForCompCode as _FiscCalendarDateForCompCode on $projection.PostingDate = _FiscCalendarDateForCompCode.CalendarDate
and $projection.CompanyCode = _FiscCalendarDateForCompCode.CompanyCode
association [0..1] to I_FiscalCalendarDateForLedger as _FiscalCalendarDateForLedger on $projection.PostingDate = _FiscalCalendarDateForLedger.CalendarDate
and $projection.CompanyCode = _FiscalCalendarDateForLedger.CompanyCode
and $projection.Ledger = _FiscalCalendarDateForLedger.Ledger
association [0..1] to I_CostCenterText as _AssetCostCenterText on $projection.ControllingArea = _AssetCostCenterText.ControllingArea
and $projection.AssetCostCenter = _AssetCostCenterText.CostCenter
and _AssetCostCenterText.ValidityStartDate <= $parameters.P_KeyDate
and _AssetCostCenterText.ValidityEndDate >= $parameters.P_KeyDate
and _AssetCostCenterText.Language = $session.system_language
association [0..1] to I_ProfitCenterText as _AssetProfitCenterText on $projection.ControllingArea = _AssetProfitCenterText.ControllingArea
and $projection.AssetProfitCenter = _AssetProfitCenterText.ProfitCenter
and _AssetProfitCenterText.ValidityStartDate <= $parameters.P_KeyDate
and _AssetProfitCenterText.ValidityEndDate >= $parameters.P_KeyDate
and _AssetProfitCenterText.Language = $session.system_language
{
@UI: { lineItem: [{position: 10, importance: #HIGH, qualifier: 'MainContent'}],
selectionField: [{position: 20}] }
@Consumption.semanticObject: 'CompanyCode'
@Consumption.filter: {selectionType: #SINGLE, multipleSelections: true, mandatory: true }
@ObjectModel.text.element: ['CompanyCodeName']
@ObjectModel.filter.enabled : true
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
key CompanyCode,
@Search.defaultSearchElement: true
@Search.fuzzinessThreshold: 0.8
@Search.ranking: #HIGH
@UI: { lineItem: [{position: 60, importance: #HIGH, qualifier: 'MainContent'}],
selectionField: [{position: 80}] }
@Consumption.semanticObject: 'FixedAsset'
@ObjectModel.text.element: ['MasterFixedAssetDescription']
@UI.textArrangement: #TEXT_LAST
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_MasterFixedAssetStdVH', element: 'MasterFixedAsset' },
additionalBinding: [ { localElement: 'CompanyCode', element: 'CompanyCode' } ]
} ]
key MasterFixedAsset,
@UI: { lineItem: [{position: 80, importance: #HIGH, qualifier: 'MainContent'}],
selectionField: [{position: 90}] }
@ObjectModel.text.element: ['FixedAssetDescription']
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_FixedAssetStdVH', element: 'FixedAsset' },
additionalBinding: [ { localElement: 'CompanyCode', element: 'CompanyCode' },
{ localElement: 'MasterFixedAsset', element: 'MasterFixedAsset' } ]
} ]
@UI.textArrangement: #TEXT_LAST
key FixedAsset,
@UI: { lineItem: [{position: 70, importance: #HIGH, qualifier: 'MainContent'}],
selectionField: [{position: 40}] }
@Consumption.filter: {selectionType: #RANGE, mandatory: true}
key LedgerFiscalYear,
@UI: { selectionField: [{position: 50}] }
@Consumption.filter: {selectionType: #RANGE}
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_FiscalYearPeriodForLedger', element: 'FiscalPeriod' },
additionalBinding: [ { localElement: 'CompanyCode', element:'CompanyCode' },
{ localElement: 'Ledger', element:'Ledger' },
{ localElement: 'LedgerFiscalYear', element:'FiscalYear' } ]
} ]
key FiscalPeriod,
@UI: { selectionField: [{position: 60}] }
@Consumption.filter: {selectionType: #SINGLE, mandatory: true }
@ObjectModel.text.element: ['AssetDepreciationAreaName']
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_DeprAreaForLedgerVH', element: 'AssetDepreciationArea' },
additionalBinding: [ { localElement: 'CompanyCode', element:'CompanyCode' }, { localElement: 'Ledger', element:'Ledger' } ]
} ]
key cast( AssetDepreciationArea as fis_afabe preserving type ) as AssetDepreciationArea,
@UI: { selectionField: [{position: 30}] }
@Consumption.filter: {selectionType: #SINGLE, mandatory: true }
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_LedgerStdVH', element: 'Ledger' } } ]
@ObjectModel.text.element: ['LedgerName']
key Ledger,
@UI: { lineItem: [{position: 20, importance: #HIGH, qualifier: 'MainContent'}] }
@Consumption.semanticObject: 'AccountingDocument'
key AccountingDocument,
key LedgerGLLineItem,
key TransactionSubitem,
key DebitCreditCode,
@Consumption.filter.hidden: true
key CurrencyRole,
@ObjectModel.text.element: ['SubLedgerAcctLineItemTypeName']
@UI: { lineItem: [{position: 50, importance: #HIGH, qualifier: 'MainContent'}] }
key SubLedgerAcctLineItemType,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_AssetTransKeyFigureSetVH', element: 'AssetAccountingKeyFigureSet' }
} ]
@Consumption.filter.hidden: true
key AssetAccountingKeyFigureSet,
@Consumption.hidden: true
@Consumption.filter.hidden: true
key AssetAccountingKeyFigure,
@ObjectModel.text.element: ['AssetAcctTransClassfctnName']
key AssetAcctTransClassfctn,
@Consumption.valueHelpDefinition: [ { entity: { name: 'C_FiscalYearForCompanyCodeVH', element: 'FiscalYear' },
additionalBinding: [ { localElement: 'CompanyCode', element:'CompanyCode' } ]
} ]
@UI.hidden: true //Root cause: Would be used in navigation from asset accounting overview app
FiscalYear,
@Consumption.hidden: true
LedgerGroup,
FixedAssetExternalID,
cast(GroupMasterFixedAsset as fis_anlgr) as GroupMasterFixedAsset,
cast(GroupFixedAsset as fis_anlgr2) as GroupFixedAsset,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_ChartOfDepreciationVH', element: 'ChartOfDepreciation' } } ]
ChartOfDepreciation,
AccountingDocumentCreationDate,
CreationTime,
cast(PostingDate as fis_budat) as PostingDate,
cast (DocumentDate as fis_bldat) as DocumentDate,
AssetValueDate,
@Consumption.hidden: true
AssetAuthorizationContext,
AssetCapitalizationDate,
AccountingDocCreatedByUser,
@ObjectModel.text.element: ['AssetTransactionTypeName']
@UI.textArrangement: #TEXT_LAST
@UI: { lineItem: [{position: 40, importance: #HIGH, qualifier: 'MainContent'}] }
AssetTransactionType,
@ObjectModel.text.element: ['AssetTransactionVariantName']
AssetTransactionVariant,
AssignmentReference,
DocumentItemText,
ReferenceDocumentType,
@UI: { lineItem: [{position: 30, importance: #HIGH, qualifier: 'MainContent'}] }
ReferenceDocument,
@Consumption.hidden: true
LogicalSystem,
@Consumption.hidden: true
ReferenceDocumentContext,
@Consumption.hidden: true
ReversalReferenceDocumentCntxt,
ReversalReferenceDocument,
ReversalTransactionSubitem,
IsReversal,
IsReversed,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_BusinessAreaStdVH', element: 'BusinessArea' } } ]
cast(BusinessArea as fis_gsber) as BusinessArea,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_SegmentStdVH', element: 'Segment' } } ]
Segment,
FinancialAccountType,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_ControllingAreaStdVH', element: 'ControllingArea' } } ]
ControllingArea,
@UI: { selectionField: [{position: 100}] }
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_AssetClassStdVH', element: 'AssetClass' } } ]
@ObjectModel.text.element: ['AssetClassName']
AssetClass,
Inventory,
@ObjectModel.text.element: ['AssetAccountDeterminationDesc']
AssetAccountDetermination,
/* Amounts */
@Consumption.filter.hidden: true
@Environment.sql.passValue: true
@UI.hidden: true
SelectedCurrencyBranch,
@Consumption.filter.hidden: true
DisplayCurrency,
@DefaultAggregation: #SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
AmountInDisplayCurrency,
@DefaultAggregation: #SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
@UI: { lineItem: [{position: 110, importance: #HIGH, qualifier: 'MainContent'}]
}
AcqnProdnAmtInDspCrcy,
@DefaultAggregation: #SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
@UI: { lineItem: [{position: 120, importance: #HIGH, qualifier: 'MainContent'}]
}
ValueAdjustmentAmtInDspCrcy,
@DefaultAggregation: #SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
RetirementRevenueAmtInDspCrcy,
@DefaultAggregation: #SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
RetirementCostsAmtInDspCrcy,
@DefaultAggregation: #SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
RetirementLossAmtInDspCrcy,
@DefaultAggregation: #SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
RetirementGainAmtInDspCrcy,
@DefaultAggregation: #SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
RetirementDeprAmtInDspCrcy,
@DefaultAggregation: #SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
RetirementAmountInDspCrcy,
@DefaultAggregation: #SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
RtrmtNetBookValueAmtInDspCrcy,
@DefaultAggregation: #SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
OrdinaryDeprAmtInDspCrcy,
@DefaultAggregation: #SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
SpecialDeprAmtInDspCrcy,
@DefaultAggregation: #SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
UnplannedDeprAmtInDspCrcy,
@DefaultAggregation: #SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
TransferredReserveAmtInDspCrcy,
BaseUnit,
@DefaultAggregation: #SUM
@Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
Quantity,
/* Descriptions */
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_CompanyCode.CompanyCodeName,
@Semantics.text
@Search.defaultSearchElement: true
@Search.fuzzinessThreshold: 0.8
@Search.ranking: #HIGH
@ObjectModel.readOnly: true
//@Consumption.filter.hidden: true
cast(FixedAssetDescription as fis_txa50_anlt) as FixedAssetDescription,
@Semantics.text
@Search.defaultSearchElement: true
@Search.fuzzinessThreshold: 0.8
@Search.ranking: #HIGH
@ObjectModel.readOnly: true
@Consumption.filter.hidden: true
_MasterFixedAsset.MasterFixedAssetDescription,
@Semantics.text
@Search.defaultSearchElement: true
@Search.fuzzinessThreshold: 0.8
@Search.ranking: #HIGH
@Consumption.filter.hidden: true
AssetAdditionalDescription,
@Semantics.text
@ObjectModel.readOnly: true
@Consumption.filter.hidden: true
@UI.hidden: true
_AssetPlant.PlantName as AssetPlantName,
/* ANLZ */
@ObjectModel.text.element: ['AssetCostCenterName']
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_CostCenterStdVH', element: 'CostCenter' },
additionalBinding: [ { localElement: 'ControllingArea', element:'ControllingArea' } ]
} ]
@UI.textArrangement: #TEXT_LAST
cast(AssetCostCenter as faa_kostl preserving type) as AssetCostCenter,
@ObjectModel.text.element: ['AssetBusinessAreaName']
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_BusinessAreaStdVH', element: 'BusinessArea' } } ]
cast(AssetBusinessArea as faa_gsber preserving type) as AssetBusinessArea,
@ObjectModel.text.element: ['AssetPlantName']
cast(AssetPlant as faa_werks) as AssetPlant,
@ObjectModel.text.element: ['AssetProfitCenterName']
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProfitCenterStdVH', element: 'ProfitCenter' },
additionalBinding: [ { localElement: 'ControllingArea', element:'ControllingArea' } ]
} ]
cast(AssetProfitCenter as faa_prctr preserving type) as AssetProfitCenter,
@ObjectModel.text.element: ['AssetSegmentName']
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_SegmentStdVH', element: 'Segment' } } ]
cast(AssetSegment as faa_segment preserving type) as AssetSegment,
/* ANLB */
@UI: { selectionField: [{position: 110}] }
@Consumption.valueHelp: '_DepreciationKeyVH'
@ObjectModel.text.element: ['DepreciationKeyName']
DepreciationKey,
PlannedUsefulLifeInYears,
PlannedUsefulLifeInPeriods,
OriglAstUsefulLifeInYears,
OriglAstUsefulLifeInPerds,
DepreciationStartDate,
DeprKeyChangeoverYear,
DeprKeyChangeoverPeriod,
VintageYear,
VintageMonth,
ReplacementValueIndexSers,
RplcmtValueAgingIndexSers,
@ObjectModel.foreignKey.association: null
Country,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_FixedAssetNatlClfn', element: 'NationalClassification' },
additionalBinding: [ { localElement: 'Country', element:'Country' } ]
} ]
@ObjectModel:{foreignKey.association: null, text.element: ['NationalClassificationDesc']}
NationalClassification,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_TaxDepreciationGroup', element: 'TaxDepreciationGroup' },
additionalBinding: [ { localElement: 'Country', element:'Country' } ]
} ]
@ObjectModel:{foreignKey.association: null, text.element: ['TaxDepreciationGroupDesc']}
TaxDepreciationGroup,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_FinMgmtAreaStdVH', element: 'FinancialManagementArea' } } ]
@ObjectModel:{foreignKey.association: null, text.element: ['FinancialManagementAreaName']}
FinancialManagementArea,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_FundStdVH', element: 'Fund' } } ]
@ObjectModel:{foreignKey.association: null, text.element: ['FundDescription']}
Fund,
GrantID,
@ObjectModel:{foreignKey.association: '_FunctionalArea', text.element: ['FunctionalAreaName']}
FunctionalArea,
@ObjectModel:{foreignKey.association: '_BudgetPeriod', text.element: ['BudgetPeriodName']}
BudgetPeriod,
@ObjectModel.text.element: ['AssetLocationName']
AssetLocation,
@Semantics.text
@ObjectModel.readOnly: true
@Consumption.filter.hidden: true
@UI.hidden: true
_AssetLocation.LocationName as AssetLocationName,
//Convert internal ID of WBSElement to external ID
@Consumption.hidden: true
InvestmentProjectWBSElement as WBSElementInternalID,
@Consumption.hidden: true
'' as InvestmentProjectWBSElement,
//_WBSElement.WBSElement as InvestmentProjectWBSElement,
_WBSElement.WBSElementExternalID,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_RU_AssetOKOF', element: 'RU_AssetOKOF' },
additionalBinding: [ { localElement: 'Country', element:'Country' } ]
} ]
@ObjectModel:{foreignKey.association: null, text.element: ['RU_AssetOKOFDesc']}
RU_AssetOKOF,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_RU_AssetDepreciationGroup', element: 'RU_AssetDepreciationGroup' },
additionalBinding: [ { localElement: 'Country', element:'Country' },
{ localElement: 'RU_AssetOKOF', element:'RU_AssetOKOF' } ]
} ]
@ObjectModel:{foreignKey.association: null, text.element: ['RU_AssetDepreciationGroupDesc']}
RU_AssetDepreciationGroup,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_JP_PrptyTxRptCityVH', element: 'JP_PrptyTxRptCity' }
} ]
@ObjectModel:{foreignKey.association: null, text.element: ['JP_PrptyTxRptCityDesc']}
JP_PrptyTxRptCity,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_JP_PrptyTxRptClassfctnKey', element: 'JP_PrptyTxRptClassfctnKey' }
} ]
@ObjectModel:{foreignKey.association: null, text.element: ['JP_PrptyTxRptClassfctnKeyDesc']}
JP_PrptyTxRptClassfctnKey,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_AssetClassText[1: Language = $session.system_language].AssetClassName,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_DepreciationAreaText[1: Language = $session.system_language].AssetDepreciationAreaName,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_AssetTransactionTypeText[1: Language = $session.system_language].AssetTransactionTypeName,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_SubLedgerAccLineItemTypeText[1: Language = $session.system_language].SubLedgerAcctLineItemTypeName,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_LedgerText[1: Language = $session.system_language].LedgerName,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_AssetTransactionVariantText[1: Language = $session.system_language].AssetTransactionVariantName,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_TaxDepreciationGroupText[1: Language = $session.system_language].TaxDepreciationGroupDesc,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_FinancialManagementAreaText[1: Language = $session.system_language].FinancialManagementAreaName,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_FunctionalAreaText[1: Language = $session.system_language].FunctionalAreaName,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_FundText[1: Language = $session.system_language].FundDescription,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_BudgetPeriodText[1: Language = $session.system_language].BudgetPeriodName,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_DepreciationKeyText[1: Language = $session.system_language].DepreciationKeyName,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
cast(_AssetBusinessAreaText[1: Language = $session.system_language].BusinessAreaName as faa_gsber_name) as AssetBusinessAreaName,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
cast(_AssetCostCenterText.CostCenterName as faa_kostl_name) as AssetCostCenterName,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
cast(_AssetProfitCenterText.ProfitCenterName as faa_prctr_name) as AssetProfitCenterName,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
cast(_AssetSegmentText[1: Language = $session.system_language].SegmentName as faa_segment_name) as AssetSegmentName,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_AssetAcctDeterminationText[1: Language = $session.system_language].AssetAccountDeterminationDesc,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_AssetAcctTransClassfctnText[1: Language = $session.system_language].AssetAcctTransClassfctnName,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_FixedAssetNatlClfnText[1: Language = $session.system_language].NationalClassificationDesc,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_RU_AssetOKOFText[1: Language = $session.system_language].RU_AssetOKOFDesc,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_RU_AssetDepreciationGroupText[1: Language = $session.system_language].RU_AssetDepreciationGroupDesc,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_JP_PrptyTxRptCityText[1: Language = $session.system_language].JP_PrptyTxRptCityDesc,
@Semantics.text
@Consumption.filter.hidden: true
@UI.hidden: true
_JP_PrptyTxRptClassfctnKeyText[1: Language = $session.system_language].JP_PrptyTxRptClassfctnKeyDesc,
/* Associations */
@Consumption.filter.hidden: true
_AssetTransactionVariant,
@Consumption.filter.hidden: true
_AssetAcctTransClassfctn,
@Consumption.filter.hidden: true
_AssetTransactionType,
@Consumption.filter.hidden: true
_CompanyCode,
@Consumption.filter.hidden: true
_CurrencyRole,
@Consumption.filter.hidden: true
_DebitCreditCode,
@Consumption.filter.hidden: true
_DepreciationArea,
@Consumption.filter.hidden: true
_FiscalYear,
@Consumption.filter.hidden: true
_FixedAsset,
@Consumption.filter.hidden: true
_LedgerVH,
@Consumption.filter.hidden: true
_LedgerGroup,
@Consumption.filter.hidden: true
_MasterFixedAsset,
@Consumption.filter.hidden: true
_SubLedgerAccLineItemType,
@Consumption.filter.hidden: true
_AssetClass,
@Consumption.filter.hidden: true
_CurrencyRoleVH,
@Consumption.filter.hidden: true
_CompanyCodeVH,
@Consumption.filter.hidden: true
_DepreciationKeyVH,
@Consumption.filter.hidden: true
_FiscCalendarDateForCompCode,
@Consumption.filter.hidden: true
_FiscalCalendarDateForLedger,
@Consumption.filter.hidden: true
_FunctionalArea,
@Consumption.filter.hidden: true
_FinancialManagementArea,
@Consumption.filter.hidden: true
_Fund,
@Consumption.filter.hidden: true
_BudgetPeriod,
@Consumption.filter.hidden: true
_DepreciationKey,
@Consumption.filter.hidden: true
_AssetAccountDetermination,
@Consumption.hidden: true
_AssetRedesignSwitchStatus, //for DCL
@Consumption.filter.hidden: true
_BaseUnit
}