R_SlsOrderWithoutChrgItmTextTP

DDL: R_SLSORDERWITHOUTCHRGITMTEXTTP Type: view_entity TRANSACTIONAL Package: RAP_SD_SLS_SOWC

Sls Ord Without Charge Item Text - TP

R_SlsOrderWithoutChrgItmTextTP is a Transactional CDS View that provides data about "Sls Ord Without Charge Item Text - TP" in SAP S/4HANA. It reads from 3 data sources (P_SalesDocumentItemText, I_SalesDocumentItemBasic, I_SalesDocumentItemCategory) and exposes 17 fields with key fields SalesOrderWithoutCharge, SalesOrderWithoutChargeItem, Language, LongTextID. It has 4 associations to related views. Part of development package RAP_SD_SLS_SOWC.

3 data source(s) 17 fields

Data Sources (3)

SourceAliasJoin Type
P_SalesDocumentItemText P_SalesDocumentItemText from
I_SalesDocumentItemBasic SalesDocumentItemBasic inner
I_SalesDocumentItemCategory SalesDocumentItemCategory inner

Associations (4)

CardinalityTargetAliasCondition
[0..*] I_TextDeterminationProcedItem _TextDeterminationProcedItem $projection.TextDeterminationProcedure = _TextDeterminationProcedItem.TextDeterminationProcedure and $projection.LongTextID = _TextDeterminationProcedItem.LongTextID and _TextDeterminationProcedItem.TextObjectCategory = 'VBBP'
[1..1] R_SalesOrderWithoutChargeTP _SalesOrderWithoutCharge $projection.SalesOrderWithoutCharge = _SalesOrderWithoutCharge.SalesOrderWithoutCharge
[0..1] I_Language _Language $projection.LanguageForEdit = _Language.Language
[0..1] I_SDDocumentItemLongTextID _LongTextID $projection.LongTextIDForEdit = _LongTextID.LongTextID

Annotations (9)

NameValueLevelField
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #TRANSACTIONAL view
ObjectModel.dataCategory #TEXT view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
Metadata.ignorePropagatedAnnotations true view
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label Sls Ord Without Charge Item Text - TP view

Fields (17)

KeyFieldSource TableSource FieldDescription
KEY SalesOrderWithoutCharge
KEY SalesOrderWithoutChargeItem
KEY Language SlsOrderWithoutChargeItemText Language
KEY LongTextID SlsOrderWithoutChargeItemText LongTextID
LongTextIDForEdit SlsOrderWithoutChargeItemText LongTextID
LanguageForEdit SlsOrderWithoutChargeItemText Language
LongText SlsOrderWithoutChargeItemText LongText
TextDeterminationProcedure I_SalesDocumentItemCategory TextDeterminationProcedure
TextDeterminationProcedureItem _TextDeterminationProcedItem TextDeterminationProcedureItem
SalesOrderWithoutChargeType I_SalesDocumentItemBasic SalesDocumentType
OrganizationDivision I_SalesDocumentItemBasic OrganizationDivision
SalesOrganization I_SalesDocumentItemBasic SalesOrganization
DistributionChannel I_SalesDocumentItemBasic DistributionChannel
_Item _Item
_SalesOrderWithoutCharge _SalesOrderWithoutCharge
_Language _Language
_LongTextID _LongTextID 
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@ObjectModel: {
dataCategory: #TEXT,
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}
@ObjectModel.semanticKey: ['SalesOrderWithoutCharge', 'SalesOrderWithoutChargeItem', 'Language', 'LongTextID']

@Metadata.ignorePropagatedAnnotations: true

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

@EndUserText.label: 'Sls Ord Without Charge Item Text - TP'

define view entity R_SlsOrderWithoutChrgItmTextTP
  as select from P_SalesDocumentItemText( P_SAPClient : $session.client ) as SlsOrderWithoutChargeItemText

    inner join   I_SalesDocumentItemBasic                                 as SalesDocumentItemBasic    on  SalesDocumentItemBasic.SalesDocument      = SlsOrderWithoutChargeItemText.SalesDocument
                                                                                                       and SalesDocumentItemBasic.SalesDocumentItem  = SlsOrderWithoutChargeItemText.SalesDocumentItem
                                                                                                       and SalesDocumentItemBasic.SDDocumentCategory = 'I'

    inner join   I_SalesDocumentItemCategory                              as SalesDocumentItemCategory on SalesDocumentItemCategory.SalesDocumentItemCategory = SalesDocumentItemBasic.SalesDocumentItemCategory

  association        to parent R_SlsOrderWithoutChargeItemTP as _Item                        on  $projection.SalesOrderWithoutCharge     = _Item.SalesOrderWithoutCharge
                                                                                             and $projection.SalesOrderWithoutChargeItem = _Item.SalesOrderWithoutChargeItem

  association [0..*] to I_TextDeterminationProcedItem        as _TextDeterminationProcedItem on  $projection.TextDeterminationProcedure          = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                             and $projection.LongTextID                          = _TextDeterminationProcedItem.LongTextID
                                                                                             and _TextDeterminationProcedItem.TextObjectCategory = 'VBBP'

  association [1..1] to R_SalesOrderWithoutChargeTP          as _SalesOrderWithoutCharge     on  $projection.SalesOrderWithoutCharge = _SalesOrderWithoutCharge.SalesOrderWithoutCharge

  association [0..1] to I_Language                           as _Language                    on  $projection.LanguageForEdit = _Language.Language

  association [0..1] to I_SDDocumentItemLongTextID           as _LongTextID                  on  $projection.LongTextIDForEdit = _LongTextID.LongTextID

{
  key cast(SlsOrderWithoutChargeItemText.SalesDocument as sales_order_without_charge preserving type)      as SalesOrderWithoutCharge,

  key cast(SlsOrderWithoutChargeItemText.SalesDocumentItem as sales_order_without_charge_itm preserving type) as SalesOrderWithoutChargeItem,

      @Semantics.language: true
  key SlsOrderWithoutChargeItemText.Language,

  key SlsOrderWithoutChargeItemText.LongTextID,

      @ObjectModel.foreignKey.association: '_LongTextID'
      @ObjectModel.editableFieldFor: 'LongTextID'
      SlsOrderWithoutChargeItemText.LongTextID                                                  as LongTextIDForEdit,

      @ObjectModel.foreignKey.association: '_Language'
      @ObjectModel.editableFieldFor: 'Language'
      SlsOrderWithoutChargeItemText.Language                                                    as LanguageForEdit,

      @ObjectModel.virtualElement: true
      @Semantics.text:true
      SlsOrderWithoutChargeItemText.LongText,

      @Consumption.hidden: true
      SalesDocumentItemCategory.TextDeterminationProcedure,

      _TextDeterminationProcedItem.TextDeterminationProcedureItem                             as TextDeterminationProcedureItem,

      //    For Access control

      @Consumption.hidden: true
      SalesDocumentItemBasic.SalesDocumentType                                                as SalesOrderWithoutChargeType,
      @Consumption.hidden: true
      SalesDocumentItemBasic.OrganizationDivision,
      @Consumption.hidden: true
      SalesDocumentItemBasic.SalesOrganization,
      @Consumption.hidden: true
      SalesDocumentItemBasic.DistributionChannel,

      //     Exposed associations

      _Item,
      _SalesOrderWithoutCharge,
      _Language,
      _LongTextID
}

Learn More