R_STOCKTRANSPORTORDER

CDS View

Stock Transport Order

R_STOCKTRANSPORTORDER is a CDS View in S/4HANA. Stock Transport Order. It contains 1 fields. 4 CDS views read from this table.

Used by 4 CDS view(s) 1 fields

CDS Views using this table (4)

ViewTypeJoinVDMDescription
R_StockTransportOrderNote view_entity from BASIC Note for Stock Transport Order
R_StockTransportOrderPartner view_entity inner BASIC Partner for Stock Transport Order
R_StockTransportOrderTP view_entity from TRANSACTIONAL Stock Transport Order - TP
R_STOItemPricingElement view_entity inner BASIC Pricing Element for STO Item

Fields (1)

KeyField CDS FieldsUsed in Views
KEY StockTransportOrder StockTransportOrder 1 
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #BASIC
}

@ObjectModel: {
  sapObjectNodeType:{
      name: 'StockTransportOrder'
  },

  usageType: {
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #A,
    sizeCategory:   #L
  },

  representativeKey: 'StockTransportOrder'
}

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}

@EndUserText.label: 'Stock Transport Order'

define view entity R_StockTransportOrder
  as select from R_PurchasingDocument

  association to many R_StockTransportOrderItem as _StockTransportOrderItem on $projection.StockTransportOrder = _StockTransportOrderItem.StockTransportOrder
  
  association [0..*] to I_PurchasingDocumentTypeText   as _StockTransportOrderTypeText     on  _StockTransportOrderTypeText.PurchasingDocumentCategory = 'F' 
                                                                                     and $projection.StockTransportOrderType = _StockTransportOrderTypeText.PurchasingDocumentType 

{
      //Key

  key cast (PurchasingDocument as vdm_stocktransportorder preserving type)              as StockTransportOrder,

      //Category

      cast (PurchasingDocumentType as vdm_stocktransportordertype preserving type)      as StockTransportOrderType,

      //Admin

      CreatedByUser,
      CreationDate,
      cast (PurchasingDocumentOrderDate as vdm_stocktransportorderdate preserving type) as StockTransportOrderDate,
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
      Language,

      //Status

      PurchasingDocumentDeletionCode,
      ReleaseIsNotCompleted,

      //Organization

      @ObjectModel.foreignKey.association: '_CompanyCode'
      CompanyCode,
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      PurchasingOrganization,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      PurchasingGroup,

      @ObjectModel.foreignKey.association: '_Supplier'
      Supplier,
      SupplierRespSalesPersonName,
      SupplierPhoneNumber,
      @ObjectModel.foreignKey.association: '_SupplyingPlant'
      SupplyingPlant,

      //      @Semantics.currencyCode

      @ObjectModel.foreignKey.association: '_DocumentCurrency'
      DocumentCurrency,

      //Incoterms

      @ObjectModel.foreignKey.association: '_IncotermsClassification'
      IncotermsClassification,
      IncotermsTransferLocation,
      @ObjectModel.foreignKey.association: '_IncotermsVersion'
      IncotermsVersion,
      IncotermsLocation1,
      IncotermsLocation2,

      //Intratat

      IsIntrastatReportingRelevant,
      IsIntrastatReportingExcluded,

      LastChangeDateTime,

      VATRegistrationCountry,

      // Address handling

      Customer,
      ManualSupplierAddressID,
      
      // Process Code will be used at the API level

      PurchasingDocumentProcessCode,

      // Associations

      _StockTransportOrderItem,
      _CompanyCode,
      _CreatedByUser,
      _Supplier,
      _PurchasingOrganization,
      _PurchasingGroup,
      _DocumentCurrency,
      _IncotermsClassification,
      _IncotermsVersion,
      _SupplyingPlant,
      _Language
      
      // Text associations for CustomUI

//      _StockTransportOrderTypeText,

//      _DocumentCurrencyText


}
where
      SupplyingPlant                                  <> ''
  and R_PurchasingDocument.PurchasingDocumentCategory =  'F'
  and IsEndOfPurposeBlocked                           =  ''

Learn More