A_FreightBookingItem

@EndUserText.label: 'Freight Booking Item'
@AccessControl.authorizationCheck: #MANDATORY
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass: #TRANSACTIONAL
    }}
@VDM.viewType: #CONSUMPTION
@OData.entityType.name: 'FreightBookingItem_Type'
@Metadata.ignorePropagatedAnnotations: true

define view entity A_FreightBookingItem
  as projection on R_TransportationOrderItemTP as FreightBookingItem
{
      /* Attributes */
      // Identification

  key TransportationOrderItemUUID,
      TransportationOrderUUID,
      TranspOrdItem,
      @ObjectModel.sapObjectNodeTypeReference: 'TransportationOrderItemType'
      TranspOrdItemType,
      @ObjectModel.sapObjectNodeTypeReference: 'TranspOrderItemCategory'
      TranspOrdItemCategory,

      TranspOrdItemParentItemUUID,
      TranspOrdItemDesc,
      @Semantics.booleanIndicator
      IsMainCargoItem,
      //TransportationMode,  // Transportation Mode is currently not used in Freight Booking Items

      //TransportationModeCategory,

      //TranspMeansOfTransport,  // Means of Transport is currently not used in Freight Booking Items

      TranspOrdItemSorting,

      // Locations

      SourceStopUUID,
      DestinationStopUUID,

      // Parties

      ShipperUUID,
      Shipper,
      ShipperAddressID,
      ConsigneeUUID,
      Consignee,
      ConsigneeAddressID,

      // Document References

      FreightUnitUUID,
      PredecessorTransportationOrder,
      TranspBaseDocument,
      @ObjectModel.sapObjectNodeTypeReference: 'TranspBizTransacDocTypeCode'
      TranspBaseDocumentType,
      TranspBaseDocumentItem,
      @ObjectModel.sapObjectNodeTypeReference: 'TranspBizTransacDocItmTypeCode'
      TranspBaseDocumentItemType,

      // Equipment Attributes

      TransportationEquipmentGroup,
      TransportationEquipmentType,
      TranspEquipmentIsShipperOwned,
      TranspEquipmentPlateNumber,
      TranspEquipRegistrationCountry,
      @Semantics.quantity.unitOfMeasure: 'TranspEquipCapacityUnit'
      TranspEquipCapacityLength,
      @Semantics.quantity.unitOfMeasure: 'TranspEquipCapacityUnit'
      TranspEquipCapacityWidth,
      @Semantics.quantity.unitOfMeasure: 'TranspEquipCapacityUnit'
      TranspEquipCapacityHeight,
      @ObjectModel.sapObjectNodeTypeReference: 'UnitOfMeasure'
      TranspEquipCapacityUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspEquipCapacityWeightUnit'
      TranspEquipCapacityWeight,
      @ObjectModel.sapObjectNodeTypeReference: 'UnitOfMeasure'
      TranspEquipCapacityWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspEquipCapacityVolumeUnit'
      TranspEquipCapacityVolume,
      @ObjectModel.sapObjectNodeTypeReference: 'UnitOfMeasure'
      TranspEquipCapacityVolumeUnit,

      // Package Attributes

      TranspOrdItemPackageID,

      // Product Attributes

      ProductUUID,
      ProductID,
      MaterialFreightGroup,
      TransportationGroup,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemTemperatureUnit'
      TranspOrdItmMinTemp,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemTemperatureUnit'
      TranspOrdItmMaxTemp,
      @ObjectModel.sapObjectNodeTypeReference: 'UnitOfMeasure'
      TranspOrdItemTemperatureUnit,

      // Quantities

      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemQuantityUnit'
      TranspOrdItemQuantity,
      @ObjectModel.sapObjectNodeTypeReference: 'UnitOfMeasure'
      TranspOrdItemQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemGrossWeightUnit'
      TranspOrdItemGrossWeight,
      @ObjectModel.sapObjectNodeTypeReference: 'UnitOfMeasure'
      TranspOrdItemGrossWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemGrossVolumeUnit'
      TranspOrdItemGrossVolume,
      @ObjectModel.sapObjectNodeTypeReference: 'UnitOfMeasure'
      TranspOrdItemGrossVolumeUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemNetWeightUnit'
      TranspOrdItemNetWeight,
      TranspOrdItemNetWeightUnit,

      // Status

      @ObjectModel.sapObjectNodeTypeReference: 'TranspOrdDangerousGoodsStatus'
      TranspOrdItemDngrsGdsSts,

      /* Redirections */
      FreightBookingItem._TransportationOrder        as _FreightBooking                : redirected to parent A_FreightBooking,
      FreightBookingItem._TranspOrdItemDocRef        as _FreightBookingItemDocRef      : redirected to composition child A_FreightBookingItemDocRef,
      FreightBookingItem._TranspOrdItemSeal          as _FreightBookingItemSeal        : redirected to composition child A_FreightBookingItemSeal,
      FreightBookingItem._TranspOrdItemCommodityCode as _FrtBookingItemCommodityCode   : redirected to composition child A_FrtBookingItemCommodityCode,
      FreightBookingItem._TranspOrdItemSerialNumber  as _FrtBookingItemSerialNumber    : redirected to composition child A_FrtBookingItemSerialNumber,
      @Semantics.valueRange.maximum: '1'
      FreightBookingItem._TranspOrdItemBatch         as _FreightBookingItemBatch       : redirected to composition child A_FreightBookingItemBatch,
      FreightBookingItem._TrOrdItmMnBPAddrDfltRprstn as _FrtBkgItmMainBPAddrDfltRprstn : redirected to composition child A_FrtBkgItmMnBPAddrDfltRprstn,
      FreightBookingItem._ShipperAddrDfltRprstn      as _ShipperAddrDfltRprstn         : redirected to A_FrtBkgItmMnBPAddrDfltRprstn,
      FreightBookingItem._ConsigneeAddrDfltRprstn    as _ConsigneeAddrDfltRprstn       : redirected to A_FrtBkgItmMnBPAddrDfltRprstn
}
where
  FreightBookingItem.TransportationOrderCategory = 'BO'