C_UniversalAllocationSegmentTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.allowExtensions: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #M,
  dataClass: #CUSTOMIZING }
@VDM: {
  viewType: #CONSUMPTION,
  usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE] }
define view entity C_UniversalAllocationSegmentTP
  as projection on R_UniversalAllocationSegmentTP
{
      
  key AllocationType,
  key AllocationCycle,
  key AllocationCycleStartDate,
  key AllocationCycleSegment,
      SegmentName,
      
      AllocationSegmentPosition,
      @ObjectModel.text.element: ['AllocationSenderRuleText']
      AllocationSenderRule,
      @ObjectModel.text.element: ['AllocationReceiverRuleText']
      AllocationReceiverRule,
      @ObjectModel.text.element: ['AllocationStatusDescription']
      AllocationSegmentIsLocked,
      
      SenderTracingFieldGroup,
      SenderFieldGroup,
      ReceiverFieldGroup,
      ReceiverTracingFieldGroup,
      AllocationSenderFixedField1,
      AllocationSenderFixedField2,
      AllocationSenderFixedField3,
      AllocationSenderFixedField4,
      AllocationSenderFixedField5,
      AllocationSenderFixedField6,
      AllocationSenderFixedField7,
      AllocationSenderFixedField8,
      AllocationSenderFixedField9,
      AllocationSenderFixedField10,
      @ObjectModel.text.element: [ 'CurrencyName' ]
      AllocationCurrency,
      AllocationReceiverFixedField1,
      AllocationReceiverFixedField2,
      AllocationReceiverFixedField3,
      AllocationReceiverFixedField4,
      AllocationReceiverFixedField5,
      AllocationReceiverFixedField6,
      AllocationReceiverFixedField7,
      AllocationReceiverFixedField8,
      AllocationReceiverFixedField9,
      AllocationReceiverFixedField10,
      @ObjectModel.text.element: ['AllocFieldGroupRowText']
      AllocationFieldGroup,
      @ObjectModel.text.element: ['CostElementDescription']
      AssessmentCostElement,
      AllocationFixedCostCenterCost,
      AllocationVariableCostCtrCost,
      AllocationAccountAssignment,
      AllocationSegmentSortField,
      AllocIsSndrExclAsRcvr,
      ManipulationRuleForCyclicMaint,
      @ObjectModel.text.element: ['AllocationStructureText']
      AllocationStructure,
      AllocationTransferStructure,
      AllocSndrFctrPercent,
      AllocRcvrFctrPercent,
      AllocSegmentShareInPercent,
      NoteText,
      CycleIsAttributedLineItmEnbld,
      AllocationTagID,
      AllocationReferenceLedger,
      PlanningCategory,
      UnitOfMeasure,
      AllocationSenderValueIsNew,
      
      @ObjectModel: {
        virtualElement: true,
        virtualElementCalculatedBy: 'ABAP:CL_FCO_ALLOC_COST_ELEM_EXIT' }
      virtual CostElementDescription : kltxt,
      
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FCOUA_VIRTUAL_SEGMENT_CALC'
      @ObjectModel.text.element: [ 'AllocScNgtvTracingFctrText' ] 
      AllocScNgtvTracingFctr,      
      
      @UI.hidden: true
      AllocScNgtvTracingFctr as AllocScNgtvTracingFctrInt, 
      
      @ObjectModel: {
        virtualElement: true,
        virtualElementCalculatedBy: 'ABAP:CL_FCOUA_VIRTUAL_SEGMENT_CALC' }
      virtual AllocScNgtvTracingFctrText : char60,
      
      _Cycle.AllocationCycleName,     
      _Cycle.CompanyCode,
      _Cycle.AllocationPostingType,
      _Cycle.AllocationActualPlanVariant,
      _Cycle.Ledger,
      _Cycle._TopDownDistributionTemplate.TopDwnDistrTmplName,
      _Cycle.LanguageCode,
      _SegmentStatus.CriticalityCode,
      _Text.AllocationSegmentDescription : localized,
      _SenderRule._Text.AllocationSenderRuleText : localized,
      _ReceiverRule._Text.AllocationReceiverRuleText : localized,
      _SegmentStatus._Text.AllocationStatusDescription : localized,
      _StructureText.AllocationStructureText : localized,
      _CurrencyText.CurrencyName : localized,
      _AllocationFieldGroupText.AllocFieldGroupRowText : localized,

      _Cycle : redirected to parent C_UniversalAllocationCycleTP,
      _SenderKeyField : redirected to composition child C_UnivAllocSenderKeyFieldTP,
      _ReceiverKeyField : redirected to composition child C_UnivAllocReceiverKeyFieldTP,
      _ReceiverTracingFactorKeyFld : redirected to composition child C_UnivAllocRcvrFctrKeyFieldTP,
      _ReceiverElement : redirected to composition child C_UnivAllocReceiverElementTP,
      _SenderElement : redirected to composition child C_UnivAllocSenderElementTP,
      _SenderValueKeyField : redirected to composition child C_UnivAllocSndrValKeyFieldTP,
      _ReceiverWeightingFactorElem : redirected to composition child C_UnivAllocRcvrFctrElementTP,
      _TagToSegmentAssignment : redirected to composition child C_UnivAllocTagSgmtAssignmentTP,
      _Text : redirected to composition child C_UnivAllocationSegmentTextTP
}