R_SalesOrderWithoutChrgTextTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}

@ObjectModel.semanticKey: ['SalesOrderWithoutCharge', 'Language', 'LongTextID']
@ObjectModel.dataCategory: #TEXT
@Metadata.ignorePropagatedAnnotations: true

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@EndUserText.label: 'Sales Order Without Charge Text - TP'

define view entity R_SalesOrderWithoutChrgTextTP
 as select from P_SalesDocumentText( P_SAPClient : $session.client ) as SalesOrderWithoutChargeText

    inner join   I_SalesDocumentBasic                                 as SalesDocumentBasic on  SalesDocumentBasic.SalesDocument      = SalesOrderWithoutChargeText.SalesDocument
                                                                                            and SalesDocumentBasic.SDDocumentCategory = 'I'

    inner join   I_SalesDocumentType                                  as SalesDocumentType  on SalesDocumentBasic.SalesDocumentType = SalesDocumentType.SalesDocumentType


  association        to parent R_SalesOrderWithoutChargeTP  as _SalesOrderWithoutCharge           on  $projection.SalesOrderWithoutCharge = _SalesOrderWithoutCharge.SalesOrderWithoutCharge

  association [0..*] to I_TextDeterminationProcedItem as _TextDeterminationProcedItem on  $projection.TextDeterminationProcedure          = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                      and $projection.LongTextID                          = _TextDeterminationProcedItem.LongTextID
                                                                                      and _TextDeterminationProcedItem.TextObjectCategory = 'VBBK'

  association [0..1] to I_Language                    as _Language                    on  $projection.LanguageForEdit = _Language.Language
  association [0..1] to I_SDDocumentLongTextID        as _LongTextID                  on  $projection.LongTextIDForEdit = _LongTextID.LongTextID

{
  key cast(SalesOrderWithoutChargeText.SalesDocument as sales_order_without_charge preserving type) as SalesOrderWithoutCharge,
      @Semantics.language: true
  key SalesOrderWithoutChargeText.Language,

  key SalesOrderWithoutChargeText.LongTextID,

      @ObjectModel.foreignKey.association: '_LongTextID'
      @ObjectModel.editableFieldFor: 'LongTextID'
      SalesOrderWithoutChargeText.LongTextID                                                 as LongTextIDForEdit,

      @ObjectModel.foreignKey.association: '_Language'
      @ObjectModel.editableFieldFor: 'Language'
      SalesOrderWithoutChargeText.Language                                                   as LanguageForEdit,
      
      @ObjectModel.virtualElement: true
      @Semantics.text:true
      SalesOrderWithoutChargeText.LongText,

      @Consumption.hidden: true
      SalesDocumentType.TextDeterminationProcedure,

      _TextDeterminationProcedItem.TextDeterminationProcedureItem               as TextDeterminationProcedureItem,

      // For Access control

      @Consumption.hidden: true
      _SalesOrderWithoutCharge.SalesOrderWithoutChargeType,
      @Consumption.hidden: true
      _SalesOrderWithoutCharge.SalesOrganization,
      @Consumption.hidden: true
      _SalesOrderWithoutCharge.DistributionChannel,
      @Consumption.hidden: true
      _SalesOrderWithoutCharge.OrganizationDivision,


      // Exposed associations

      _SalesOrderWithoutCharge,
      _Language,
      _LongTextID
}