R_OperatingGLAccountTP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: [ '_CreatedBy' ]
@EndUserText.label: 'Operating G/L Account Root'
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #S,
  dataClass: #CUSTOMIZING
}
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.sapObjectNodeType.name: 'GeneralLedgerAccount'
define root view entity R_OperatingGLAccountTP
  as select from           I_GLAccountInChartOfAccounts as Acct
    left outer to one join I_ChartOfAccounts            as CoA  on Acct.ChartOfAccounts = CoA.ChartOfAccounts

  composition [0..*] of R_OperatingGLAcctInCoCodeTP    as _CompanyCode

  //  on Acct.ChartOfAccounts = _CoCodeColumn.ChartOfAccounts

  //                                                              and Acct.GLAccount       = _CoCodeColumn.GLAccount

  //                                                              and _CompanyCode.CompanyCode = CoCodeColumn.CompanyCode




  //  association [0..1] to I_GLAcctInCOAImplementStat   as _Impl      on  Acct.ChartOfAccounts = _Impl.ChartOfAccounts

  //                                                                   and Acct.GLAccount       = _Impl.GLAccount



  association [0..1] to I_GLAcctInChartOfAcctsProdn    as _NotNeeded                     on  Acct.ChartOfAccounts = _NotNeeded.ChartOfAccounts
                                                                                         and Acct.GLAccount       = _NotNeeded.GLAccount

  association [1..*] to I_GLAccountText                as _GLAccountText                 on  $projection.ChartOfAccounts = _GLAccountText.ChartOfAccounts
                                                                                         and $projection.GLAccount       = _GLAccountText.GLAccount

  association [0..*] to I_ChartOfAccountsText          as _ChartOfAccountsText           on  $projection.ChartOfAccounts = _ChartOfAccountsText.ChartOfAccounts
  association [0..*] to I_GLAccountHierarchyNode       as _GLAccountHierarchyNode        on  $projection.GLAccount       = _GLAccountHierarchyNode.GLAccount
                                                                                         and $projection.ChartOfAccounts = _GLAccountHierarchyNode.ChartOfAccounts
  association [0..1] to I_GLAccountForPublicSector     as _PublicSector                  on  $projection.ChartOfAccounts = _PublicSector.ChartOfAccounts
                                                                                         and $projection.GLAccount       = _PublicSector.GLAccount
  association [0..1] to I_GLAccountGroup               as _GLAccountGroup                on  $projection.GLAccountGroup  = _GLAccountGroup.GLAccountGroup
                                                                                         and $projection.ChartOfAccounts = _GLAccountGroup.ChartOfAccounts
  association [0..1] to I_FunctionalArea               as _FunctionalArea                on  $projection.FunctionalArea = _FunctionalArea.FunctionalArea
  association [1..1] to I_Globalcompany                as _GlobalCompany                 on  $projection.PartnerCompany = _GlobalCompany.Company
  association [0..1] to I_ChartOfAccounts              as _CorporateGroupChartOfAccounts on  $projection.CorporateGroupChartOfAccounts = _CorporateGroupChartOfAccounts.ChartOfAccounts
  association [0..1] to I_GLAccountInChartOfAccounts   as _CorporateGroupAccount         on  $projection.CorporateGroupChartOfAccounts = _CorporateGroupAccount.ChartOfAccounts
                                                                                         and $projection.CorporateGroupAccount         = _CorporateGroupAccount.GLAccount
  association [0..*] to I_GLAccountGroupText           as _GLAccountGroupText            on  $projection.GLAccountGroup  = _GLAccountGroupText.GLAccountGroup
                                                                                         and $projection.ChartOfAccounts = _GLAccountGroupText.ChartOfAccounts
  association [0..1] to I_GLAccountType                as _GLAccountType                 on  $projection.GLAccountType = _GLAccountType.GLAccountType
  association [0..1] to I_GLAccountSubtype             as _GLAccountSubtype              on  $projection.GLAccountSubtype = _GLAccountSubtype.GLAccountSubtype
  association [0..*] to I_GLAccountTypeText            as _GLAccountTypeText             on  $projection.GLAccountType = _GLAccountTypeText.GLAccountType

  association [1..1] to I_GLAccountText                as _MaintTxt                      on  Acct.ChartOfAccounts  = _MaintTxt.ChartOfAccounts
                                                                                         and $projection.GLAccount = _MaintTxt.GLAccount
                                                                                         and _MaintTxt.Language    = CoA.MaintenanceLanguage
  association [0..1] to I_GLAcctInCOAImplementStatType as _GLAcctImplementStatus         on  $projection.GLAcctCOAImplementStatus = _GLAcctImplementStatus.GLAcctCOAImplementStatus

  association [0..*] to I_GLAccountText                as _BankReconAcctTxt              on  $projection.ChartOfAccounts           = _BankReconAcctTxt.ChartOfAccounts
                                                                                         and $projection.BankReconciliationAccount = _BankReconAcctTxt.GLAccount

  association [0..1] to I_CostElement                  as _CostElement                   on  $projection.ChartOfAccounts  = _CostElement.ChartOfAccounts
                                                                                         and $projection.GLAccount        = _CostElement.CostElement
                                                                                         and _CostElement.ControllingArea = 'A000'

  association [0..1] to I_UserContactCard              as _CreatedBy                     on  $projection.CreatedByUser = _CreatedBy.ContactCardID

{
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ChartOfAccountsStdVH',
                     element: 'ChartOfAccounts' }
        }]
      //      @ObjectModel.text.association: '_ChartOfAccountsText'

      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
  key Acct.ChartOfAccounts,
      @Consumption.valueHelpDefinition: [
      { entity:  { name:    'I_GLAcctInChtOfAcctsStdVH',
                   element: 'GLAccount' },
                   additionalBinding: [{ localElement: 'ChartOfAccounts',
                                element: 'ChartOfAccounts' }]
      }]
      @ObjectModel.hierarchy.association: '_GLAccountHierarchyNode'
  key Acct.GLAccount,
      //      @ObjectModel.foreignKey.association: '_GLAcctInChartOfAcctsStatus'

      case
       when Acct._GLAcctInChartOfAcctsStatus.GLAcctCOAImplementStatus is null
      then  'I'
      else Acct._GLAcctInChartOfAcctsStatus.GLAcctCOAImplementStatus
      end                                                                  as GLAcctCOAImplementStatus,

      _NotNeeded.GLAccountIsNotProdnRelevant,
      //      Acct._GLAcctInChartOfAcctsStatus.GLAccountCOAIsDeliveredBySAP,

      Acct.IsBalanceSheetAccount,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_GLAccountGroupStdVH',
                     element: 'GLAccountGroup' },
          additionalBinding: [{ localElement: 'ChartOfAccounts',
                                element: 'ChartOfAccounts' }]
        }]
      //      @ObjectModel.text.association: '_GLAccountGroupText'

      @ObjectModel.foreignKey.association: '_GLAccountGroup'
      Acct.GLAccountGroup,
      @ObjectModel.foreignKey.association: '_CorporateGroupChartOfAccounts'
      Acct._ChartOfAccounts.CorporateGroupChartOfAccounts                  as CorporateGroupChartOfAccounts,
      @ObjectModel.foreignKey.association: '_CorporateGroupAccount'
      Acct.CorporateGroupAccount,
      Acct.ProfitLossAccountType,
      Acct._RetainedEarningsGLAccount.RetainedEarningsGLAccount            as RetainedEarningsGLAccount,
      Acct.SampleGLAccount,
      Acct.AccountIsMarkedForDeletion,
      Acct.AccountIsBlockedForCreation,
      Acct.AccountIsBlockedForPosting,
      Acct.AccountIsBlockedForPlanning,
      @ObjectModel.foreignKey.association: '_GlobalCompany'
      Acct.PartnerCompany,
      @ObjectModel.foreignKey.association: '_FunctionalArea' //Inserted by VDM CDS Suite Plugin

      Acct.FunctionalArea,
      Acct.CreationDate,
      @Semantics.user.createdBy: true
      Acct.CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      Acct.LastChangeDateTime,

      Acct._Text[1: Language = $session.system_language].GLAccountName     as GLAccountLogonLangName, //[1:Language = $session.system_language]

      Acct._Text[1: Language = $session.system_language].GLAccountLongName as GLAcctLogonLangLongName,
      _MaintTxt.GLAccountName                                              as GLAccountName,
      _MaintTxt.GLAccountLongName                                          as GLAccountLongName,
      $session.system_language                                             as Language,



      @Consumption.valueHelpDefinition: [
         { entity:  { name:    'I_GLAccountType',
                      element: 'GLAccountType' }

         }]
      //       @ObjectModel.text.association: '_GLAccountTypeText'


      @ObjectModel.foreignKey.association: '_GLAccountType' //Inserted by VDM CDS Suite Plugin

      Acct.GLAccountType,
      @ObjectModel.foreignKey.association: '_GLAccountSubtype'
      Acct.GLAccountSubtype,
      Acct.GLAccountExternal,
      Acct.BankReconciliationAccount,
      @EndUserText.label: 'Profit Loss Account'
      Acct.IsProfitLossAccount,

      Acct._ChartOfAccounts,


      // Public Sector Fields

      _PublicSector.PubSecBudgetCnsmpnType,
      _PublicSector.PubSecBdgtAcctRevnExpnCode,
      _PublicSector.PubSecBudgetIsRelevant,
      _PublicSector.PubSecBdgtAcctIsPostgAllowed,
      _PublicSector.PubSecBdgtAcctIsBdgtAllowed,
      _PublicSector.PubSecBdgtAcctIsCarryFwd,
      @ObjectModel.text.association: null
      _PublicSector.PubSecBdgtAcctCarryFwdTo,
      _PublicSector.CashLedgerAccount,
      @ObjectModel.text.association: null
      _PublicSector.SponsoredClass,

      Acct._RetainedEarningsGLAccount,

      _CostElement.CostElementCategory,
      _CostElement.UnitOfMeasure,
      @EndUserText.label: 'Record Quantity'
      cast( _CostElement.ConsumptionQtyIsRecorded as xfeld )               as ConsumptionQtyIsRecorded,
      //      _CostElement.ConsumptionQtyIsRecorded,

      _ChartOfAccountsText,
      _GLAccountHierarchyNode,
      _PublicSector,
      _GLAccountGroup,
      _FunctionalArea,
      _GlobalCompany,
      _CorporateGroupChartOfAccounts,
      _CorporateGroupAccount,
      _GLAccountGroupText,
      _GLAccountType,
      _GLAccountTypeText,
      _GLAccountSubtype,
      _CompanyCode,
      _GLAccountText,
      _GLAcctImplementStatus,
      _BankReconAcctTxt,
      _CostElement,
      _CreatedBy,
      Acct._GLAcctInChartOfAcctsStatus

      //  _association_name // Make association public

}