R_ServiceDocumentTP

@AbapCatalog: {
  sqlViewName: 'RSRVCDOCUMENTTP',
  compiler.compareFilter: true,
  preserveKey: true

}

@EndUserText.label: 'Transaction Processing: Service Header'

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API,
  lifecycle.status: #DEPRECATED
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@Metadata: {
  ignorePropagatedAnnotations: true
}
@ClientHandling: {
  algorithm: #SESSION_VARIABLE
}

@ObjectModel: {
  // this will make the title column bold in smart templates

  // and description and ID are displayed in two lines when using annotation @ObjectModel.text.element

  semanticKey: ['ServiceDocument'],
  representativeKey: 'ServiceDocument',
  usageType: {serviceQuality: #C, sizeCategory: #XXL, dataClass: #MIXED}
}

define root view R_ServiceDocumentTP
  as select from I_ServiceDocumentEnhcd
  composition [0..*] of R_ServiceDocumentItemTP        as _ServiceDocumentItemTP

  association [0..*] to I_ServiceDocumentSuccessor     as _ServiceDocumentSuccessor     on  $projection.ServiceDocumentUUID = _ServiceDocumentSuccessor.ServiceDocumentUUID
                                                                                        and $projection.ServiceObjectType   = _ServiceDocumentSuccessor.ServiceObjectType

  association [1]    to I_BusinessPartner                 as _ServiceDocCreatedBy       on  $projection.ServiceDocumentCreatedByUser = _ServiceDocCreatedBy.BusinessPartner
  association [1]    to I_BusinessPartner                 as _ServiceDocChangedBy       on  $projection.ServiceDocumentChangedByUser = _ServiceDocChangedBy.BusinessPartner


  association [0..1] to I_SrvcMgmtBPQuickView_2        as _SrvcDocBPSoldToParty         on  $projection.SoldToParty = _SrvcDocBPSoldToParty.BusinessPartner
  association [0..1] to I_SrvcMgmtBPQuickView_2        as _SrvcDocBPContactCard         on  $projection.ContactPerson = _SrvcDocBPContactCard.BusinessPartner
  association [0..1] to I_SrvcMgmtBPQuickView_2        as _SrvcDocBPRespEmployee        on  $projection.ResponsibleEmployee = _SrvcDocBPRespEmployee.BusinessPartner

  association [1]    to I_SrvcDocErrorStatusVH            as _ServiceDocHasError        on  $projection.ServiceDocumentHasError = _ServiceDocHasError.ServiceDocumentHasError


  association [0..1] to E_ServiceDocument              as _ServiceDocumentExt           on  $projection.ServiceObjectType = _ServiceDocumentExt.ServiceCategory
                                                                                        and $projection.ServiceDocument   = _ServiceDocumentExt.ServiceOrder

  //  association [0..1] to I_SrvcDocHdrRelForBillgSts    as _SrvcDocHdrRelForBillgSts on  $projection.ServiceDocIsReleasedForBilling = _SrvcDocHdrRelForBillgSts.SrvcOrdReldForBillingStatus


  association [0..1] to I_StatusObjectUUIDStatus       as _SrvcDocSystemStatus          on  $projection.ServiceDocumentUUID     = _SrvcDocSystemStatus.StatusObjectUUID
                                                                                        and (
                                                                                           _SrvcDocSystemStatus.StatusCode      = 'I1002'
                                                                                           or _SrvcDocSystemStatus.StatusCode   = 'I1003'
                                                                                           or _SrvcDocSystemStatus.StatusCode   = 'I1004'
                                                                                           or _SrvcDocSystemStatus.StatusCode   = 'I1005'
                                                                                         )
                                                                                        and _SrvcDocSystemStatus.StatusIsActive = 'X'

  association [0..1] to I_CustMgmtLifecycleUserStsText as _CustMgmtLifecycleUserStsText on  $projection.ServiceDocumentStatus      = _CustMgmtLifecycleUserStsText.CustMgmtLifecycleUserStatus
                                                                                        and _CustMgmtLifecycleUserStsText.Language = $session.system_language

{
      @ObjectModel.foreignKey.association: '_ServiceObjType'
  key ServiceObjectType,
  key ServiceDocument,

      ServiceDocumentUUID,

      @Semantics.uuid: true
      ServiceDocumentCharUUID,

      ServiceDocumentDescription,

      @ObjectModel.foreignKey.association: '_ServiceDocumentType'
      ServiceDocumentType,

      @ObjectModel.foreignKey.association: '_ServiceDocumentStatus'
      //@ObjectModel.text.association: '_ServiceDocumentStatusText'

      ServiceDocumentStatus,

      case
           when _ServiceDocumentType.StatusProfile <> '' and _CustMgmtLifecycleUserStsText.CustMgmtLifecycleUserStatus <> ''
            then _CustMgmtLifecycleUserStsText.CustMgmtLifecycleUserStsName
           when _ServiceDocumentType.StatusProfile = ''
            then _ServiceDocumentStatus._ServiceDocumentStatusText[1:Language = $session.system_language].ServiceDocumentStatusName
           else _ServiceDocumentStatus._ServiceDocumentStatusText[1:Language = $session.system_language].ServiceDocumentStatusName
       end                            as ServiceDocumentStatusName,


      @ObjectModel.foreignKey.association: '_ServiceDocumentPriority'
      ServiceDocumentPriority,

      @ObjectModel.foreignKey.association: '_RespEmployee'
      ResponsibleEmployee,

      @ObjectModel.foreignKey.association: '_SoldToParty'
      SoldToParty,

      @ObjectModel.foreignKey.association: '_ContactPerson'
      ContactPerson,

      //@ObjectModel.foreignKey.association: '_ServiceDocHasError'

      @Semantics.booleanIndicator: true
      ServiceDocumentHasError,

      //Amount

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      @Semantics.currencyCode:true
      TransactionCurrency             as TransactionCurrency,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocNetAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocGrossAmount,


      ServiceDocumentCreationDate,
      ServiceDocumentChangedDate,
      PostingDate,
      ServiceDocumentCreatedByUser,
      ServiceDocumentChangedByUser,
      @Semantics.booleanIndicator: true
      ServiceDocumentIsQuotation,
      SrvcDocIsMaintServiceOrder,

      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrganization,
      @ObjectModel.foreignKey.association: '_SalesOffice'
      SalesOffice,
      @ObjectModel.foreignKey.association: '_SalesGroup'
      SalesGroup,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,
      @ObjectModel.foreignKey.association: '_Division'
      Division,


      //Fields required for MCSO,

      RequestedServiceStartDate,
      RequestedServiceEndDate,

      @ObjectModel.foreignKey.association: '_BillToParty'
      BillToParty,
      @ObjectModel.foreignKey.association: '_ShipToParty'
      ShipToParty,
      @ObjectModel.foreignKey.association: '_PayerParty'
      PayerParty,

      SoldToPartyCountry,
      SoldToPartyRegion,

      @ObjectModel.foreignKey.association: '_ServiceDocBillingStatus'
      ServiceDocBillingStatus,
      //      @ObjectModel.foreignKey.association: '_SrvcDocIsRelForBillgSts'

      @Semantics.booleanIndicator: true
      ServiceDocIsReleasedForBilling,
      @Semantics.booleanIndicator: true
      ServiceDocumentIsRejected,
      @Semantics.booleanIndicator: true
      ServiceDocumentIsReleased,
      @API.element.releaseState: #DEPRECATED
      MaintSrvcOrdExecutionStatus,
      ServiceTeam,


      // For Authorization


      //      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit'

      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit_2'
      SalesOfficeOrgUnitID,

      //      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit'

      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit_2'
      SalesOrganizationOrgUnitID,

      //      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit'

      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit_2'
      SalesGroupOrgUnitID,

      //      @ObjectModel.foreignKey.association: '_ServiceOrganizationOrgUnit'

      @ObjectModel.foreignKey.association: '_ServiceOrganizationOrgUnit_2'
      ServiceOrganization,

      case ServiceDocumentHasError
         when 'X' then 1
        when ' ' then 0
         else 0
       end                            as BusSolnOrdErrorStsCriticality,


      //External Reference Number

      PurchaseOrderByCustomer,

      _SrvcDocSystemStatus.StatusCode as SystemStatus,

      /* Associations */
      _ServiceDocumentItemTP,

      _ServiceObjType,
      _ServiceDocumentPriority,
      _ServiceDocumentStatus,
      _SrvcDocIsRelForBillgSts,
      _ServiceDocBillingStatus,
      _RespEmployee,
      _SoldToParty,
      _ContactPerson,
      //_ServiceDocHasError,


      /* Required for DCL */
      _ServiceDocumentType,
      _SalesOrganization,
      _SalesOffice,
      _SalesGroup,
      _DistributionChannel,
      _Division,
      _ServiceDocumentSuccessor,
      _TransactionCurrency,
      _ServiceDocCreatedBy,
      _ServiceDocChangedBy,
      _SrvcDocBPSoldToParty,
      _SrvcDocBPContactCard,
      _SrvcDocBPRespEmployee,
      _ServiceDocHasError,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_SalesOrganizationOrgUnit_2'
      _SalesOrganizationOrgUnit,

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_SalesOfficeOrgUnit_2'
      _SalesOfficeOrgUnit,

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_SalesGroupOrgUnit_2'
      _SalesGroupOrgUnit,

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_ServiceOrganizationOrgUnit_2'
      _ServiceOrganizationOrgUnit,

      _SalesOrganizationOrgUnit_2,
      _SalesOfficeOrgUnit_2,
      _SalesGroupOrgUnit_2,
      _ServiceOrganizationOrgUnit_2,

      // _SrvcDocErrSts

      _BillToParty,
      _ShipToParty,
      _PayerParty,
      _SoldToPartyCountry,
      _SoldToPartyRegion,
      _ServiceTeam,
      _SrvcDocSystemStatus
      // _CustMgmtLifecycleUserStsText


      //      _SrvcDocHdrRelForBillgSts

            
}