R_ServiceDocumentItemTP

@AbapCatalog.sqlViewName: 'RSRVCDOCITEMTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@EndUserText.label: 'Transaction Process: Service Item'

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API,
  lifecycle.status: #DEPRECATED
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@Metadata: {
  ignorePropagatedAnnotations: true
}
@ClientHandling: {
  algorithm: #SESSION_VARIABLE
}

@ObjectModel: {
   representativeKey: 'ServiceDocumentItem',
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #C,
     sizeCategory:   #XXL
   }
}

define view R_ServiceDocumentItemTP
  as select from I_ServiceDocumentItemEnhcd as ServiceDocumentItemEnhcd
 
  // composition [0..*] of R_ServiceDocumentTextTP as _ServiceDocumentItemTextTP

  left outer to one join  I_BusSolnOrdItmFUPEntProject   as EnterpriseProjectItem   on EnterpriseProjectItem.BusSolnOrderItemCharUUID = ServiceDocumentItemEnhcd.ServiceDocumentItemCharUUID
  
  left outer to one join  I_EnterpriseProject as ProjectItems on EnterpriseProjectItem.Project = ProjectItems.Project
  left outer to one join I_PPM_ProjProcessingStsTxt as ProcessingStsTxt  on ProcessingStsTxt.ProcessingStatus = ProjectItems.ProcessingStatus
                                                                          and ProcessingStsTxt.LanguageCode = $session.system_language
                                                                          
   left outer to one join I_CustMgmtPartner as _ProjectManager on ServiceDocumentItemEnhcd.ServiceDocument = _ProjectManager.CustMgmtDocument 
                                                             and ServiceDocumentItemEnhcd.ServiceDocumentItem = _ProjectManager.CustMgmtDocumentItem
                                                             and _ProjectManager.CustMgmtObjectType ='BUS2000172'
                                                             and _ProjectManager.CustMgmtPartnerFunction = 'PROJM001'
                                                              

  
  association  to parent R_ServiceDocumentTP as _ServiceDocumentTP on  $projection.ServiceObjectType = _ServiceDocumentTP.ServiceObjectType
                                                                         and $projection.ServiceDocument   = _ServiceDocumentTP.ServiceDocument

  association [0..1] to E_ServiceDocumentItem      as _ServiceDocItemExt on  $projection.ServiceObjectType   = _ServiceDocItemExt.ServiceCategory
                                                                         and $projection.ServiceDocument     = _ServiceDocItemExt.ServiceOrderItem
                                                                         and $projection.ServiceDocumentItem = _ServiceDocItemExt.ServiceLineExternalID

  association [0..1] to I_StatusObjectUUIDStatus       as _SrvcDocSystemStatus      on  $projection.ServiceDocumentItemUUID   = _SrvcDocSystemStatus.StatusObjectUUID
                                                                                    and (
                                                                                           _SrvcDocSystemStatus.StatusCode      = 'I1002'
                                                                                           or _SrvcDocSystemStatus.StatusCode   = 'I1003'
                                                                                           or _SrvcDocSystemStatus.StatusCode   = 'I1004'
                                                                                           or _SrvcDocSystemStatus.StatusCode   = 'I1005'
                                                                                         )
                                                                                    and _SrvcDocSystemStatus.StatusIsActive = 'X'
                                                                        
{
      @ObjectModel.foreignKey.association: '_ServiceObjType'
  key ServiceDocumentItemEnhcd.ServiceObjectType,
      @ObjectModel.foreignKey.association: '_ServiceDocument'
  key ServiceDocument,
  key ServiceDocumentItem,

      @ObjectModel.foreignKey.association: '_ServiceDocumentType'
      ServiceDocumentItemEnhcd.ServiceDocumentType,

      /* Added fields */
      ServiceDocumentItemDescription,
      ServiceDocumentItemUUID,
      @Semantics.uuid:true
      ServiceDocumentItemCharUUID,
     ServiceDocumentItemEnhcd. ServiceDocumentItemObjectType,
      @Semantics.quantity.unitOfMeasure: 'ServiceDocItemQuantityUnit'
      ServiceDocumentItemQuantity,
      ServiceDocItemQuantityUnit,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocumentItemNetAmount,
      ServiceDocItemCategory,

      OriginallyRequestedProduct,
      @API.element.releaseState: #DEPRECATED
      MaintSrvcOrdExecutionStatus,
      
      @ObjectModel.foreignKey.association: '_RespEmployee'
      ServiceDocumentItemEnhcd.ResponsibleEmployee,

      BillToParty,
      PayerParty,
      ShipToParty,
      ServiceTeam,

      @ObjectModel.foreignKey.association: '_SalesOrganization'
      ServiceDocumentItemEnhcd.SalesOrganization,
      @ObjectModel.foreignKey.association: '_SalesOffice'
      ServiceDocumentItemEnhcd.SalesOffice,
      @ObjectModel.foreignKey.association: '_SalesGroup'
      ServiceDocumentItemEnhcd.SalesGroup,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      ServiceDocumentItemEnhcd.DistributionChannel,
      @ObjectModel.foreignKey.association: '_Division'
      ServiceDocumentItemEnhcd.Division,
      @ObjectModel.foreignKey.association: '_SrvcDocItmLifecycleStatus'
      ServiceDocumentItemEnhcd.ServiceDocumentItemStatus,

     // For Authorization


      //      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit'

      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit_2'
      ServiceDocumentItemEnhcd.SalesOfficeOrgUnitID,

      //      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit'

      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit_2'
     ServiceDocumentItemEnhcd.SalesOrganizationOrgUnitID,

      //      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit'

      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit_2'
      ServiceDocumentItemEnhcd.SalesGroupOrgUnitID,

      //      @ObjectModel.foreignKey.association: '_ServiceOrganizationOrgUnit'

      @ObjectModel.foreignKey.association: '_ServiceOrganizationOrgUnit_2'
      ServiceDocumentItemEnhcd.ServiceOrganization,


      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      @Semantics.currencyCode:true
      ServiceDocumentItemEnhcd.TransactionCurrency as TransactionCurrency,
      
      // Project Related fields required for Situation Related information

      EnterpriseProjectItem.Project as Project,
      
      ProjectItems.ProjectStartDate as ProjectStartDate,
      
      ProjectItems.ProjectEndDate  as ProjectEndDate,
      
      ProcessingStsTxt.ProcessingStatusText as ProcessingStatusText,
      
     // BusinessPartner.BusinessPartnerName as ProjectManagerName,      


      //2011CE: Fields for Item object page and Situation

      //ServiceDocItemCategory, -> used

      // ServiceDocumentItemStatus,-> used

      ServiceDocumentItemEnhcd.LtstConfirmedDeliveryDateTime,
      ServiceDocumentItemEnhcd.SrvcDocItmDeliveryStatus,
      ServiceDocumentItemEnhcd.PlannedServiceStartDateTime,
      ServiceDocumentItemEnhcd.PlannedServiceEndDateTime,
      ServiceDocumentItemEnhcd.RequestedServiceStartDateTime,
      ServiceDocumentItemEnhcd.RequestedServiceEndDateTime,
      ServiceDocumentItemEnhcd.ServiceContractItemStartDate,
      ServiceDocumentItemEnhcd.ServiceContractItemEndDate,
      ServiceDocumentItemEnhcd.SoldToParty,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocumentItemEnhcd.ServiceDocItemGrossAmount,

      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      _ServiceDocumentTP.ServiceDocNetAmount,
      
      _SrvcDocSystemStatus.StatusCode                                                                               as SystemStatus,
      
      ServiceDocumentItemEnhcd._ServiceObjType,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_SrvcDocItmLifecycleStatus'
      ServiceDocumentItemEnhcd._ServiceDocItemStatus,
      ServiceDocumentItemEnhcd._SrvcDocItmLifecycleStatus,      
      ServiceDocumentItemEnhcd._ServiceDocument,
      ServiceDocumentItemEnhcd._ServiceDocItemCategory,   

      /* Associations */
      _ServiceDocumentTP,
     ServiceDocumentItemEnhcd._ServiceDocItemRefObj,
      //   _ServiceDocumentItemTextTP,

      
      //Expose association for Project for situation 

 //     _SolutionOrderItemSitn,

 //     _ProjectItems,


      /* Required for DCL */
      ServiceDocumentItemEnhcd._ServiceDocumentType,
      ServiceDocumentItemEnhcd._RespEmployee,
      ServiceDocumentItemEnhcd._SalesOrganization,
      ServiceDocumentItemEnhcd._SalesOffice,
      ServiceDocumentItemEnhcd._SalesGroup,
      ServiceDocumentItemEnhcd._DistributionChannel,
      ServiceDocumentItemEnhcd._Division,
      ServiceDocumentItemEnhcd._TransactionCurrency,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_SalesOrganizationOrgUnit_2'
      ServiceDocumentItemEnhcd._SalesOrganizationOrgUnit,

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_SalesOfficeOrgUnit_2'
      ServiceDocumentItemEnhcd._SalesOfficeOrgUnit,

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_SalesGroupOrgUnit_2'
      ServiceDocumentItemEnhcd._SalesGroupOrgUnit,

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_ServiceOrganizationOrgUnit_2'
      ServiceDocumentItemEnhcd._ServiceOrganizationOrgUnit,

      ServiceDocumentItemEnhcd._SalesOrganizationOrgUnit_2,
      ServiceDocumentItemEnhcd._SalesOfficeOrgUnit_2,
      ServiceDocumentItemEnhcd._SalesGroupOrgUnit_2,
      ServiceDocumentItemEnhcd._ServiceOrganizationOrgUnit_2,
      ServiceDocumentItemEnhcd._SoldToParty,
      _SrvcDocSystemStatus
//      _SrvcDocItmCustMgmtLCUsrStsTxt

      
    //  _BusinessPartner,

     // _ProjectTeamMember

}