R_SalesOrderWithoutChargeTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_OutputRequest', '_CreatedByUser', '_LastChangedByUser'] }

@ObjectModel: {
    sapObjectNodeType:{
        name: 'SalesOrderWithoutCharge'
    },
    usageType: {
        dataClass:      #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory:   #L
    },
    semanticKey: ['SalesOrderWithoutCharge']
}

@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_Extension'],
  elementSuffix: 'SDH',
  quota: {
    maximumFields: 204,
    maximumBytes: 6800
  }
}

@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Sales Order Without Charge - TP'

define root view entity R_SalesOrderWithoutChargeTP
  as select from         I_SalesOrderWithoutCharge as SalesOrderWithoutCharge
  left outer to one join I_OutputRequest           as OutputRequest on  OutputRequest.OutputControlApplicationObject = SalesOrderWithoutCharge.SalesOrderWithoutCharge
                                                                    and OutputRequest.OutputControlApplObjectType    = 'SALES_DOCUMENT'

  composition [0..*] of R_SlsOrderWithoutChargeItemTP  as _Item
  composition [0..*] of R_SlsOrdWithoutChargePartnerTP as _Partner
  composition [0..*] of R_SlsOrdWithoutChrgPrcgElmntTP as _PricingElement
  composition [0..*] of R_SalesOrderWithoutChrgTextTP  as _Text
  composition [0..1] of R_SlOrWtCrShipToPartyTP        as _ShipToParty
  association [0..1] to R_OutputRequestTP              as _OutputRequest            on  $projection.OutputRequestUUID = _OutputRequest.OutputRequestUUID
  association [0..1] to I_SlsOrdWthoutChrgPartner      as _SoldToParty              on  $projection.SalesOrderWithoutCharge = _SoldToParty.SalesOrderWithoutCharge
                                                                                    and _SoldToParty.PartnerFunction        = 'AG'
  association [0..1] to I_SlsOrganizationDistrChnl     as _SlsOrganizationDistrChnl on  $projection.SalesOrganization   = _SlsOrganizationDistrChnl.SalesOrganization
                                                                                    and $projection.DistributionChannel = _SlsOrganizationDistrChnl.DistributionChannel

  //Extension Association

  association [1]    to E_SalesDocumentBasic           as _Extension                on  $projection.SalesOrderWithoutCharge = _Extension.SalesDocument

{
  key SalesOrderWithoutCharge.SalesOrderWithoutCharge,
      @ObjectModel.foreignKey.association: '_SalesOrderWithoutChargeType'
      SalesOrderWithoutCharge.SalesOrderWithoutChargeType,

      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrderWithoutCharge.SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      SalesOrderWithoutCharge.DistributionChannel,

      _SlsOrganizationDistrChnl.ReferenceDistributionChannel,

      @ObjectModel.foreignKey.association: '_OrganizationDivision'
      SalesOrderWithoutCharge.OrganizationDivision,
      @ObjectModel.foreignKey.association: '_SalesGroup'
      SalesOrderWithoutCharge.SalesGroup,
      @ObjectModel.foreignKey.association: '_SalesOffice'
      SalesOrderWithoutCharge.SalesOffice,

      @ObjectModel.foreignKey.association: '_SalesDistrict'
      SalesOrderWithoutCharge.SalesDistrict,

      @ObjectModel.text.element: ['CustomerName']
      SalesOrderWithoutCharge.SoldToParty,
      @Semantics.text:true
      _SoldToParty.FullName                                                                                         as CustomerName,

      _SoldToParty.AddressID                                                                                        as SoldToPartyAddressID,
      
      @ObjectModel.foreignKey.association: '_CreatedByUser'
      SalesOrderWithoutCharge.CreatedByUser,
      SalesOrderWithoutCharge.CreationDate,
      SalesOrderWithoutCharge.CreationTime,

      cast( dats_tims_to_tstmp( SalesOrderWithoutCharge.CreationDate, SalesOrderWithoutCharge.CreationTime, abap_system_timezone( $session.client, 'NULL' ),
        $session.client, 'NULL' ) as creation_date_time )                                                           as SalesDocumentCreationDateTime,

      @ObjectModel.foreignKey.association: '_LastChangedByUser'
      SalesOrderWithoutCharge.LastChangedByUser,
      SalesOrderWithoutCharge.LastChangeDate,
      case tstmp_is_valid(cast(SalesOrderWithoutCharge.LastChangeDateTime as abap.dec(15,0)))
        when 0 then cast( dats_tims_to_tstmp( SalesOrderWithoutCharge.CreationDate, SalesOrderWithoutCharge.CreationTime, 'UTC', $session.client, 'NULL' ) as last_changed_date_time )
            else cast( SalesOrderWithoutCharge.LastChangeDateTime as last_changed_date_time )
      end                                                                                                           as LastChangeDateTime,

      SalesOrderWithoutCharge.PurchaseOrderByCustomer,
      @ObjectModel.foreignKey.association: '_CustomerPurchaseOrderType'
      SalesOrderWithoutCharge.CustomerPurchaseOrderType,
      SalesOrderWithoutCharge.CustomerPurchaseOrderDate,      
      SalesOrderWithoutCharge.PurchaseOrderByShipToParty,

      @ObjectModel.foreignKey.association: '_CustomerGroup'
      SalesOrderWithoutCharge.CustomerGroup,

      @ObjectModel.foreignKey.association: '_AdditionalCustomerGroup1'
      SalesOrderWithoutCharge.AdditionalCustomerGroup1,
      @ObjectModel.foreignKey.association: '_AdditionalCustomerGroup2'
      SalesOrderWithoutCharge.AdditionalCustomerGroup2,
      @ObjectModel.foreignKey.association: '_AdditionalCustomerGroup3'
      SalesOrderWithoutCharge.AdditionalCustomerGroup3,
      @ObjectModel.foreignKey.association: '_AdditionalCustomerGroup4'
      SalesOrderWithoutCharge.AdditionalCustomerGroup4,
      @ObjectModel.foreignKey.association: '_AdditionalCustomerGroup5'
      SalesOrderWithoutCharge.AdditionalCustomerGroup5,
      
      SalesOrderWithoutCharge.SalesOrderWithoutChargeDate,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesOrderWithoutCharge.TotalNetAmount,
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      SalesOrderWithoutCharge.TransactionCurrency,

      @ObjectModel.foreignKey.association: '_SDDocumentReason'
      SalesOrderWithoutCharge.SDDocumentReason,

      SalesOrderWithoutCharge.PricingDate,
      
      @ObjectModel.foreignKey.association: '_SDPricingProcedure'
      SalesOrderWithoutCharge.SDPricingProcedure,
      
      SalesOrderWithoutCharge.ServicesRenderedDate,
      SalesOrderWithoutCharge.BillingDocumentDate,
      SalesOrderWithoutCharge.FixedValueDate,
      @ObjectModel.foreignKey.association: '_CustomerPriceGroup'
      SalesOrderWithoutCharge.CustomerPriceGroup,

      @ObjectModel.foreignKey.association: '_CustomerPaymentTerms'
      SalesOrderWithoutCharge.CustomerPaymentTerms,

      SalesOrderWithoutCharge.PaymentMethod,

      @ObjectModel.foreignKey.association: '_OverallDeliveryBlockStatus'
      SalesOrderWithoutCharge.OverallDeliveryBlockStatus,

      @ObjectModel.foreignKey.association: '_OverallBillingBlockStatus'
      SalesOrderWithoutCharge.OverallBillingBlockStatus,
      
      @ObjectModel.foreignKey.association: '_OverallDeliveryStatus'
      SalesOrderWithoutCharge.OverallDeliveryStatus,

      @ObjectModel.foreignKey.association: '_HdrGeneralIncompletionStatus'
      cast(SalesOrderWithoutCharge.HdrGeneralIncompletionStatus as hdr_general_incompltn_status preserving type )   as HdrGeneralIncompletionStatus,


      @ObjectModel.foreignKey.association: '_OvrlItmGeneralIncompletionSts'
      cast(SalesOrderWithoutCharge.OvrlItmGeneralIncompletionSts as itms_ovrl_incompletion_status preserving type ) as OvrlItmGeneralIncompletionSts,

      @ObjectModel.foreignKey.association: '_SalesDocApprovalStatus'
      SalesOrderWithoutCharge.SalesDocApprovalStatus,

      @ObjectModel.foreignKey.association: '_OverallChmlCmplncStatus'
      SalesOrderWithoutCharge.OverallChmlCmplncStatus,

      @ObjectModel.foreignKey.association: '_OverallDangerousGoodsStatus'
      SalesOrderWithoutCharge.OverallDangerousGoodsStatus,

      @ObjectModel.foreignKey.association: '_OvrlSftyDataSheetSts'
      SalesOrderWithoutCharge.OverallSafetyDataSheetStatus,

      @ObjectModel.foreignKey.association: '_OvrlTradeCmplncEmbargoStatus'
      SalesOrderWithoutCharge.OverallTrdCmplncEmbargoSts,

      @ObjectModel.foreignKey.association: '_OvTrdCmplncSnctndListChkSts'
      cast(SalesOrderWithoutCharge.OvrlTrdCmplncSnctndListChkSts as totwatchlistscrngchksts preserving type )       as OvrlTrdCmplncSnctndListChkSts,

      @ObjectModel.foreignKey.association: '_OvrlTrdCmplncLegalCtrlChkSts'
      SalesOrderWithoutCharge.OvrlTrdCmplncLegalCtrlChkSts,

      @ObjectModel.foreignKey.association: '_ControllingArea'
      SalesOrderWithoutCharge.ControllingArea,

      SalesOrderWithoutCharge.RequestedDeliveryDate,

      @ObjectModel.foreignKey.association: '_ShippingCondition'
      SalesOrderWithoutCharge.ShippingCondition,
      SalesOrderWithoutCharge.CompleteDeliveryIsDefined,
      SalesOrderWithoutCharge.OrderCombinationIsAllowed,
      @ObjectModel.foreignKey.association: '_ShippingType'
      SalesOrderWithoutCharge.ShippingType,

      @ObjectModel.foreignKey.association: '_DeliveryBlockReason'
      SalesOrderWithoutCharge.DeliveryBlockReason,

      @ObjectModel.foreignKey.association: '_HeaderBillingBlockReason'
      SalesOrderWithoutCharge.HeaderBillingBlockReason,

      @ObjectModel.foreignKey.association: '_SlsOrdWthoutChrgApprvlReason'
      SalesOrderWithoutCharge.SlsOrdWthoutChrgApprvlReason,

      @ObjectModel.foreignKey.association: '_BillingCompanyCode'
      SalesOrderWithoutCharge.BillingCompanyCode,  
      
      @ObjectModel.foreignKey.association: '_IncotermsClassification'
      SalesOrderWithoutCharge.IncotermsClassification,
      //      IncotermsTransferLocation,

      SalesOrderWithoutCharge.IncotermsLocation1,
      SalesOrderWithoutCharge.IncotermsLocation2,
      @ObjectModel.foreignKey.association: '_IncotermsVersion'
      SalesOrderWithoutCharge.IncotermsVersion,

      //      CostCenter,


      SalesOrderWithoutCharge.ReferenceSDDocument,
      @ObjectModel.foreignKey.association: '_ReferenceSDDocumentCategory'
      SalesOrderWithoutCharge.ReferenceSDDocumentCategory,
      SalesOrderWithoutCharge.AccountingDocExternalReference,

      // Status

      @ObjectModel.foreignKey.association: '_OverallSDProcessStatus'
      SalesOrderWithoutCharge.OverallSDProcessStatus,
      @ObjectModel.foreignKey.association: '_OverallSDDocumentRejectionSts'
      SalesOrderWithoutCharge.OverallSDDocumentRejectionSts,
      @ObjectModel.foreignKey.association: '_TotalBlockStatus'
      SalesOrderWithoutCharge.TotalBlockStatus,
      @ObjectModel.foreignKey.association: '_OverallSDDocReferenceStatus'
      SalesOrderWithoutCharge.OverallSDDocReferenceStatus,

      OutputRequest.OutputRequestUUID,
      
      // Compositions

      _Item,
      _Partner,
      _PricingElement,
      _Text,
      _ShipToParty,
      
      //Re-use RAP associations

      _OutputRequest,
      
      // Associations

      SalesOrderWithoutCharge._SalesOrderWithoutChargeType,
      SalesOrderWithoutCharge._OrganizationDivision,
      SalesOrderWithoutCharge._CreatedByUser,      
      SalesOrderWithoutCharge._CustomerPriceGroup,
      SalesOrderWithoutCharge._LastChangedByUser,
      SalesOrderWithoutCharge._CustomerGroup,
      SalesOrderWithoutCharge._TransactionCurrency,
      SalesOrderWithoutCharge._IncotermsClassification,
      SalesOrderWithoutCharge._IncotermsVersion,
      SalesOrderWithoutCharge._CustomerPaymentTerms,
      SalesOrderWithoutCharge._OverallBillingBlockStatus,
      SalesOrderWithoutCharge._OverallDeliveryBlockStatus,
      SalesOrderWithoutCharge._OverallDeliveryStatus,
      SalesOrderWithoutCharge._HdrGeneralIncompletionStatus,
      SalesOrderWithoutCharge._OvrlItmGeneralIncompletionSts,
      SalesOrderWithoutCharge._SalesDocApprovalStatus,
      SalesOrderWithoutCharge._OverallChmlCmplncStatus,
      SalesOrderWithoutCharge._OverallDangerousGoodsStatus,
      SalesOrderWithoutCharge._OvrlSftyDataSheetSts,
      SalesOrderWithoutCharge._OvrlTradeCmplncEmbargoStatus,
      SalesOrderWithoutCharge._OvTrdCmplncSnctndListChkSts,
      SalesOrderWithoutCharge._OvrlTrdCmplncLegalCtrlChkSts,
      SalesOrderWithoutCharge._ControllingArea,
      SalesOrderWithoutCharge._SDDocumentReason,
      SalesOrderWithoutCharge._SDPricingProcedure,
      SalesOrderWithoutCharge._ShippingCondition,
      SalesOrderWithoutCharge._ShippingType,
      SalesOrderWithoutCharge._BillingCompanyCode,
      SalesOrderWithoutCharge._HeaderBillingBlockReason,
      SalesOrderWithoutCharge._DeliveryBlockReason,
      SalesOrderWithoutCharge._SlsOrdWthoutChrgApprvlReason,
      SalesOrderWithoutCharge._OverallSDProcessStatus,
      SalesOrderWithoutCharge._OverallSDDocumentRejectionSts,
      SalesOrderWithoutCharge._TotalBlockStatus,
      SalesOrderWithoutCharge._OverallSDDocReferenceStatus,
      SalesOrderWithoutCharge._SalesOrganization,
      SalesOrderWithoutCharge._DistributionChannel,
      SalesOrderWithoutCharge._SalesGroup,
      SalesOrderWithoutCharge._SalesOffice,
      SalesOrderWithoutCharge._SalesDistrict,
      SalesOrderWithoutCharge._CustomerPurchaseOrderType,
      SalesOrderWithoutCharge._ReferenceSDDocumentCategory,
      SalesOrderWithoutCharge._AdditionalCustomerGroup1,
      SalesOrderWithoutCharge._AdditionalCustomerGroup2,
      SalesOrderWithoutCharge._AdditionalCustomerGroup3,
      SalesOrderWithoutCharge._AdditionalCustomerGroup4,
      SalesOrderWithoutCharge._AdditionalCustomerGroup5

}