R_OUTPUTREQUESTITEM

CDS View

Output Request Item for RAP

R_OUTPUTREQUESTITEM is a CDS View in S/4HANA. Output Request Item for RAP. 3 CDS views read from this table.

Used by 3 CDS view(s)

CDS Views using this table (3)

ViewTypeJoinVDMDescription
C_PhysInvtryMngItmListOutpReqQ view_entity from CONSUMPTION Physical Inventory Output Request Query
R_OutputRequestItemTP view_entity from TRANSACTIONAL Output Request Item for RAP
R_PhysInvtryOutpRequestItem view_entity from COMPOSITE PI Document Output Request Items 
@AbapCatalog: {
  sqlViewName: 'RORITEMRAP',
  compiler.compareFilter: true
}
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@AccessControl: {
  authorizationCheck: #NOT_REQUIRED,
  personalData.blocking: #REQUIRED
}
@ObjectModel: {
   representativeKey: 'OutputRequestItemUUID',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #XXL
   }
}
@ClientHandling: {
     type: #INHERITED,
     algorithm: #SESSION_VARIABLE
}
@Metadata.ignorePropagatedAnnotations: false
@Metadata.allowExtensions: false
@EndUserText.label: 'Output Request Item for RAP'

define view R_OutputRequestItem
  as select from           apoc_d_or_item
    left outer to one join I_OutputRequestItemBinaryData on I_OutputRequestItemBinaryData.OutputRequestItemBinaryDataID = '' //apoc_d_outputdat on apoc_d_outputdat.id = ''

  association [1..1] to R_OutputRequest               as _OutputRequest               on  $projection.OutputRequestUUID = _OutputRequest.OutputRequestUUID
  association [0..1] to I_OutputRequestItemStatus     as _OutputRequestItemStatus     on  $projection.OutputRequestItemStatus = _OutputRequestItemStatus.OutputRequestItemStatus
  association [0..1] to I_OutputControlApplObjectType as _OutputControlApplObjectType on  $projection.OutputControlApplObjectType = _OutputControlApplObjectType.OutputControlApplObjectType
  association [0..1] to I_OutputChannel               as _OutputChannel               on  $projection.OutputChannel = _OutputChannel.OutputChannel
  association [0..1] to I_DispatchTime                as _DispatchTime                on  $projection.DispatchTime = _DispatchTime.DispatchTime
  association [0..1] to I_DataTransferMode            as _DataTransferMode            on  $projection.OutputItemDataTransferMode = _DataTransferMode.DataTransferMode
  association [0..1] to I_OutputControlOutputType     as _OutputDocumentType          on  $projection.OutputDocumentType          = _OutputDocumentType.OutputDocumentType
                                                                                      and $projection.OutputControlApplObjectType = _OutputDocumentType.OutputControlApplObjectType
  association [0..*] to R_OutputRequestItemEmail      as _OutputRequestItemEmail      on  $projection.OutputRequestItemUUID = _OutputRequestItemEmail.OutputRequestItemUUID
  association [0..*] to R_OutputRequestItemAttachment as _OutputRequestItemAttachment on  $projection.OutputRequestItemUUID = _OutputRequestItemAttachment.OutputRequestItemUUID
{
  key apoc_d_or_item.db_key                          as OutputRequestItemUUID,
      apoc_d_or_item.appl_object_type                as OutputControlApplObjectType,
      apoc_d_or_item.appl_object_id                  as OutputControlApplicationObject,
      apoc_d_or_item.item_id                         as OutputRequestItem,
      apoc_d_or_item.parent_key                      as OutputRequestUUID,
      //https://support.wdf.sap.corp/sap/support/message/2070228764

      cast ( 'application/pdf'   as    w3conttype )  as MimeType, //abap.char( 128 ) abap.sstring(1255) w3conttype

      I_OutputRequestItemBinaryData.OutputBinaryData as OutputDataBinary,
      cast(' ' as boole_d preserving type)           as OutputPreviewIsNotPossible,
      apoc_d_or_item.status                          as OutputRequestItemStatus,
      apoc_d_or_item.output_type                     as OutputDocumentType,
      apoc_d_or_item.channel                         as OutputChannel,
      apoc_d_or_item.item_origin                     as OutputRequestItemOrigin,
      apoc_d_or_item.receiver_id                     as Recipient,
      apoc_d_or_item.receiver_role                   as RecipientRole,
      apoc_d_or_item.change_indicator                as IsChangeDocument,
      apoc_d_or_item.dispatch_time                   as DispatchTime,
      apoc_d_or_item.reference_item                  as OutputRequestItemRefUUID,
      apoc_d_or_item.crea_date_time                  as CreationDateTime,
      apoc_d_or_item.crea_ident_uuid                 as CreatedByUser,
      apoc_d_or_item.lchg_date_time                  as LastChangeDateTime,
      apoc_d_or_item.lchg_ident_uuid                 as LastChangedByUser,
      apoc_d_or_item.form_template_name              as FormTemplate,
      apoc_d_or_item.form_template_type              as FormTemplateType,
      apoc_d_or_item.form_template_language_code     as FormTemplateLanguage,
      apoc_d_or_item.form_template_country_code      as FormTemplateCountry,
      apoc_d_or_item.sender_organization_id          as SenderOrganizationalCenter,
      apoc_d_or_item.sender_organization_type        as SenderOrganizationalCenterType,
      apoc_d_or_item.sender_org_unit_id              as SenderOrganizationalUnit,
      apoc_d_or_item.sender_org_unit_type            as SenderOrganizationalUnitType,
      apoc_d_or_item.sender_country_code             as SenderCountry,
      apoc_d_or_item.sender_email_uri                as SenderEmailAddress,
      apoc_d_or_item.email_template_id               as EmailTemplate,
      apoc_d_or_item.print_queue_name                as PrintQueue,
      apoc_d_or_item.print_queue_item_id             as PrintQueueItem,
      apoc_d_or_item.print_number_of_copies          as PrintCopyNumber,
      apoc_d_or_item.printing_method                 as PrintingMethod,
      apoc_d_or_item.spool_request_id                as SpoolRequest,
      apoc_d_or_item.output_queue                    as OutputQueue,
      apoc_d_or_item.output_queue_item_id            as OutputQueueItem,
      apoc_d_or_item.output_queue_zip_mode           as OutputItemDataTransferMode,
      apoc_d_or_item.doc_number_of_pages             as TotalPageNumber,
      apoc_d_or_item.doc_page_description_language   as DocumentPageDescriptionLang,
      apoc_d_or_item.kpro_class                      as KnowledgeProviderObjectCat,
      apoc_d_or_item.kpro_objid                      as KnowledgeProviderObject,
      apoc_d_or_item.form_untag_pdf                  as FormPDFIsUntagged,

      /* Associations */
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _OutputRequest,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _OutputRequestItemEmail,
      _OutputRequestItemAttachment,
      _OutputRequestItemStatus,
      _OutputControlApplObjectType,
      _OutputChannel,
      _DispatchTime,
      _DataTransferMode,
      _OutputDocumentType
}

Learn More