I_MAINTORDERINSPECTIONLOT

CDS View

Maintenance Order Inspection Lot

I_MAINTORDERINSPECTIONLOT is a CDS View in S/4HANA. Maintenance Order Inspection Lot. It contains 1 fields. 5 CDS views read from this table.

Used by 5 CDS view(s) 1 fields

CDS Views using this table (5)

ViewTypeJoinVDMDescription
A_MaintOrderInspectionLot view_entity from CONSUMPTION Checklist information of work order
C_MaintJobWorkItemChecklist view_entity from CONSUMPTION Maintenance Work Item Check List
P_MaintOrdOpCheckList view_entity from COMPOSITE Maintenance Order Check List
R_MaintenanceChecklistTP view_entity from TRANSACTIONAL Manage Inspection Checklists TP
R_MaintInspLotCharacteristic view_entity from TRANSACTIONAL Characteristics in Manage Inspection

Fields (1)

KeyField CDS FieldsUsed in Views
KEY InspectionLot InspectionLot 2 
@AbapCatalog.sqlViewName: 'IMAINTORDINSPLOT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Maintenance Order Inspection Lot'
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        //serviceQuality: #B    //Note 3165545 comment

        serviceQuality: #C      //Note 3165545

    }
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: { viewType: #COMPOSITE }
define view I_MaintOrderInspectionLot
  as select from I_MaintenanceOrder     as _MaintenanceOrder
    inner join   I_MaintenanceChecklist as _MaintenanceChecklist on  _MaintenanceChecklist.MaintenanceBusinessObject     = _MaintenanceOrder.MaintenanceOrder
                                                                 and _MaintenanceChecklist.MaintenanceChecklistType      = 'BUS2045'
                                                                 and _MaintenanceChecklist.MaintenanceBusinessObjectType = 'BUS2007'
    inner join   I_InspectionLot        as _InspectionLot        on _InspectionLot.InspectionLot = _MaintenanceChecklist.MaintenanceChecklist

  association [0..1] to I_InspLotUsageDecision  as _InspLotUsageDecision     on  $projection.InspectionLot = _InspLotUsageDecision.InspectionLot
  association [0..*] to I_InspectionOperation   as _InspectionOperation      on  $projection.InspectionLot = _InspectionOperation.InspectionLot

  // Foreign Key Associations

  association [1..1] to I_Plant                 as _Plant                    on  $projection.Plant = _Plant.Plant
  association [1..1] to I_InspectionLotType     as _InspectionLotType        on  $projection.InspectionLotType = _InspectionLotType.InspectionLotType
  association [1..1] to I_InspectionLotOrigin   as _InspectionLotOrigin      on  $projection.InspectionLotOrigin = _InspectionLotOrigin.InspectionLotOrigin
  association [0..1] to I_BillOfOperationsType  as _BillOfOperationsType     on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [0..1] to I_BillOfOperationsGroup as _BillOfOperationsGroup    on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                             and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup
  association [0..1] to I_Customer              as _InspLotSelectionCustomer on  $projection.InspLotSelectionCustomer = _InspLotSelectionCustomer.Customer
  association [0..1] to I_Customer              as _Customer                 on  $projection.Customer = _Customer.Customer
  association [0..1] to I_Supplier              as _InspLotSelectionSupplier on  $projection.InspLotSelectionSupplier = _InspLotSelectionSupplier.Supplier
  association [0..1] to I_Supplier              as _Supplier                 on  $projection.Supplier = _Supplier.Supplier
  association [1..1] to I_Indicator             as _InspectionLotHasUsgeDcsn on  $projection.InspectionLotHasUsageDecision = _InspectionLotHasUsgeDcsn.IndicatorValue
 // association [1..1] to I_MaintenanceOrder      as _maintorder               on  $projection.MaintenanceOrder = _maintorder.MaintenanceOrder


{
  key _MaintenanceOrder.MaintenanceOrder,
  key _InspectionLot.InspectionLot,

      @ObjectModel.foreignKey.association: '_Plant'
      _InspectionLot.Plant,
      @ObjectModel.foreignKey.association: '_InspectionLotType'
      _InspectionLot.InspectionLotType,
      @ObjectModel.foreignKey.association: '_InspectionLotOrigin'
      _InspectionLot.InspectionLotOrigin,
      _InspectionLot.StatusObject,
      _InspectionLot.StatusObjectCategory,
      _InspectionLot.StatusProfile,
      _InspectionLot.GoodsReceiptIsMovedToBlkdStock,
      _InspectionLot.InspectionLotIsSkipped,
      _InspectionLot.InspLotCreatedOnLocalDate,
      _InspectionLot.InspLotCreatedOnLocalTime,
      _InspectionLot.InspectionLotCreatedBy,
      _InspectionLot.InspectionLotCreatedOn,
      _InspectionLot.InspectionLotCreatedOnTime,
      _InspectionLot.InspectionLotChangedBy,
      _InspectionLot.InspectionLotChangeDate,
      _InspectionLot.InspectionLotChangeTime,
      _InspectionLot.ChangedDateTime,
      _InspectionLot.InspectionLotStartDate,
      _InspectionLot.InspectionLotStartTime,
      _InspectionLot.InspectionLotEndDate,
      _InspectionLot.InspectionLotEndTime,
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
      _InspectionLot.BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
      _InspectionLot.BillOfOperationsGroup,
      _InspectionLot.BillOfOperationsUsage,
      _InspectionLot.BillOfOperationsVariant,
      _InspectionLot.BillOfOperationsChangeStateID,
      _InspectionLot.InspLotSelBillOfOperationsUsge,
      _InspectionLot.InspLotSelectionValidFromDate,
      _InspectionLot.ManufacturingOrder,
      _InspectionLot.OrderInternalBillOfOperations,
      @ObjectModel.foreignKey.association: '_InspLotSelectionCustomer'
      _InspectionLot.InspLotSelectionCustomer,
      @ObjectModel.foreignKey.association: '_Customer'
      _InspectionLot.Customer,
      @ObjectModel.foreignKey.association: '_InspLotSelectionSupplier'
      _InspectionLot.InspLotSelectionSupplier,
      @ObjectModel.foreignKey.association: '_Supplier'
      _InspectionLot.Supplier,
      _InspectionLot.Language,
      _InspectionLot.InspectionLotText,
      _InspectionLot.InspectionLotObjectText,
      _InspectionLot.InspLotNmbrAddlRecordedCharc,
      _InspectionLot.InspLotNmbrOpenShortTermCharc,
      _InspectionLot.InspLotNmbrOpenLongTermCharc,
      _InspectionLot.InspLotUsageDecisionTool,
      @ObjectModel.foreignKey.association: '_InspectionLotHasUsgeDcsn'
      _InspectionLot.InspectionLotHasUsageDecision,

      _MaintenanceOrder.MaintenanceOrderType,
      _MaintenanceOrder.MaintenancePlanningPlant,
      _MaintenanceOrder.MaintenancePlannerGroup,
      _MaintenanceOrder.MaintObjectLocAcctAssgmtNmbr,
      //_MaintenanceOrder.Equipment,                         //Note 3165545 comment

      _MaintenanceOrder._Equipment.AuthorizationGroup,       //Note 3165545


      _MaintenanceChecklist.MaintBusinessSubobjectType,
      _MaintenanceChecklist.MaintenanceBusinessSubobject,
      _MaintenanceChecklist.MaintChecklistTemplateType,
      _MaintenanceChecklist.MaintenanceChecklistTemplate,
      _MaintenanceChecklist.Equipment,                      //Note 3165545 un-comment

      _MaintenanceChecklist.FunctionalLocation,
      _MaintenanceChecklist.MaintChklstAddlInformationText,
      _MaintenanceChecklist.MainChecklistIsDeactivated,
      _MaintenanceChecklist.MaintenanceBusinessObjectType,
      _MaintenanceChecklist.MaintenanceChecklistType,
      
      _InspLotUsageDecision,
      _InspectionOperation,
      _Plant,
      _InspectionLotType,
      _InspectionLotOrigin,
      _BillOfOperationsType,
      _BillOfOperationsGroup,
      _InspLotSelectionCustomer,
      _Customer,
      _Supplier,
      _InspLotSelectionSupplier,
      _InspectionLotHasUsgeDcsn,
      _MaintenanceOrder._LocationAccountAssignment
      //_MaintenanceOrder._Equipment                        //Note 3165545 comment        

      
}

Learn More