atov_collection_type_import

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Collection type for use at import'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity atov_collection_type_import
  
  // Select all but CBC collections

  as select from    ato_cols                    as col
    left outer join atov_cbc_collections_import as cbc on col.collection_id = cbc.collection_id
{
  key col.collection_id,
      col.collection_type,
      col.category,
      case( col.repository_name )
      when '' then ''
      else 'X'
      end as is_gcts_collection
}
where
  cbc.collection_id is null

union all

// Select only CBC collections

select from atov_cbc_collections_import as cbc
 inner join ato_cols as col on col.collection_id = cbc.collection_id
{
  key cbc.collection_id,
      'X' as collection_type, // CBC

      col.category,
      case( col.repository_name )
      when '' then ''
      else 'X'
      end as is_gcts_collection
}