R_SecurityClassConditionTP_2

@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #M,
  dataClass: #MASTER
}
@EndUserText.label: 'Security Class Condition'
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
define view entity R_SecurityClassConditionTP_2
  as select from I_SecurityClassCondition
  association        to parent R_SecurityClassTP      as _SecurityClass                 on  $projection.SecurityClass = _SecurityClass.SecurityClass

  composition [0..*] of R_ScrtyClCndnFmlaVariableTP_2 as _FormulaVariable
  association [0..1] to I_FinCndnInterestCalcType     as _FinCndnInterestCalcType       on  $projection.InterestCalculationType = _FinCndnInterestCalcType.InterestCalculationType
  association [0..1] to I_FinCndnConditionType        as _FinCndnConditionType          on  $projection.FinConditionConditionType      = _FinCndnConditionType.FinConditionConditionType
                                                                                        and _FinCndnConditionType.TreasuryContractType = '2'
  association [0..1] to I_FactoryCalendarValueHelp    as _FactoryCalendar1              on  $projection.FinConditionFactoryCalendar1 = _FactoryCalendar1.FactoryCalendarLegacyID
  association [0..1] to I_FactoryCalendarValueHelp    as _FactoryCalendar2              on  $projection.FinConditionFactoryCalendar2 = _FactoryCalendar2.FactoryCalendarLegacyID
  association [0..1] to I_FactoryCalendarValueHelp    as _FactoryCalendar3              on  $projection.FinConditionFactoryCalendar3 = _FactoryCalendar3.FactoryCalendarLegacyID
  association [0..1] to I_FactoryCalendarValueHelp    as _FactoryCalendar4              on  $projection.FinConditionFactoryCalendar4 = _FactoryCalendar4.FactoryCalendarLegacyID
  association [0..1] to I_FactoryCalendarValueHelp    as _FactoryCalendar5              on  $projection.FinConditionFactoryCalendar5 = _FactoryCalendar5.FactoryCalendarLegacyID
  association [0..1] to I_ReferenceInterestRate       as _InterestReference             on  $projection.InterestReference = _InterestReference.ReferenceInterestRate

  //VHs

  //association [0..1] to I_ScrtyClConditionType        as _ScrtyClConditionType          on  $projection.FinConditionConditionType = _ScrtyClConditionType.FinConditionConditionType

  association [0..1] to I_FinancialConditionForm      as _FinConditionForm              on  $projection.FinConditionForm = _FinConditionForm.FinConditionForm
  association [0..1] to I_InterestCalculationMethod   as _InterestCalculationMethod     on  $projection.InterestCalculationMethod = _InterestCalculationMethod.InterestCalculationMethod
  association [0..1] to I_FinCndnDateUpdateRule       as _FinCndnCalcDteUpdateRule      on  $projection.FinCndnCalcDteUpdateRule = _FinCndnCalcDteUpdateRule.FinCndnDateUpdateRule
  association [0..1] to I_FinCndnDateUpdateRule       as _FinCndnDueDteUpdateRule       on  $projection.FinCndnDueDteUpdateRule = _FinCndnDueDteUpdateRule.FinCndnDateUpdateRule
  association [0..1] to I_FinCndnDateUpdateRule       as _InterestRateFixingDateRule    on  $projection.InterestRateFixingDateRule = _InterestRateFixingDateRule.FinCndnDateUpdateRule
 
  association [0..1] to I_ExptlIntrstSettlmtFrqcy     as _ExptlIntrstSettlmtFrqcy       on  $projection.ExponentialIntrstSettlmtFrqcy = _ExptlIntrstSettlmtFrqcy.ExponentialIntrstSettlmtFrqcy
  association [0..1] to I_DividendFactorType          as _DividendFactorType            on  $projection.DividendFactorType = _DividendFactorType.DividendFactorType
  association [0..1] to I_FinCndnAmountRoundingCat    as _FinCndnRateFactorRndngCat     on  $projection.FinCndnRateFactorRndngCategory = _FinCndnRateFactorRndngCat.FinCndnAmountRoundingCategory
  association [0..1] to I_FinCndnAmountRoundingCat    as _FinCndnFactorRoundingCat      on  $projection.FinCndnFactorRoundingCategory = _FinCndnFactorRoundingCat.FinCndnAmountRoundingCategory
  association [0..1] to I_FinCndnAmountRoundingCat    as _FinCndnBaseFactorRndngCat     on  $projection.FinCndnBaseFactorRndngCategory = _FinCndnBaseFactorRndngCat.FinCndnAmountRoundingCategory
  association [0..1] to I_FinCndnAmountRoundingCat    as _FinCndnAmountRoundingCat      on  $projection.FinCndnAmountRoundingCategory = _FinCndnAmountRoundingCat.FinCndnAmountRoundingCategory
  association [0..1] to I_FinCndnAmountTimeUnit       as _FinCndnAmountTimeUnit         on  $projection.FinCndnAmountTimeUnit = _FinCndnAmountTimeUnit.FinCndnAmountTimeUnit
  association [0..1] to I_AvgIntrstRateWeightingCat   as _AvgIntrstRateWeightingCat     on  $projection.AverageIntrstRateWeightingCat = _AvgIntrstRateWeightingCat.AverageIntrstRateWeightingCat
  association [0..1] to I_FinCndnAmountRoundingCat    as _AvgIntrstRateRndngCategory    on  $projection.AverageIntrstRateRndngCategory = _AvgIntrstRateRndngCategory.FinCndnAmountRoundingCategory
  association [0..1] to I_AvgIntrstRateResetCalcEvt   as _AvgIntrstRateResetCalcEvt     on  $projection.AverageIntrstRateResetCalcEvt = _AvgIntrstRateResetCalcEvt.AverageIntrstRateResetCalcEvt
  association [0..1] to I_InterestRateFixingDateRef   as _InterestRateFixingDateRef     on  $projection.InterestRateFixingDateRef = _InterestRateFixingDateRef.InterestRateFixingDateRef
  association [0..1] to I_FinCndnUpdateRuleEntryType  as _FinCndnUpdateRuleEntryType    on  $projection.FinCndnUpdateRuleEntryType = _FinCndnUpdateRuleEntryType.FinCndnUpdateRuleEntryType
  association [0..1] to I_FinCndnDateFrqcyUnit      as _FinCndnCalcDteFrqcyUnit       on  $projection.FinCndnCalcDteFrqcyUnit = _FinCndnCalcDteFrqcyUnit.FinCndnDateFrqcyUnit
  association [0..1] to I_FinCndnDateFrqcyUnit      as _FinCndnDueDteFrqcyUnit        on  $projection.FinCndnDueDteFrqcyUnit = _FinCndnDueDteFrqcyUnit.FinCndnDateFrqcyUnit
  association [0..1] to I_FinCndnDateFrqcyUnit      as _InterestRateAdjmtFrqcyUnit    on  $projection.InterestRateAdjmtFrqcyUnit = _InterestRateAdjmtFrqcyUnit.FinCndnDateFrqcyUnit
  association [0..1] to I_FinCndnDateFrqcyUnit      as _InterestRateFixingFrqcyUnit   on  $projection.InterestRateFixingFrqcyUnit = _InterestRateFixingFrqcyUnit.FinCndnDateFrqcyUnit
  association [0..1] to I_IntrstCalcDateReference     as _IntrstCalcDateReference       on  $projection.InterestCalculationDateRef = _IntrstCalcDateReference.InterestCalculationDateRef
  association [0..1] to I_InterestDueDateReference    as _InterestDueDateReference      on  $projection.InterestDueDateReference = _InterestDueDateReference.InterestDueDateReference
  association [0..1] to I_FinCndnRpaytSettlmtRule       as _FinCndnSettlementRule         on  $projection.FinCndnRpaytSettlmt = _FinCndnSettlementRule.FinCndnRpaytSettlmt
  association [0..1] to I_FinCndnDueDteShiftToTermEnd    as _FinConditionDueDateShift      on  $projection.FinCndnDueDteShiftToTermEnd = _FinConditionDueDateShift.FinCndnDueDteShiftToTermEnd
  association [0..1] to I_IntrstRateAdjmtDteUpdtRule  as _IntrstRateAdjmtDteUpdtRule    on  $projection.InterestRateAdjustmentDateRule = _IntrstRateAdjmtDteUpdtRule.InterestRateAdjustmentDateRule
  association [0..1] to I_FinancialWorkingDayShift    as _FinCndnCalcDteWrkgDayShft     on  $projection.FinCndnCalcDteWrkgDayShft = _FinCndnCalcDteWrkgDayShft.FinancialWorkingDayShift
  association [0..1] to I_FinancialWorkingDayShift    as _FinCndnDueDteWrkgDayShft      on  $projection.FinCndnDueDteWrkgDayShft = _FinCndnDueDteWrkgDayShft.FinancialWorkingDayShift
  association [0..1] to I_FinancialWorkingDayShift    as _IntrstRateAdjmtDteWrkgDayShft on  $projection.IntrstRateAdjmtDateWrkgDayShft = _IntrstRateAdjmtDteWrkgDayShft.FinancialWorkingDayShift
  association [0..1] to I_FinCndnPaytDteWrkgDayShift    as _FinCndnPaytDateWrkgDayShft    on  $projection.FinCndnPaytDateWrkgDayShft = _FinCndnPaytDateWrkgDayShft.FinancialWorkingDayShift
  association [0..1] to I_FinCndnPerdCalculationMethod     as _FinCndnFirstPeriodCalcMethod  on  $projection.FinCndnFirstPeriodCalcMethod = _FinCndnFirstPeriodCalcMethod.FinCndnPeriodCalcMethod
  association [0..1] to I_FinCndnPerdCalculationMethod     as _FinCndnLastPeriodCalcMethod   on  $projection.FinCndnLastPeriodCalcMethod = _FinCndnLastPeriodCalcMethod.FinCndnPeriodCalcMethod
  association [0..1] to I_FinCndnCalcBaseReference    as _FinCndnCalcBaseReference      on  $projection.FinCndnCalcBaseReference = _FinCndnCalcBaseReference.FinCndnCalcBaseReference
                                                                                        and _FinCndnCalcBaseReference.TreasuryContractType = '2'

{
  key SecurityClass,
  key FinConditionConditionType,
  key case
        when dats_is_valid(ConditionItemValidityStartDate) = 1
          then ConditionItemValidityStartDate
        else
          '99991231'
      end as ConditionItemValidityStartDate,
  key FinConditionSubItem,

      FinancialInstrProductCategory,
      CndnItmValdtyStrtDtIsInclusive,
      FinConditionForm,

      FinCndnReferenceConditionType,
      FinCndnRefAccumulatingCndnType,

      InterestCalculationMethod,

      InterestCalculationType,

      ExponentialIntrstSettlmtFrqcy,
      IntrstCalcMethFactoryCalendar,
      InterestFirstPeriodRate,

      InterestRefRateOptrSign,
      InterestReference,
      ConditionPercentageRate,
      FinancialConditionPaymentRate,

      DividendFactorType,
      FinCndnRateFactorRndngCategory,
      FinCndnRateFactorRndngDecimals,

      FinCndnFactorRoundingCategory,
      FinCndnFactorRoundingDecimals,
      FinCndnBaseFactorRndngCategory,
      FinCndnBaseFactorRndngDecimals,

      FinCndnAmountRoundingCategory,
      FinCndnAmountRoundingUnit,
      RndngBaseUntAmtInCndnItmCrcy,
      FinConditionIntrstBaseAmount,
      FinCndnCalcBaseReference,
      FinancialConditionItemAmount,
      FinancialConditionItemCurrency,

      FinCndnAmountTimeUnit,

      //FinConditionExchangeRate,

      ScrtyClCndnDrctExchRate,
      ScrtyClCndnIndrctExchRate,
      FinConditionFactoryCalendar1,
      FinConditionFactoryCalendar2,
      FinConditionFactoryCalendar3,
      FinConditionFactoryCalendar4,
      FinConditionFactoryCalendar5,

      //Average Interest Rate

      AverageIntrstRateWeightingCat,
      AverageIntrstRateRndngCategory,
      AverageIntrstRateRndngDecimals,
      AverageInterestRateSpreadValue,
      AvgIntrstRateHasUsedUpperLimit,
      AverageInterestUpperLimitRate,
      AvgIntrstRateHasUsedLowerLimit,
      AverageInterestLowerLimitRate,
      AverageIntrstRateResetCalcEvt,

      //Update Rule

      FinCndnUpdateRuleEntryType,
      //      FinCndnUpdateRuleFirstDate,

      //      FinCndnUpdateRuleDateFrequency,

      //      FinCndnUpdateRuleDateFrqcyUnit,

      //      UpdateRuleDateIsMonthEnd,

      //      FinCndnUpdtRuleDateWrkgDayShft,


      //Calculation Date

      FinCndnCalcDteUpdateRule,
      CalculationDate,
      FinCndnCalcDteFrequency,
      FinCndnCalcDteFrqcyUnit,
      CalcDateIsAsEndDateInclusive,
      CalcDateIsAsEndDateMonthEnd,
      FinCndnCalcDteWrkgDayShft,
      FinCndnCalcDteShftDrctn,
      ScrtyClCndnCalcDteShftNrOfDays,
      CalcDteIsRegularWithVarblDte,
      InterestCalculationDateRef,

      //Due Date

      FinCndnDueDteUpdateRule,
      DueDate,
      FinCndnDueDteFrequency,
      FinCndnDueDteFrqcyUnit,
      DueDateIsAsEndDateInclusive,
      DueDateIsAsEndDateMonthEnd,
      FinCndnDueDteWrkgDayShft,
      FinCndnDueDteShftDrctn,
      ScrtyClCndnDueDteShftNrOfDays,
      DueDteIsRegularWithVarblDte,
      InterestDueDateReference,

      //Payment Date

      FinCndnPaytDateWrkgDayShft,

      //Other Calculation Date

      FinCndnDueDteShiftToTermEnd,
      FinCndnDuDteIsFinMathCalcReltd,
      FinCndnRpaytSettlmt,
      FinCndnFirstPeriodCalcMethod,
      FinCndnLastPeriodCalcMethod,

      //Interest Rate Adjustment Date

      InterestRateAdjustmentDateRule,
      InterestRateAdjustmentDate,
      IntrstRateAdjmtDateIsMonthEnd,
      InterestRateAdjustmentFrqcy,
      InterestRateAdjmtFrqcyUnit,
      IntrstRateAdjmtDateWrkgDayShft,
      FinCndnAdjmtDteShftDrctn,
      ScrtyClIntrstRateAdjmtShftDays,

      //Interest Rate Fixing Date

      InterestRateFixingDateRule,
      InterestRateFixingDate,
      IntrstRateFixingDateIsMonthEnd,
      InterestRateFixingFrqcy,
      InterestRateFixingFrqcyUnit,
      FinCndnFixingDteShftDrctn,
      ScrtyClIntrstRateFixShftDays,
      FinCndnRateFixingLockoutPeriod,
      IntrstRateFixDteShftIsModifd,
      InterestRateFixingDateRef,

      _SecurityClass.FinancialInstrumentProductType,

      _FormulaVariable,

      _SecurityClass,
      

      //Value Help

      //_ScrtyClConditionType,

      _FinCndnConditionType,
      _FinCndnInterestCalcType,
      _DividendFactorType,
      _FactoryCalendar1,
      _FactoryCalendar2,
      _FactoryCalendar3,
      _FactoryCalendar4,
      _FactoryCalendar5,
      _InterestReference,
      _FinConditionForm,
      _InterestCalculationMethod,
      _FinCndnCalcDteUpdateRule,
      _FinCndnDueDteUpdateRule,
      _InterestRateFixingDateRule,
      _ExptlIntrstSettlmtFrqcy,
      _FinCndnRateFactorRndngCat,
      _FinCndnFactorRoundingCat,
      _FinCndnBaseFactorRndngCat,
      _FinCndnAmountRoundingCat,
      _FinCndnAmountTimeUnit,
      _AvgIntrstRateWeightingCat,
      _AvgIntrstRateRndngCategory,
      _AvgIntrstRateResetCalcEvt,
      _FinCndnUpdateRuleEntryType,
      _FinCndnCalcDteFrqcyUnit,
      _FinCndnDueDteFrqcyUnit,
      _InterestRateFixingFrqcyUnit,
      _IntrstCalcDateReference,
      _InterestDueDateReference,
      _FinCndnSettlementRule,
      _FinConditionDueDateShift,
      _IntrstRateAdjmtDteUpdtRule,
      _InterestRateAdjmtFrqcyUnit,
      //working date shift VH

      _FinCndnCalcDteWrkgDayShft,
      _FinCndnDueDteWrkgDayShft,
      _IntrstRateAdjmtDteWrkgDayShft,
      _FinCndnPaytDateWrkgDayShft,
      _FinCndnFirstPeriodCalcMethod,
      _FinCndnLastPeriodCalcMethod,
      _FinCndnCalcBaseReference,

      _InterestRateFixingDateRef
}