R_InsurClmSubclaimTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Insurance Subclaim - TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM: {
  viewType:#TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
@ObjectModel: {
   semanticKey: [ 'InsuranceClaim' ],
usageType:{
  dataClass:      #TRANSACTIONAL,
  serviceQuality: #C,
  sizeCategory:   #XL
}
}
define view entity R_InsurClmSubclaimTP
  as select from I_InsurClmSubclaim
  composition [0..*] of R_InsurClaimSubclaimItemTP   as _InsuranceClaimSubclaimItem
  composition [0..*] of R_InsurClmSubclaimPaymentTP  as _InsuranceClaimSubclaimPayment
  composition [0..*] of R_InsurClmSubclaimReserveTP  as _InsuranceClaimSubclaimReserve
  composition [0..*] of R_InsurClmSubclmPerformerTP  as _InsuranceClmSubclmPerformer
  composition [0..*] of R_InsurClmSubclmDiagnosisTP  as _InsurClmSubclmDiagnosis
  composition [0..*] of R_InsurClmSubclmRoleAssgmtTP as _InsurClmSubclmRoleAssgmt
  composition [0..*] of R_InsurClmSubclmItemGroupingTP as _InsurClmSubclmItemGrouping
  composition [0..*] of R_InsurClmWrkrsCompnHdrTP    as _InsurClmWrkrsCompnHdr
  composition [0..*] of R_InsurClmSubclmAttachmentTP as _InsurClmSubclmAttachment
  composition [0..*] of R_InsurClmSubclmAttchOutbTP  as _InsurClmSubclmAttachOut
  // composition [0..*] of R_InsurClmSubclmDmgdObjTP   as _InsuranceClmSubclmDmgdObj

  // composition [0..*] of R_InsurClmSubclmRsrvPaytTP as _InsuranceClmSubclmFinOvw

  
  association to parent R_InsuranceClaimTP as _InsuranceClaim 
        on  $projection.InsuranceClaim = _InsuranceClaim.InsuranceClaim
        
  association [1..1] to E_InsuranceSubClaim as _Extension on $projection.InsuranceClaim = _Extension.InsuranceClaim
                                                         and $projection.InsurClmSubclm = _Extension.InsurClmSubclm       
{
  key  InsuranceClaim,
  key  InsurClmSubclm,
       CreationDateTime,
       LastChangeDateTime,
       @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimLifeCycleStatus'
       InsurClmLifeCycSts,
       InsurClmSubclmStsChgdOnDteTime,
       @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimSubclaimType'
       InsurClmSubclmType,
       @ObjectModel.sapObjectNodeTypeReference: 'InsurClmSubrogtnRecoveryStatus'
       InsurClmSubrogtnRecoveryStatus,
       InsurClmSubclaimDescription,
       @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimBenefitTypeTree'
       InsurClmBenefitTypeTree,
       InsurClmBnftTypeTreeGeneration,
       InsurClmBnftTypeTreeVersion,
       InsurClmCoverage as InsuranceClaimCoverageControl,
       IsInProcess,
       IsClosed,
       InsurClmSubclaimAssignUUID,
       @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimCovered'
       InsurClmCvrgConfirmedFlag,
       InsurClmFraudFlag,
       @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimSalvageFlag'
       InsurClmSalvageFlag,
       InsurClmLitigationFlag,
       InsurClmNegotiationFlag,
       @ObjectModel.sapObjectNodeTypeReference: 'InsurClmSubclmStsRsn'
       InsurClmSubclmStsRsn,
       @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimComplexity'
       InsurClmComplexity,
       InsurClmIsOtherInsurance,
       @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClmSubrogtnPotential'
       InsurClmSubrogtnPotential,
       InsurClmContractVersion,
       
       //Associations

       _InsuranceClaim,
       _InsuranceClaimSubclaimItem,
       _InsuranceClaimSubclaimPayment,
       _InsuranceClaimSubclaimReserve,
       _InsuranceClmSubclmPerformer,
       //_InsuranceClmSubclmFinOvw,

       _InsurClmSubclmDiagnosis,
       _InsurClmSubclmRoleAssgmt,
       _InsurClmSubclmItemGrouping,
       _InsurClmWrkrsCompnHdr,
       _InsurClmSubclmAttachment,
       _InsurClmSubclmAttachOut
}