R_SecurityClassTP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: [ '_ChangeDocument' ]
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #M,
  dataClass: #MASTER
}
@EndUserText.label: 'Security Class'
@ObjectModel.representativeKey: 'SecurityClass'
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@ObjectModel.sapObjectNodeType.name: 'SecurityClass'
define root view entity R_SecurityClassTP
  as select from I_SecurityClass
  composition [0..*] of R_SecurityClSecondaryIndexTP   as _SecurityClSecondaryIndex
  composition [0..*] of R_SecurityClassRatingTP        as _SecurityClassRating
  composition [0..*] of R_SecurityClPayInPriceRateTP   as _SecurityClPayInPriceRate
  composition [0..*] of R_SecurityClassConditionTP     as _SecurityClassCondition
  composition [0..*] of R_SecurityClassSPPITP          as _SecurityClassSPPI
  composition [0..*] of R_InstlmntBondPrtnAssignmentTP as _InstlmntBondPrtnAssignment
  composition [0..*] of R_BondRedemptionScheduleTP     as _BondRedemptionSchedule
  composition [0..*] of R_SecurityClassExchangeTP      as _SecurityClassExchange
  composition [0..*] of R_SecuritySwapTP               as _SecuritySwap
  composition [1..1] of R_SecurityClConditionHeaderTP  as _SecurityClassConditionHeader
  composition [1..1] of R_SecurityClRgtyRptgHeaderTP   as _SecurityClRgtyRptgHeader
  composition [0..*] of R_ScrtyClSubscrpnPeriodTP      as _ScrtyClSubscrpnPeriod
  composition [0..*] of R_SecurityClassConditionTP_2   as _SecurityClassCondition_2
  composition [0..1] of R_ScrtyClConditionHeaderTP_2   as _SecurityClConditionHeader_2

  association [0..1] to I_FinancialInstrProdCat        as _FinancialInstrProdCat        on  $projection.FinancialInstrProductCategory = _FinancialInstrProdCat.FinancialInstrProductCategory
  association [0..1] to I_FinInstrProdTypeValueHelp    as _FinInstrProdTypeValueHelp    on  $projection.FinancialInstrumentProductType = _FinInstrProdTypeValueHelp.FinancialInstrumentProductType
  association [0..1] to I_SecurityClassIssuer          as _IssuerCounterParty           on  $projection.Issuer = _IssuerCounterParty.BusinessPartner
  association [0..1] to I_SecurityClassGenClassfctn    as _SecurityClassGenClassfctn    on  $projection.ScrtyClassGenClassification = _SecurityClassGenClassfctn.ScrtyClassGenClassification
  association [0..1] to I_SecurityClassTransferType    as _SecurityClassTransferType    on  $projection.SecurityClassTransferType = _SecurityClassTransferType.SecurityClassTransferType
  association [0..1] to I_SecurityClassStatus          as _SecurityClassStatus          on  $projection.SecurityClassStatus = _SecurityClassStatus.SecurityClassStatus
  //association [0..1] to I_UserContactCard              as _CreatedByUser                on  $projection.SecurityClassCreatedByUser = _CreatedByUser.ContactCardID

  //association [0..1] to I_UserContactCard              as _LastChangedByUser            on  $projection.SecurityClassLastChangedByUser = _LastChangedByUser.ContactCardID

  association [0..1] to I_SecurityClassFundType        as _SecurityClassFundType        on  $projection.SecurityClassFundType = _SecurityClassFundType.SecurityClassFundType
  association [0..1] to I_BondClassification           as _BondClassification           on  $projection.BondClassification = _BondClassification.BondClassification
  association [0..1] to I_SecurityClassQuotation       as _SecurityClassQuotation       on  $projection.SecurityClassQuotation = _SecurityClassQuotation.SecurityClassQuotation
  association [0..1] to I_SecurityClassStockCategory   as _SecurityClassStockCategory   on  $projection.SecurityClassStockCategory = _SecurityClassStockCategory.SecurityClassStockCategory
  association [0..1] to I_SecurityClassStockForm       as _SecurityClassStockForm       on  $projection.SecurityClassStockForm = _SecurityClassStockForm.SecurityClassStockForm
  association [0..1] to I_SecurityClassFundCategory    as _SecurityClassFundCategory    on  $projection.SecurityClassFundCategory = _SecurityClassFundCategory.SecurityClassFundCategory
  association [0..1] to I_ScrtyClTrancheClassfctnVH    as _ScrtyClTrancheClassfctnVH    on  $projection.ScrtyClTrancheClassification = _ScrtyClTrancheClassfctnVH.ScrtyClTrancheClassification
  association [0..1] to I_ScrtyClShareholdingType      as _ScrtyClShareholdingType      on  $projection.SecurityClassShareholdingType = _ScrtyClShareholdingType.SecurityClassShareholdingType
  association [0..1] to I_ScrtyClShareholdingStructure as _ScrtyClShareholdingStructure on  $projection.ScrtyClShareholdingStructure = _ScrtyClShareholdingStructure.ScrtyClShareholdingStructure
  association [0..*] to I_ChangeDocument_2             as _ChangeDocument               on  _ChangeDocument.ChangeDocObjectClass = 'VWGATTUNG'
                                                                                        and _ChangeDocument.ChangeDocObject      = $projection.SecurityClass
  association [0..1] to I_ScrtyClTaxClassification    as _ScrtyClTaxClassification     on  $projection.SecurityClassTaxClassification = _ScrtyClTaxClassification.SecurityClassTaxClassification 
  
{
  key SecurityClass,
      FinancialInstrProductCategory,
      FinancialInstrumentProductType,
      SecurityClassName,
      SecurityClassDescription,
      Issuer,
      @Semantics.booleanIndicator
      cast( case
        when SecurityClassIsListed = '1' then 'X'
        else ''
      end as ftr_sc_sboernot preserving type ) as SecurityClassIsListed,
      SecurityClassQuotation,
      IssueCurrency,
      ScrtyClassGenClassification,
      SecurityClassTransferType,

      SecurityClassStatus,
      SecurityClassIssuePriceValue,
      IssueRateInPercent,
      ScrtyClMinimalNumberOfUnits,
      SecurityClassCreatedByUser,
      SecurityClassCreationDate,
      SecurityClassCreationTime,
      SecurityClassCreationSource,
      SecurityClassLastChangedByUser,
      SecurityClassLastChangedDate,
      SecurityClassLastChangedTime,
      SecurityClassLastChangedSource,

      SecurityClassIssueStartDate,

      SecurityClassNomPerStockValue,
      SecurityClassStockCategory,
      SecurityClassStockForm,
      SecurityClassFundType,
      SecurityClassFundCategory,
      SecurityClassFundVolumeAmount,
      ScrtyClIssuePremiumInPercent,
      SecurityClassTaxClassification,

      BondClassification,
      BondCertificateNominalAmount,
      BondCertPerTrdgUnitNominalAmt,
      SecurityClassFinalDueDate,
      ScrtyClCalcPeriodStartDate,
      ScrtyClCompatibleTermEndDate,
      ScrtyClExpectedTermEndDate,
      ScrtyClIsCalcdWthNomPerTrdgUnt,
      ScrtyClTrancheClassification,
      SecurityClassAssetPool,

      IntrstCalcFnlDuDteIsIncld,
      SecurityClassShareholdingType,
      ScrtyClShareholdingStructure,

      _SecurityClSecondaryIndex,
      _SecurityClassRating,
      _SecurityClPayInPriceRate,
      _SecurityClassCondition,
      _SecurityClassSPPI,
      _InstlmntBondPrtnAssignment,
      _SecurityClassAssetPool,
      _BondRedemptionSchedule,
      _SecurityClassExchange,
      _SecuritySwap,
      _SecurityClassConditionHeader,
      _SecurityClRgtyRptgHeader,
      _ScrtyClSubscrpnPeriod,
      _SecurityClassCondition_2,
      _SecurityClConditionHeader_2,

      //Value Help

      _FinancialInstrProdCat,
      _FinInstrProdTypeValueHelp,
      _IssuerCounterParty,
      _SecurityClassGenClassfctn,
      _SecurityClassTransferType,
      _SecurityClassStatus,
      //_CreatedByUser,

      //_LastChangedByUser,

      _SecurityClassFundType,
      _BondClassification,
      _SecurityClassQuotation,
      _SecurityClassStockCategory,
      _SecurityClassStockForm,
      _SecurityClassFundCategory,
      _ScrtyClTrancheClassfctnVH,
      _ScrtyClShareholdingType,
      _ScrtyClShareholdingStructure,
      _ScrtyClTaxClassification,

      //Change Document

      _ChangeDocument
}