R_HierRuntimeRprstnNode

@AbapCatalog.sqlViewName: 'RHRRPNODE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Hierarchy Node'
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@ObjectModel: {
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #C,
    sizeCategory: #XXL
   }
}
@ClientHandling.algorithm: #SESSION_VARIABLE
define view R_HierRuntimeRprstnNode
  as select from hrrp_node_n
  association [0..*] to R_HierRuntimeRprstnNodeText as _Text                on  $projection.HierarchyID        = _Text.HierarchyID
                                                                            and $projection.ValidityEndDate    = _Text.ValidityEndDate
                                                                            and $projection.HierarchyNode      = _Text.HierarchyNode
                                                                            and $projection.HierarchyNodeClass = _Text.HierarchyNodeClass
                                                                            and $projection.ParentNode         = _Text.ParentNode
                                                                            and $projection.HierarchyVersion   = _Text.HierarchyVersion
  association [0..1] to R_HierRuntimeRepresentation as _Hierarchy           on  $projection.HierarchyID      = _Hierarchy.HierarchyID
                                                                            and $projection.HierarchyVersion = _Hierarchy.HierarchyVersion
                                                                            and $projection.ValidityEndDate  = _Hierarchy.ValidityEndDate
  association [0..1] to I_WBSElementBasicData       as _WBSElementBasicData on  $projection.WBSElement = _WBSElementBasicData.WBSElement
  association [0..1] to I_ProjectBasicData          as _ProjectBasicData    on  $projection.Project = _ProjectBasicData.Project
{

  key          hryid_42                                                  as HierarchyID,
  key          cast( '000000000000001' as hryversn preserving type )     as HierarchyVersion, //keep it for compatibility

               @Semantics.businessDate.to: true
  key          cast(hryvalto as fis_datbi preserving type )              as ValidityEndDate,
               @ObjectModel.text.association: '_Text'
  key          hrynode                                                   as HierarchyNode,
  key          nodecls                                                   as HierarchyNodeClass,
  key          parnode                                                   as ParentNode,
               hrytyp                                                    as HierarchyType,
               @Semantics.businessDate.from: true
               cast(hryvalfrom as fis_datab preserving type )            as ValidityStartDate,
               balind                                                    as DebitCreditCode,
               nodetype                                                  as NodeType,
               nodevalue                                                 as HierarchyNodeVal,
               hryseqnbr                                                 as SequenceNumber,
               hrylevel                                                  as HierarchyNodeLevel,

               //HRRP_SI_CLFD

               kokrs                                                     as ControllingArea, //FIS_KOKRS

               ktopl                                                     as ChartOfAccounts, //FIS_KTOPL

               itclg                                                     as ConsolidationChartOfAccounts,
               sityp                                                     as SubItemCategory,
               scen_id                                                   as ValidationScenarioID,
               fikrs                                                     as FinancialManagementArea,
               fma_fisyear                                               as FinMgmtAreaFiscalYear,
               //HRRP_SI_BETY

               saknr                                                     as GLAccount, //FIS_RACCT

               kostl                                                     as CostCenter, //FIS_KOSTL

               prctr                                                     as ProfitCenter,
               stagr                                                     as StatisticalKeyFigure, //FIS_STAGR

               lstar                                                     as ActivityType, //LEARR

               //_WBSElementBasicData.WBSElementExternalID             as WBSElementExternalID,

               cast( posid as fis_wbs_no_conv preserving type )          as WBSElement,
               fkber                                                     as FunctionalArea,
               bukrs                                                     as CompanyCode,
               segment                                                   as Segment,
               cbttype                                                   as BusinessTransactionType,
               aufnr                                                     as OrderID, //FIS_AUFNR

               fincode                                                   as Fund,
               grant_nbr                                                 as GrantID,
               budget_pd                                                 as BudgetPeriod,
               sponsored_class                                           as SponsoredClass,
               fictr                                                     as FundCenterText,
               sponsored_prog                                            as SponsoredProgram,
               measure                                                   as FundedProgram,
               partner                                                   as BusinessPartnerNumber,
               acc_id                                                    as BankAccountInternalID,
               lqpos                                                     as LiquidityItem,
               gsber                                                     as AssetBusinessArea,
               trtyp                                                     as FinancialTransactionType, //FIS_RMVCT

               kunnr                                                     as CustomerNum,
               lifnr                                                     as AssetSupplier,
               cast( pspid as fis_project_no_conv preserving type  )     as Project,
               //_ProjectBasicData.ProjectExternalID                   as ProjectExternalID,

               matnr                                                     as Material,
               kdgrp                                                     as CustomerGroup,
               land1                                                     as CountryOrRegion,
               item                                                      as FinancialStatementItemTemplate,
               cast ( bunit as fincs_consolidationunit preserving type ) as ConsolidationUnit,
               sitem                                                     as SubItem,
               docty                                                     as ConsolidationDocumentType,
               rcomp                                                     as Company,
               matkl                                                     as MaterialGroup,
               rule_num                                                  as ValidationRuleID,
               bzirk                                                     as SalesDistrict,
               fkart                                                     as BillingDocumentType,
               spart                                                     as Division,
               vkorg                                                     as SalesOrganization,
               vtweg                                                     as DistributionChannel,
               werks                                                     as Plant,
               brsch                                                     as Industry,
               fipex                                                     as CommitmentItem,
               plevl                                                     as PostingLevel, //FC_PLEVL

               fs_product_group                                          as FinancialServicesProductGroup,
               //HRRP_SI_CHSALES

               pricingrelevant                                           as PricingIsRelevant,
               //HRRP_SI_FSVITM

               sign                                                      as SignIsInverted,
               regrouping                                                as GeneralLedgerAgingIncrement,
               fs_leafitem                                               as FinancialStatementLeafItem,
               fs_nodetype                                               as FinancialStatementNodeType,
               hrynodeext                                                as FinStmntNodeFormattedID,
               @Semantics.booleanIndicator:true
               banksplit                                                 as BankAccountGroupingIsSet,
               node_timedep                                              as HierarchyNodeIsTimeDependent,
               congr                                                     as ConsolidationGroup,
               _Text,
               _Hierarchy,
               _WBSElementBasicData,
               _ProjectBasicData
}
where hrytyp not like 'C$%'