ATOV_COL_VER_FORWARDABLE_BASE

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Forwardable without QA restriction'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity ATOV_COL_VER_FORWARDABLE_BASE

  as select distinct from ato_col_versions               as Collection_Version
    inner join            ato_cols                       as Collection     on Collection.collection_id = Collection_Version.collection_id
  // Never allow for import/forward status Discarded

    inner join            atov_status_schema_not_discard as Not_Discarded  on  Not_Discarded.collection_id = Collection_Version.collection_id
                                                                           and Not_Discarded.version       = Collection_Version.version
    inner join            atov_collection_type_import    as Col_Type       on Col_Type.collection_id = Collection_Version.collection_id

    inner join            ato_col_v_status               as Import_Status  on  Import_Status.collection_id = Collection_Version.collection_id
                                                                           and Import_Status.version       = Collection_Version.version
                                                                           and Import_Status.status_schema = 'I'
    inner join            ato_type_status                as Type_Status    on  Type_Status.collection_type             = Col_Type.collection_type
                                                                           and Type_Status.status_schema               = 'I'
                                                                           and Type_Status.allowed_status              = Import_Status.status
                                                                           and Type_Status.is_eligible_for_next_schema = 'X'
    inner join            ato_col_v_status               as Forward_Status on  Forward_Status.collection_id = Collection_Version.collection_id
                                                                           and Forward_Status.version       = Collection_Version.version
                                                                           and Forward_Status.status_schema = 'F'

    inner join            ato_statusschema               as Statusschema   on  Statusschema.status_schema   = Forward_Status.status_schema
                                                                           and Statusschema.previous_status = Forward_Status.status
                                                                           and Statusschema.next_status     = 'FS' //Forwarded


    inner join            ato_col_setup                  as setup          on  setup.tms_forwarding <> '' //go directly to designtime for Performance

                                                                           and setup.tms_config     <> ''
                                                                           and setup.timestamp      =  0
{
  key Collection_Version.collection_id,
  /* start suppress warning shlporigin_not_inherited */
  key Collection_Version.version,
  /* end suppress warning shlporigin_not_inherited */
      'X' as is_forwardable_wo_qa
}
where
       Collection_Version.timestamp =  0
  // identical to ATOV_COL_VER_IMP_BASE

  and  Collection.status            <> 'H' // Hidden should not be processed in the UI

  and(
       Collection.client            =  '' //Client independent collections EXT/DEV/CCC

    or Collection.client            = $session.client
  ) //BC and client-dep EXT collections