R_OperatingGLAcctInCoCodeTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@Search.searchable: true
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Operating G/L Account Company Code Data'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #S,
  dataClass: #CUSTOMIZING
}
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.sapObjectNodeType.name: 'GeneralLedgerAccount'
@AccessControl.privilegedAssociations: [ '_CreatedBy' ]


/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view entity R_OperatingGLAcctInCoCodeTP
  as select from           I_GLAccountInCompanyCode as skb1
    left outer to one join I_CompanyCode            as t001 on skb1.CompanyCode = t001.CompanyCode
  association        to parent R_OperatingGLAccountTP  as _GLAcctInCOA            on  $projection.ChartOfAccounts = _GLAcctInCOA.ChartOfAccounts
                                                                                  and $projection.GLAccount       = _GLAcctInCOA.GLAccount

  association [0..1] to I_Reconciliationaccttype       as _ReconciliationAcctType on  $projection.ReconciliationAccountType = _ReconciliationAcctType.ReconciliationAccountType
  association [0..1] to I_FieldStatusGroup             as _FieldStatusGroup       on  $projection.FieldStatusVariant = _FieldStatusGroup.FieldStatusVariant
                                                                                  and $projection.FieldStatusGroup   = _FieldStatusGroup.FieldStatusGroup
  association [0..1] to I_FieldStatusVariant           as _FieldStatusVariant     on  $projection.FieldStatusVariant = _FieldStatusVariant.FieldStatusVariant
  association [0..1] to I_TaxCategory                  as _TaxCategory            on  $projection.CompanyCode = _TaxCategory.CompanyCode
                                                                                  and $projection.TaxCategory = _TaxCategory.TaxCategory
  association [0..1] to I_GLAcctInCoCodeImplementStat  as _GLAcctInCoCodeStatus   on  $projection.CompanyCode = _GLAcctInCoCodeStatus.CompanyCode
                                                                                  and $projection.GLAccount   = _GLAcctInCoCodeStatus.GLAccount
  association [0..1] to I_GLAcctInCOAImplementStatType as _GLAcctImplementStatus  on  $projection.GLAcctCoCodeImplementStatus = _GLAcctImplementStatus.GLAcctCOAImplementStatus
  association [0..1] to I_GLAcctInDefaultLanguageText  as _Text                   on  $projection.ChartOfAccounts = _Text.ChartOfAccounts //I_GLAccountText

                                                                                  and $projection.GLAccount       = _Text.GLAccount
  association [0..1] to I_PlanningLevel                as _PlanningLevel          on  $projection.PlanningLevel = _PlanningLevel.PlanningLevel
  association [0..1] to I_GLAccountInChartOfAccounts   as _AlternativeGLAccount   on  t001.CountryChartOfAccounts      = _AlternativeGLAccount.ChartOfAccounts
                                                                                  and $projection.AlternativeGLAccount = _AlternativeGLAccount.GLAccount
  association [0..1] to I_Housebank                    as _HouseBank              on  $projection.HouseBank = _HouseBank.HouseBank
  association [0..1] to I_HouseBankAccount             as _HouseBankAccount       on  $projection.HouseBank = _HouseBankAccount.HouseBankAccount
  association [0..1] to I_AcctgDocItmDspSqncRuleText   as _SortKeyText            on  $projection.AcctgDocItmDisplaySequenceRule = _SortKeyText.AcctgDocItmDisplaySequenceRule
                                                                                  and _SortKeyText.Language                      = $session.system_language
  association [0..1] to I_CurrencyText                 as _CurrencyText           on  $projection.GLAccountCurrency = _CurrencyText.Currency

  association [0..1] to I_IntrstCalcFrequencyInMonthsT as _IntrstFreqText         on  $projection.IntrstCalcFrequencyInMonths = _IntrstFreqText.IntrstCalcFrequencyInMonths
  association [0..1] to I_InterestCalculationCode      as _InterestCode           on  $projection.InterestCalculationCode     = _InterestCode.InterestCalculationCode
  
  association [0..1] to I_UserContactCard              as _CreatedBy              on  $projection.CreatedByUser = _CreatedBy.ContactCardID
  
{
      @ObjectModel.text.element: [ 'GLAccount' ]
      @Consumption.semanticObject: 'GLAccount'
      @Search.defaultSearchElement:true
      @Search.fuzzinessThreshold:0.8
      @Search.ranking:#HIGH
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_GLAccount',
                     element: 'GLAccount' }
        }]
  key skb1.GLAccount,
      @ObjectModel.text.element: [ 'CompanyCode' ]
      @ObjectModel.sort.enabled: false
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
  key skb1.CompanyCode,
      @ObjectModel.text.element: [ 'ChartOfAccounts' ]
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ChartOfAccountsStdVH',
                     element: 'ChartOfAccounts' }
        }]
  key t001.ChartOfAccounts              as ChartOfAccounts,
      t001.CompanyCodeName              as CompanyCodeName,
      skb1.AuthorizationGroup,
      skb1.AccountingClerk,
      skb1.LastInterestCalcRunDate,
      skb1.CreationDate,
      skb1.CreatedByUser,
      @Semantics.systemDateTime.localInstanceLastChangedAt: true
      @Semantics.systemDateTime.lastChangedAt: true
      cast(case
        when skb1.LastChangeDateTime    = 0 then cast( '19700101010101' as timestamp )
        else skb1.LastChangeDateTime
      end as timestamp preserving type) as LastChangeDateTime,
      skb1.PlanningLevel,
      skb1.HouseBank,
      skb1.HouseBankAccount,
      skb1.ExchRateDifferencesAccountDetn,
      @ObjectModel.foreignKey.association: '_ReconciliationAcctType'
      skb1.ReconciliationAccountType,
      //      @ObjectModel.foreignKey.association: '_TaxCategory'

      skb1.TaxCategory,
      skb1.InterestCalculationCode,
      skb1.GLAccountCurrency,
      skb1.ReconciliationAcctIsChangeable,
      skb1.IsManagedExternally,
      //      cast( substring(skb1.wmeth, 1, 1) as fac_gl_acct_extern_ind preserving type ) as IsManagedExternally,

      skb1.IsAutomaticallyPosted,
      skb1.LineItemDisplayIsEnabled,
      skb1.SupplementIsAllowed,
      skb1.IsOpenItemManaged,
      skb1.InterestCalculationDate,
      skb1.IntrstCalcFrequencyInMonths,
      skb1.AcctgDocItmDisplaySequenceRule,
      skb1.AlternativeGLAccount,
      //      cast(skb1.altkt as fis_alternativeglaccount preserving type ) as AlternativeGLAccount,

      skb1.JointVentureRecoveryCode,
      //      @API.element.releaseState: #DEPRECATED

      //      @API.element.successor: 'CommitmentItemShortID'

//      skb1.CommitmentItemShortID,

      //      cast(skb1.fipos as fmis_ci_internalname preserving type)      as CommitmentItemShortID,

      skb1.TaxCodeIsRequired,
      skb1.BalanceHasLocalCurrency,
      skb1.ValuationGroup,
      skb1.APARToleranceGroup,
      skb1.AccountIsBlockedForPosting,
      skb1.AccountIsMarkedForDeletion,
      skb1.ClearingIsLedgerGroupSpecific,
      skb1.CashPlanningGroup,
      skb1.IsCashFlowAccount,
      skb1.GLAcctInflationKey,
      skb1.FieldStatusGroup,
      skb1.MultiCurrencyAccountingCode,
      skb1.IsExtendedOpenItemManaged,
      //_Text.GLAccountName                                           as GLAccountName,

      t001.ControllingArea              as ControllingArea,
      @ObjectModel.foreignKey.association: '_FieldStatusVariant'
      t001.FieldStatusVariant           as FieldStatusVariant,
      t001.CountryChartOfAccounts       as CountryChartOfAccounts,

      case when
           skb1._GLAcctInCoCodeStatus.GLAcctCoCodeImplementStatus is null then
           'I'
         else
           skb1._GLAcctInCoCodeStatus.GLAcctCoCodeImplementStatus
         end                            as GLAcctCoCodeImplementStatus,
      skb1._GLAcctInCoCodeStatus,
      _AlternativeGLAccount,
      _ReconciliationAcctType,
      _FieldStatusGroup,
      _FieldStatusVariant,
      _TaxCategory,
      _GLAcctInCOA,
      _PlanningLevel,
      //  _GLAcctInCoa,

      _Text,
      //_glacctText,

      //  _GLAcctInCoCodeStatus

      //  _glacctincoa2

      _GLAcctImplementStatus,
      _HouseBank,
      _HouseBankAccount,
      _SortKeyText,
      _CurrencyText,
      _IntrstFreqText,
      _InterestCode,
      _CreatedBy

}