R_OutputRequestItemTP

@ObjectModel: {
   usageType.serviceQuality: #B,
   usageType.sizeCategory: #XXL,
   usageType.dataClass: #TRANSACTIONAL,
   semanticKey: [ 'OutputRequestItem' ],
   representativeKey: 'OutputRequestItemUUID'
}
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.privilegedAssociations: [ '_OutputRequest',
                                         '_OutputRequestItemEmail',
                                         '_OutputRequestItemEmailTo',
                                         '_OutputRequestItemEmailCc',
                                         '_OutputRequestItemEmailBcc',
                                         '_OutputRequestItemAttachment',
                                         '_OutputRequestItemLog' ]
@AccessControl.personalData.blocking: #REQUIRED
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true //shall be changed to false, because MDE on this level(TP) is not needed anymore

@EndUserText.label: 'Output Request Item for RAP'
define view entity R_OutputRequestItemTP
  as select from R_OutputRequestItem
  association        to parent R_OutputRequestTP      as _OutputRequest               on  $projection.OutputRequestUUID = _OutputRequest.OutputRequestUUID
  composition [0..*] of R_OutputRequestItemEmailTP    as _OutputRequestItemEmail
  composition [0..*] of R_OutputRequestItemAttchTP    as _OutputRequestItemAttachment
  composition [0..*] of R_OutputRequestItemLogTP      as _OutputRequestItemLog
  association [0..1] to I_OutputRequestItemBinaryData as _OutputReqBinaryDataStandard on  _OutputReqBinaryDataStandard.OutputRequestItemBinaryDataID = ''
  association [0..1] to I_OutputSenderOrgCenterType   as _OutputSenderOrgType         on  $projection.SenderOrganizationalCenterType = _OutputSenderOrgType.SenderOrganizationalCenterType
  association [0..1] to I_OutputSenderOrgUnitType     as _OutputSenderOrgUnitType     on  $projection.SenderOrganizationalUnitType = _OutputSenderOrgUnitType.SenderOrganizationalUnitType
  association [0..1] to I_OutpReqItmPqVH              as _PrintQueueVH                on  $projection.PrintQueue = _PrintQueueVH.PrintQueue
  association [0..1] to C_OQ_QUEUE_VH                 as _OutputQueueVH               on  $projection.OutputQueue = _OutputQueueVH.Qname
  association [0..1] to I_OCFormTemplate              as _FormTemplate                on  $projection.OutputControlApplObjectType = _FormTemplate.OutputControlApplObjectType
                                                                                      and $projection.OutputDocumentType          = _FormTemplate.OutputDocumentType
                                                                                      and $projection.FormTemplateType            = _FormTemplate.FormType
                                                                                      and $projection.FormTemplate                = _FormTemplate.FormTemplate
  association [0..1] to I_OCEmailTemplate             as _EmailTemplate               on  $projection.OutputControlApplObjectType = _EmailTemplate.OutputControlApplObjectType
                                                                                      and $projection.OutputDocumentType          = _EmailTemplate.OutputDocumentType
                                                                                      and $projection.EmailTemplate               = _EmailTemplate.EmailTemplate
  association [0..1] to I_Country                     as _SenderCountry               on  $projection.SenderCountry = _SenderCountry.Country
  association [0..1] to I_Country                     as _FormTemplateCountry         on  $projection.FormTemplateCountry = _FormTemplateCountry.Country
  association [0..1] to I_Language                    as _FormTemplateLanguage        on  $projection.FormTemplateLanguage = _FormTemplateLanguage.Language
  association [0..*] to R_OutputRequestItemEmailTP    as _OutputRequestItemEmailTo    on  $projection.OutputRequestItemUUID                    = _OutputRequestItemEmailTo.OutputRequestItemUUID
                                                                                      and _OutputRequestItemEmailTo.OutputRequestItemEmailRole = 'TO'
  association [0..*] to R_OutputRequestItemEmailTP    as _OutputRequestItemEmailCc    on  $projection.OutputRequestItemUUID                    = _OutputRequestItemEmailCc.OutputRequestItemUUID
                                                                                      and _OutputRequestItemEmailCc.OutputRequestItemEmailRole = 'CC'
  association [0..*] to R_OutputRequestItemEmailTP    as _OutputRequestItemEmailBcc   on  $projection.OutputRequestItemUUID                     = _OutputRequestItemEmailBcc.OutputRequestItemUUID
                                                                                      and _OutputRequestItemEmailBcc.OutputRequestItemEmailRole = 'BCC'

{
  key OutputRequestItemUUID,
      @ObjectModel.foreignKey.association: '_OutputControlApplObjectType'
      OutputControlApplObjectType,
      OutputControlApplicationObject,
      OutputRequestItem,
      OutputRequestUUID,
      @ObjectModel.foreignKey.association: '_OutputRequestItemStatus'
      OutputRequestItemStatus,
      @ObjectModel.foreignKey.association: '_OutputDocumentType'
      OutputDocumentType,
      @ObjectModel.foreignKey.association: '_OutputChannel'
      OutputChannel,
      OutputRequestItemOrigin,
      Recipient,
      RecipientRole,
      IsChangeDocument,
      @ObjectModel.foreignKey.association: '_DispatchTime'
      DispatchTime,
      @UI.hidden: true
      OutputRequestItemRefUUID,
      @Semantics.systemDateTime.createdAt: true
      CreationDateTime,
      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      @ObjectModel.foreignKey.association: '_FormTemplate'
      FormTemplate,
      FormTemplateType,
      FormTemplateLanguage,
      FormTemplateCountry,
      SenderOrganizationalCenter,
      @ObjectModel.foreignKey.association: '_OutputSenderOrgType'
      SenderOrganizationalCenterType,
      SenderOrganizationalUnit,
      @ObjectModel.foreignKey.association: '_OutputSenderOrgUnitType'
      SenderOrganizationalUnitType,
      SenderCountry,
      @ObjectModel.foreignKey.association: '_EmailTemplate'
      EmailTemplate,
      SenderEmailAddress,
      @ObjectModel.foreignKey.association: '_PrintQueueVH'
      PrintQueue,
      PrintQueueItem,
      PrintCopyNumber,
      //  PrintingMethod,

      SpoolRequest,
      OutputQueue,
      OutputQueueItem,
      OutputItemDataTransferMode,
      TotalPageNumber,
      DocumentPageDescriptionLang,
      KnowledgeProviderObjectCat,
      KnowledgeProviderObject,
      FormPDFIsUntagged,
      /* Associations */
      //R_OutputRequestItem

      _DispatchTime,
      _DataTransferMode,
      _OutputChannel,
      _OutputControlApplObjectType,
      _OutputDocumentType,
      _OutputRequest,
      _OutputRequestItemStatus,
      _OutputRequestItemEmail,
      _OutputRequestItemEmailTo,
      _OutputRequestItemEmailCc,
      _OutputRequestItemEmailBcc,
      _OutputRequestItemAttachment,
      _OutputRequestItemLog,
      _OutputReqBinaryDataStandard,
      _OutputSenderOrgType,
      _OutputSenderOrgUnitType,
      _PrintQueueVH,
      _OutputQueueVH,
      _SenderCountry,
      _EmailTemplate,
      _FormTemplate,
      _FormTemplateCountry,
      _FormTemplateLanguage
}