R_InsuranceClaimTP

@AbapCatalog.extensibility.extensible
@AbapCatalog.extensibility.elementSuffix: 'ICA'
@AbapCatalog.extensibility.quota.maximumFields: 100
@AbapCatalog.extensibility.quota.maximumBytes: 1000
@AbapCatalog.extensibility.dataSources: ['_Extension']
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Insurance Claim - TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM: {
  viewType:#TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
@ObjectModel: {
   semanticKey: [ 'InsuranceClaim' ],
usageType:{
  dataClass:      #TRANSACTIONAL,
  serviceQuality: #C,
  sizeCategory:   #XL
}
}
define root view entity R_InsuranceClaimTP
  as select from I_InsuranceClaim
  composition [0..*] of R_InsurClmByDiagnosisGroupTP    as _InsurClmByDiagnosisGroup
  composition [0..*] of R_InsurClmByLicensePlateNoTP    as _InsurClmByLicensePlateNo
  composition [0..*] of R_InsuranceClaimByHandlerTP     as _InsuranceClaimByHandler
  composition [0..*] of R_InsuranceClaimByDateOfLossTP  as _InsuranceClaimByDateOfLoss
  composition [0..*] of R_InsurClmSubclaimTP            as _InsuranceSubclaim
  composition [0..*] of R_InsurClaimItemTP              as _InsuranceClmItem
  composition [0..*] of R_InsurClaimTaskTP              as _InsuranceClmTask
  composition [0..*] of R_InsurClmCoverageReferralTP    as _InsuranceClmCvrgReferral
  composition [0..*] of R_InsurClmParticipantTP         as _InsuranceClmParticipant
  composition [0..*] of R_InsuranceClaimPaymentTP       as _InsuranceClaimPayment
  composition [0..*] of R_InsuranceClaimReserveTP       as _InsuranceClaimReserve
  composition [0..*] of R_InsurClmDamagedObjectTP       as _InsuranceClaimDamagedObject
  composition [0..*] of R_InsurClmPerformerTP           as _InsuranceClaimPerformer
  composition [0..*] of R_InsurClmPolicySnapshotTP      as _InsurClmPolicySnapshot
  composition [0..*] of R_InsuranceClaimNoteTP          as _InsurClmNote
  composition [0..*] of R_InsurClmFactCaptureTP         as _InsurClmFactCapture
  composition [0..*] of R_InsurClmObjectAssignmentTP    as _InsurClmObjAssignment
  composition [0..*] of R_InsurClmSubrogationTP         as _InsurClmSubrogation
  composition [0..*] of R_InsurClmLitigationHeaderTP    as _InsurClmLitigationHeader
  composition [0..*] of R_InsurClmNegotiationHeaderTP   as _InsurClmNegotiationHeader
  composition [0..*] of R_InsuranceClaimItemGroupingTP  as _InsuranceClaimItemGrouping
  composition [0..*] of R_InsurClmWaitPeriodTP          as _InsurClmWaitPeriod
  composition [0..*] of R_InsurClmTaxHeaderTP           as _InsurClmTaxHeader 
  composition [0..*] of R_InsurClmLoanHeaderTP          as _InsurClmLoanHeader
  composition [0..*] of R_InsurClmImpairmentTP          as _InsurClmImpairment
  composition [0..*] of R_InsurClmBnftSplitPerdcHdrTP   as _InsurClmBnftSplitPerdcHdr
  composition [0..*] of R_InsurClmSpclRightBnftSplitTP  as _InsurClmSpclRightBnftSplit
  composition [0..*] of R_InsurClmFundHeaderTP          as _InsurClmFundHeader
  composition [0..*] of R_InsurClmBenefitSplitHeaderTP  as _InsurClmBenefitSplitHeader
  composition [0..*] of R_InsurClmAttachmentOutboundTP  as _InsurClmAttachOutbound
  composition [0..*] of R_InsurClmAttachmentTP          as _InsurClmAttachment
  composition [0..*] of R_InsurClmArchiveLinkAssgmtTP   as _InsurClmArchiveLinkAssgmt
  composition [0..*] of R_InsurClmPrtcpntWrkrsCompnTP   as _InsurClmPrtcpntWrkrsCompn
  association [1..1] to E_InsuranceClaim_2              as _Extension  on  $projection.InsuranceClaim = _Extension.InsuranceClaim
{

  key InsuranceClaim,
      InsuranceContract,
      InsurClmPolicyProduct as InsuranceClaimContractControl,//GTNC approval

      ChangedOnDateTime as LastChangeDateTime,
      LastChangedByUser,
      CreationDateTime,
      CreatedByUser,
       @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimLifeCycleStatus' 
      InsurClmLifeCycSts,
      @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimStatReason'
      InsurClmStatReason,
      @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimType'
      InsurClmType,
      @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClmAuthorizationGroup'
      InsurClmAuthznGrp,
      InsurClmPolicyProdGeneration,
      InsurClmPolicyProductVersion,
      @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimIncidentType'
      InsurClmIncdntType,
      @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimCauseOfLoss'
      InsurClmCauseOfLoss,
      InsurClmLossLocAddressID,
      InsurClmTypeGeneration,
      InsurClmTypeVers,
      @Semantics.dateTime:true
      dats_tims_to_tstmp (InsurClmDateOfLoss, InsurClmTimeOfLoss,
        InsurClmTimeZoneOfLoss,
        $session.client,'NULL'  ) as InsurClmLossDateTime, //GTNC approval

      InsurClmContractLastRenewal,
      InsurClmVersionChangeTime,
      InsurClmAssignUUID,
      @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimComplexity'
      InsurClmComplexity,
      InsurClmJurisdictionCountry,
      InsurClmJurisdictionRegion,
      @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimCovered'
      InsurClmCovered,
      @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimBenefitTypeTree'
      InsurClmBenefitTypeTree,
      InsurClmBnftTypeTreeGeneration,
      InsurClmBnftTypeTreeVersion,
      InsurClmIsWithoutProduct,
      InsurClmIsDummyClaim,
      InsurClmReportedDate,
      InsurClmAgentReportedDate,
      InsurClmSensitiveClaim,

      _InsuranceSubclaim,
      _InsuranceClmItem,
      _InsuranceClmTask,
      _InsuranceClmCvrgReferral,
      _InsuranceClmParticipant,
      _InsuranceClaimPayment,
      _InsuranceClaimReserve,
      _InsuranceClaimDamagedObject,
      _InsuranceClaimPerformer,
      _InsurClmPolicySnapshot,
      _InsuranceClaimByDateOfLoss,
      _InsuranceClaimByHandler,
      _InsurClmByLicensePlateNo,
      _InsurClmByDiagnosisGroup,
      _InsurClmNote,
      _InsurClmFactCapture,
      _InsurClmObjAssignment,
      _InsurClmSubrogation,
      _InsurClmLitigationHeader,
      _InsurClmNegotiationHeader,
      _InsuranceClaimItemGrouping,
      _InsurClmWaitPeriod,
      _InsurClmTaxHeader,
      _InsurClmLoanHeader,
      _InsurClmImpairment,
      _InsurClmBnftSplitPerdcHdr,
      _InsurClmSpclRightBnftSplit,
      _InsurClmFundHeader,
      _InsurClmBenefitSplitHeader,
      _InsurClmAttachOutbound,
      _InsurClmAttachment,
      _InsurClmArchiveLinkAssgmt,
      _InsurClmPrtcpntWrkrsCompn
}