R_PurContrAccountTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@EndUserText.label: 'Purchase Contract Account'

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel.semanticKey:  [ 'AccountAssignmentNumber','PurchaseContractItem','PurchaseContract' ]
@ObjectModel.representativeKey: 'AccountAssignmentNumber'

@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MIXED
}

@Metadata.ignorePropagatedAnnotations: true

define view entity R_PurContrAccountTP
  as select from           I_PurCtrAccount
    left outer to one join I_CommitmentItem      on I_PurCtrAccount.CommitmentItem = I_CommitmentItem.CommitmentItem
    left outer to one join I_WBSElementBasicData on I_PurCtrAccount.WBSElementInternalID = I_WBSElementBasicData.WBSElementInternalID

  association to parent R_PurchaseContractItemTP as _PurchaseContractItem on  _PurchaseContractItem.PurchaseContract     = $projection.PurchaseContract
                                                                          and _PurchaseContractItem.PurchaseContractItem = $projection.PurchaseContractItem

  association to R_PurchaseContractTP            as _PurContract          on  _PurContract.PurchaseContract = $projection.PurchaseContract
{
  key I_PurCtrAccount.AccountAssignment as AccountAssignmentNumber,
      @ObjectModel.foreignKey.association: '_PurchaseContractItem'
  key I_PurCtrAccount.PurchaseContractItem,
      @ObjectModel.foreignKey.association: '_PurContract'
  key I_PurCtrAccount.PurchaseContract,
      I_PurCtrAccount.CostCenter,
      I_PurCtrAccount.MasterFixedAsset,
      I_PurCtrAccount.ProjectNetwork,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      I_PurCtrAccount.Quantity,
      I_PurCtrAccount.OrderQuantityUnit,
      I_PurCtrAccount.MultipleAcctAssgmtDistrPercent,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      I_PurCtrAccount.PurgDocNetAmount,
      I_PurCtrAccount.DocumentCurrency,
      I_PurCtrAccount.IsDeleted,
      I_PurCtrAccount.GLAccount,
      I_PurCtrAccount.BusinessArea,
      I_PurCtrAccount.SalesOrder,
      I_PurCtrAccount.SalesOrderItem,
      I_PurCtrAccount.SalesOrderScheduleLine,
      I_PurCtrAccount.FixedAsset,
      I_PurCtrAccount.OrderID,
      I_PurCtrAccount.UnloadingPointName,
      I_PurCtrAccount.ControllingArea,
      I_PurCtrAccount.CostObject,
//      I_PurCtrAccount.ProfitabilitySegment,

      I_PurCtrAccount.ProfitCenter,

      I_WBSElementBasicData.WBSElementInternalID,

      I_WBSElementBasicData.WBSDescription,
      I_PurCtrAccount.ProjectNetworkInternalID,
      I_PurCtrAccount.CommitmentItemShortID,
      I_PurCtrAccount.FundsCenter,
      I_PurCtrAccount.Fund,
      I_PurCtrAccount.FunctionalArea,
      I_PurCtrAccount.LastChangedDate,
      I_PurCtrAccount.GoodsRecipientName,
      I_PurCtrAccount.IsFinallyInvoiced,
//      I_PurCtrAccount.RealEstateObject,

      I_PurCtrAccount.NetworkActivityInternalID,
      I_PurCtrAccount.PartnerAccountNumber,
      I_PurCtrAccount.JointVentureRecoveryCode,
      I_PurCtrAccount.SettlementReferenceDate,
      I_PurCtrAccount.OrderInternalID,
      I_PurCtrAccount.OrderIntBillOfOperationsItem,
      I_PurCtrAccount.TaxCode,
      I_PurCtrAccount.TaxJurisdiction,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      I_PurCtrAccount.NonDeductibleInputTaxAmount,
      I_PurCtrAccount.CostCtrActivityType,
      I_PurCtrAccount.BusinessProcess,
      I_PurCtrAccount.GrantID,
      I_PurCtrAccount.BudgetPeriod,
      I_PurCtrAccount.EarmarkedFundsDocument,
      I_PurCtrAccount.ValidityDate,

      @Semantics.systemDateTime.lastChangedAt: true
      _PurContract.LastChangeDateTime   as LastChangeDateTime,


      /* Associations */
      _PurContract,
      _PurchaseContractItem

}

where
      _PurContract.PurchaseContract              is not null
  and _PurchaseContractItem.PurchaseContractItem is not null