R_UniversalAllocationSegmentTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Universal Allocation Segment Draft'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #M,
  dataClass: #CUSTOMIZING }
@VDM: { viewType: #TRANSACTIONAL,
        lifecycle.contract.type: #SAP_INTERNAL_API }
define view entity R_UniversalAllocationSegmentTP
  as select from I_UniversalAllocationSegment

  association        to parent R_UniversalAllocationCycleTP as _Cycle           on  $projection.AllocationType           = _Cycle.AllocationType
                                                                                and $projection.AllocationCycle          = _Cycle.AllocationCycle
                                                                                and $projection.AllocationCycleStartDate = _Cycle.AllocationCycleStartDate

  association [0..*] to I_AllocationStructureText           as _StructureText   on  $projection.AllocationStructure = _StructureText.AllocationStructure
  association [0..*] to I_CurrencyText                      as _CurrencyText    on  $projection.AllocationCurrency  = _CurrencyText.Currency
  association [0..*] to R_UnivAllocVirtualKeyField          as _VirtualKeyField on  $projection.AllocationType           = _VirtualKeyField.AllocationType
                                                                                and $projection.AllocationCycle          = _VirtualKeyField.AllocationCycle
                                                                                and $projection.AllocationCycleStartDate = _VirtualKeyField.AllocationCycleStartDate
                                                                                and $projection.AllocationCycleSegment   = _VirtualKeyField.AllocationCycleSegment

  composition [0..*] of R_UnivAllocSenderKeyFieldTP         as _SenderKeyField
  composition [0..*] of R_UnivAllocSndrValKeyFieldTP        as _SenderValueKeyField
  composition [0..*] of R_UnivAllocReceiverKeyFieldTP       as _ReceiverKeyField
  composition [0..*] of R_UnivAllocRcvrFctrKeyFieldTP       as _ReceiverTracingFactorKeyFld
  composition [0..*] of R_UnivAllocReceiverElementTP        as _ReceiverElement
  composition [0..*] of R_UnivAllocSenderElementTP          as _SenderElement
  composition [0..*] of R_UnivAllocRcvrFctrElementTP        as _ReceiverWeightingFactorElem
  composition [0..*] of R_UnivAllocTagSgmtAssignmentTP      as _TagToSegmentAssignment
  composition [0..*] of R_UnivAllocationSegmentTextTP       as _Text

{
  key AllocationType,
  key AllocationCycle,
  key AllocationCycleStartDate,
  key AllocationCycleSegment,

      SegmentName,

      AllocationSegmentPosition,
      AllocationSenderRule,
      AllocationReceiverRule,
      @Semantics.booleanIndicator: true
      AllocationSegmentIsLocked,
      AllocScNgtvTracingFctr,
      SenderTracingFieldGroup,
      SenderFieldGroup,
      ReceiverFieldGroup,
      ReceiverTracingFieldGroup,
      AllocationSenderFixedField1,
      AllocationSenderFixedField2,
      AllocationSenderFixedField3,
      AllocationSenderFixedField4,
      AllocationSenderFixedField5,
      AllocationSenderFixedField6,
      AllocationSenderFixedField7,
      AllocationSenderFixedField8,
      AllocationSenderFixedField9,
      AllocationSenderFixedField10,
      AllocationCurrency,
      AllocationReceiverFixedField1,
      AllocationReceiverFixedField2,
      AllocationReceiverFixedField3,
      AllocationReceiverFixedField4,
      AllocationReceiverFixedField5,
      AllocationReceiverFixedField6,
      AllocationReceiverFixedField7,
      AllocationReceiverFixedField8,
      AllocationReceiverFixedField9,
      AllocationReceiverFixedField10,
      AllocationFieldGroup,
      AssessmentCostElement,
      AllocationFixedCostCenterCost,
      AllocationVariableCostCtrCost,
      AllocationAccountAssignment,
      AllocationSegmentSortField,
      AllocIsSndrExclAsRcvr,
      ManipulationRuleForCyclicMaint,
      AllocationStructure,
      AllocationTransferStructure,
      AllocSndrFctrPercent,
      AllocRcvrFctrPercent,
      AllocSegmentShareInPercent,

      cast( _Note.NoteText as fcoua_segment_note ) as NoteText,
      _Cycle.CycleIsAttributedLineItmEnbld,

      cast('' as fco_tag_id)                       as AllocationTagID,
      cast('' as fco_alloc_reference_ledger)       as AllocationReferenceLedger,
      cast(' ' as boolean)                         as AllocationSenderValueIsNew,

      cast( _VirtualKeyField[1:AllocationFieldName = 'CATEGORY'].AllocationFieldMinimumValue as fcom_category ) as PlanningCategory,
      cast(
      case substring(AllocationFieldGroup, 1, 4)
        when 'VMSL' 
          then _VirtualKeyField[1:AllocationFieldName = 'RVUNIT'].AllocationFieldMinimumValue
        else 
          _VirtualKeyField[1:AllocationFieldName = 'RUNIT'].AllocationFieldMinimumValue
      end as meins )   as UnitOfMeasure,

      _ReceiverRule,
      _SenderRule,
      _SegmentStatus,

      _Cycle,
      _SenderKeyField,
      _SenderValueKeyField,
      _ReceiverKeyField,
      _ReceiverTracingFactorKeyFld,
      _ReceiverElement,
      _SenderElement,
      _ReceiverWeightingFactorElem,
      _TagToSegmentAssignment,
      _Text,
      _StructureText,
      _CurrencyText,
      _AllocationFieldGroupText
}