R_MaintenanceChecklistTP

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Manage Inspection Checklists TP'
@VDM.viewType: #TRANSACTIONAL
@VDM.usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.sapObjectNodeType.name: 'InspectionLot'
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
define root view entity R_MaintenanceChecklistTP 
 as select from I_MaintOrderInspectionLot
 association [0..1] to I_MaintenanceOrderOperation as _MaintenanceOrderOp on  $projection.MaintenanceBusinessSubobject = _MaintenanceOrderOp.MaintOrderOperationInternalID
 association [1..1] to I_InspectionLotAggregate    as _InspLotAgg         on  $projection.InspectionLot = _InspLotAgg.InspectionLot
 association [0..1] to C_InspUsgDescCF             as _CalFields          on  $projection.InspectionLot = _CalFields.InspectionLot
 association [0..1] to I_TechnicalObject           as _TechnicalObject    on  $projection.TechnicalObject = _TechnicalObject.TechnicalObject
                                                                         and  $projection.TechObjIsEquipOrFuncnlLoc = _TechnicalObject.TechObjIsEquipOrFuncnlLoc 
 association [0..1] to I_Plant                     as _Plant              on  $projection.Plant = _Plant.Plant                                                                        
{
 
   key InspectionLot, 
   @ObjectModel.text.element:  [ 'MaintenanceOrderDesc' ]
   key MaintenanceOrder,
   key cast(_MaintenanceOrderOp.MaintenanceOrderOperation as maintenanceorderoperation preserving type) as MaintenanceOrderOperation,
   _MaintenanceOrderOp.MaintOperationalChecklistType,
   MaintenanceBusinessSubobject,
   Plant,
   InspectionLotType,
   InspectionLotText,
   InspectionLotObjectText,
   Equipment,
   FunctionalLocation,
   cast( case when MainChecklistIsDeactivated = 'X'
   then 'Deactivated'
   else 'Activated' end as char15 ) as ActivationStatusName, 
  // If Equipment is available in inspection lot, Technical Object will hold Equipment,

  // otherwise will hold Functional Location Data

      case when Equipment = '' then
                  cast( FunctionalLocation as eams_tec_obj )
             else cast( Equipment as eams_tec_obj ) end             as TechnicalObject,
  // Technical Object Type : If Equipment is available in inspection lot, Technical Object will hold Equipment,

  // otherwise will hold Functional Location Data

      cast( case when Equipment = '' and FunctionalLocation = '' then ''
            else case when Equipment = '' then 'EAMS_FL'
            else 'EAMS_EQUI' end end as eams_tec_obj_type_value ) as TechObjIsEquipOrFuncnlLoc,
   //Inspection Lot Status

      cast ( _CalFields.InspLotCompltnStatus as vdm_insplotcompltnstatus preserving type )            as InspLotCompltnStatus, 
   //Results Status()

     cast ( _CalFields.InspLotRsltRecgStatus as vdm_qminsplotrsltrecgstatus preserving type ) as InspLotRsltRecgStatus,    
   //Total Characteristics Count in a Inspection Lot

     _InspLotAgg.InspCharacteristicCount,   
   //Characteristics Count in a Inspection Lot for Micro Chart

    _InspLotAgg.InspCharAcceptedCount,
    _InspLotAgg.InspCharRejectedCount,
    _InspLotAgg.InspCharOpenCount,
    //Order Description as a Text

     @Semantics.text: true
    _MaintenanceOrderOp._MaintenanceOrder.MaintenanceOrderDesc,
    //Operation Description as a Text

    _MaintenanceOrderOp.OperationDescription,
    //Plant Description as a Text

    _Plant.PlantName,
    //Usage Decision Fields

    I_MaintOrderInspectionLot._InspLotUsageDecision.InspLotUsageDecisionValuation,
    I_MaintOrderInspectionLot._InspLotUsageDecision._UsageDecisionValuation._Text[1:Language=$session.system_language].InspLotUsgeDcsnValuationText,
    I_MaintOrderInspectionLot._InspLotUsageDecision._UsageDecisionCode._Text[1:Language=$session.system_language].UsageDecisionCodeText,
    I_MaintOrderInspectionLot._InspLotUsageDecision.InspectionLotUsageDecisionCode,
    @EndUserText: { label: 'Criticality for Usage Decision Code', quickInfo: 'Criticality for Usage Decision Code' } 
      case I_MaintOrderInspectionLot._InspLotUsageDecision.InspLotUsageDecisionValuation
       when 'A' then 3
       when 'R' then 1
       else 0
      end                                        as UsageDecisionCodeCriticality,   
      //Schedule Start date and end date

    _MaintenanceOrderOp._MaintenanceOrder.ScheduledBasicStartDate,
    _MaintenanceOrderOp._MaintenanceOrder.ScheduledBasicEndDate,
    //Fields For DCL

    MaintenancePlanningPlant,
    MaintenanceOrderType,
    AuthorizationGroup,
   //Make association public

   //For Technical Object Description as a Text

    _TechnicalObject
}
where MaintenanceBusinessSubobject <> ' '
and _MaintenanceOrderOp.MaintenanceOrderOperation <> ' '