R_TransportationOrderItemTP

@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl: {
  authorizationCheck: #MANDATORY,
  privilegedAssociations: [
    '_TranspOrdItemParentItem',
    '_SourceStop',
    '_DestinationStop'
  ]
}
@EndUserText.label: 'Transportation Order Item - TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass:#TRANSACTIONAL
    },
    semanticKey: ['TranspOrdItem'],
    representativeKey: 'TransportationOrderItemUUID'
}

@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_Extension'],
  elementSuffix: 'TOI',
  quota: {
    maximumFields: 408, //This is calculated with formula - 2* <Customer Percentage from SCFD_REGISTRY> * <max number of fields in SCFD_REGISTRY>

    maximumBytes: 8160  //This is calculated with formula - 4* <Customer Percentage from SCFD_REGISTRY> * <number of chars as defined in SCFD_REGISTRY>

  }
}

define view entity R_TransportationOrderItemTP
  as select from I_TransportationOrderItem_2 as TransportationOrderItem

  composition [0..*] of R_TranspOrdItemSealTP          as _TranspOrdItemSeal
  composition [0..*] of R_TranspOrdItemBatchTP         as _TranspOrdItemBatch
  composition [0..*] of R_TranspOrdItemDocRefTP        as _TranspOrdItemDocRef
  composition [0..*] of R_TranspOrdItemCommodityCodeTP as _TranspOrdItemCommodityCode
  composition [0..*] of R_TrOrdItmMnBPAddrDfltRprstnTP as _TrOrdItmMnBPAddrDfltRprstn
  composition [0..*] of R_TranspOrdItemNoteTP          as _TranspOrdItemNote
  composition [0..*] of R_TranspOrdItemSerialNumberTP  as _TranspOrdItemSerialNumber

  association to parent R_TransportationOrderTP        as _TransportationOrder        on  $projection.TransportationOrderUUID = _TransportationOrder.TransportationOrderUUID
  association [0..1] to R_TrOrdItmMnBPAddrDfltRprstnTP as _ShipperAddrDfltRprstn      on  $projection.TransportationOrderItemUUID            = _ShipperAddrDfltRprstn.TransportationOrderItemUUID
                                                                                      and _ShipperAddrDfltRprstn.TranspOrdBizPartnerFunction = 'U6'
  association [0..1] to R_TrOrdItmMnBPAddrDfltRprstnTP as _ConsigneeAddrDfltRprstn    on  $projection.TransportationOrderItemUUID              = _ConsigneeAddrDfltRprstn.TransportationOrderItemUUID
                                                                                      and _ConsigneeAddrDfltRprstn.TranspOrdBizPartnerFunction = 'WE'
  //Extension Association

  association [1]    to E_TransportationOrderItem      as _Extension                  on  $projection.TransportationOrderItemUUID = _Extension.TransportationOrderItemUUID
{
      /* Attributes */
      // Identification

  key TransportationOrderItem.TransportationOrderItemUUID,
      TransportationOrderItem.TransportationOrderUUID,
      TransportationOrderItem.TranspOrdItem,
      TransportationOrderItem.TranspOrdItemType,
      TransportationOrderItem.TranspOrdItemCategory,

      TransportationOrderItem.TranspOrdItemParentItemUUID,
      TransportationOrderItem.TranspOrdItemDesc,
      @Semantics.booleanIndicator
      TransportationOrderItem.IsMainCargoItem,
      TransportationOrderItem.TranspOrdItemSorting,

      // Locations

      TransportationOrderItem.SourceStopUUID,
      TransportationOrderItem.DestinationStopUUID,

      // Parties

      TransportationOrderItem.ShipperUUID,
      TransportationOrderItem.Shipper,
      TransportationOrderItem.ShipperAddressID,
      TransportationOrderItem.ConsigneeUUID,
      TransportationOrderItem.Consignee,
      TransportationOrderItem.ConsigneeAddressID,

      // Document References

      TransportationOrderItem.FreightUnitUUID,
      TransportationOrderItem.PredecessorTransportationOrder,
      TransportationOrderItem.TranspBaseDocument,
      TransportationOrderItem.TranspBaseDocumentType,
      TransportationOrderItem.TranspBaseDocumentItem,
      TransportationOrderItem.TranspBaseDocumentItemType,

      // Equipment Attributes

      TransportationOrderItem.TransportationEquipmentGroup,
      TransportationOrderItem.TransportationEquipmentType,
      TransportationOrderItem.TranspEquipmentIsShipperOwned,
      TransportationOrderItem.TranspEquipmentPlateNumber,
      TransportationOrderItem.TranspEquipRegistrationCountry,
      @Semantics.quantity.unitOfMeasure: 'TranspEquipCapacityUnit'
      TransportationOrderItem.TranspEquipCapacityLength,
      @Semantics.quantity.unitOfMeasure: 'TranspEquipCapacityUnit'
      TransportationOrderItem.TranspEquipCapacityWidth,
      @Semantics.quantity.unitOfMeasure: 'TranspEquipCapacityUnit'
      TransportationOrderItem.TranspEquipCapacityHeight,
      TransportationOrderItem.TranspEquipCapacityUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspEquipCapacityWeightUnit'
      TransportationOrderItem.TranspEquipCapacityWeight,
      TransportationOrderItem.TranspEquipCapacityWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspEquipCapacityVolumeUnit'
      TransportationOrderItem.TranspEquipCapacityVolume,
      TransportationOrderItem.TranspEquipCapacityVolumeUnit,

      // Package Attributes

      TransportationOrderItem.TranspOrdItemPackageID,

      // Product Attributes

      TransportationOrderItem.ProductUUID,
      TransportationOrderItem.ProductID,
      TransportationOrderItem.MaterialFreightGroup,
      TransportationOrderItem.TransportationGroup,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemTemperatureUnit'
      TransportationOrderItem.TranspOrdItmMinTemp,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemTemperatureUnit'
      TransportationOrderItem.TranspOrdItmMaxTemp,
      TransportationOrderItem.TranspOrdItemTemperatureUnit,

      // Quantities

      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemQuantityUnit'
      TransportationOrderItem.TranspOrdItemQuantity,
      TransportationOrderItem.TranspOrdItemQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemGrossWeightUnit'
      TransportationOrderItem.TranspOrdItemGrossWeight,
      TransportationOrderItem.TranspOrdItemGrossWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemGrossVolumeUnit'
      TransportationOrderItem.TranspOrdItemGrossVolume,
      TransportationOrderItem.TranspOrdItemGrossVolumeUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemNetWeightUnit'
      TransportationOrderItem.TranspOrdItemNetWeight,
      TransportationOrderItem.TranspOrdItemNetWeightUnit,

      // Status

      TransportationOrderItem.TranspOrdItemDngrsGdsSts,

      // (Technical/Hidden) Attributes

      _TransportationOrder.TransportationOrderCategory,

      /* Associations */
      TransportationOrderItem._BusTransDocTypeCode,
      TransportationOrderItem._Consignee,
      TransportationOrderItem._DestinationStop,
      TransportationOrderItem._PrdcssrTransportationOrder,
      TransportationOrderItem._Product,
      TransportationOrderItem._Shipper,
      TransportationOrderItem._SourceStop,
      TransportationOrderItem._TranspOrdItemCategory,
      TransportationOrderItem._TranspOrdItemGrossVolumeUnit,
      TransportationOrderItem._TranspOrdItemGrossWeightUnit,
      TransportationOrderItem._TranspOrdItemNetWeightUnit,
      TransportationOrderItem._TranspOrdItemParentItem,
      TransportationOrderItem._TranspOrdItemQuantityUnit,
      TransportationOrderItem._TranspOrdItemType,
      TransportationOrderItem._TransportationGroup,
      _TransportationOrder,
      _TranspOrdItemSeal,
      _TranspOrdItemSerialNumber,
      @Semantics.valueRange.maximum: '1'
      _TranspOrdItemBatch,
      _TranspOrdItemDocRef,
      _TranspOrdItemCommodityCode,
      _TrOrdItmMnBPAddrDfltRprstn,
      _ShipperAddrDfltRprstn,
      _ConsigneeAddrDfltRprstn,
      _TranspOrdItemNote
}