R_StockTransportOrderPartner

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #BASIC
}

@ObjectModel: {
  usageType: {
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #B,
    sizeCategory:   #L
  },

  representativeKey: 'PartnerFunction'
}

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}

@EndUserText.label: 'Partner for Stock Transport Order'

define view entity R_StockTransportOrderPartner
  as select from I_PurchasingDocumentPartner as Partner
    inner join   R_StockTransportOrder       as StockTransportOrder on Partner.PurchasingDocument = StockTransportOrder.StockTransportOrder
    
  association to one R_StockTransportOrder as _StockTransportOrder on $projection.StockTransportOrder = _StockTransportOrder.StockTransportOrder
{
       //Key

       @ObjectModel.foreignKey.association: '_StockTransportOrder'
  key  cast(Partner.PurchasingDocument as vdm_stocktransportorder preserving type) as StockTransportOrder,

  key  cast(Partner.PartnerFunction as parvw_unv preserving type)                  as PartnerFunction,

       Partner.SupplierSubrange,

       Partner.Plant,

       Partner.PurchasingOrganization,

       Partner.PartnerCounter,

       Partner.CreatedByUser,

       Partner.CreationDate,

       Partner.PurchasingDocumentPartnerType, // transient


       Partner.Supplier,

       Partner.SupplierHierarchyCategory,

       Partner.SupplierContact,

       Partner.PersonWorkAgreement,

       Partner.DefaultPartner, // default for a particular Partner function, checkbox on Partner tab in ME21N



       // Associations

       _StockTransportOrder,
       Partner._PurchasingOrganization,
       Partner._Plant,
       Partner._PartnerFunction,
       Partner._PartnerFunctionText,
       Partner._Supplier,
       Partner._SupplierContact,
       Partner._PersonWorkAgreement
}
where
  Partner.PurchasingDocumentItem = '00000'