R_HierRuntimeRprstnNodeText

@AbapCatalog.sqlViewName: 'RHRRPNODET'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Hierarchy Node Text'
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@ObjectModel: {
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #B,
    sizeCategory: #XXL
   }
}
@ClientHandling.algorithm: #SESSION_VARIABLE
define view R_HierRuntimeRprstnNodeText
  as select from hrrp_nodet_n
  association [0..1] to I_Language                  as _Language  on  $projection.Language = _Language.Language
  association [0..1] to R_HierRuntimeRepresentation as _Hierarchy on  $projection.HierarchyID      = _Hierarchy.HierarchyID
                                                                  and $projection.ValidityEndDate  = _Hierarchy.ValidityEndDate
                                                                  and $projection.HierarchyVersion = _Hierarchy.HierarchyVersion
{

  key       hryid_42                                              as HierarchyID,
  key       cast( '000000000000001' as hryversn preserving type ) as HierarchyVersion, //keep it for compatibility

            @Semantics.businessDate.to: true
  key       cast(hryvalto as fis_datbi preserving type )          as ValidityEndDate,
  key       hrynode                                               as HierarchyNode,
  key       nodecls                                               as HierarchyNodeClass,
  key       parnode                                               as ParentNode,
            @ObjectModel.foreignKey.association: '_Language'
  key       spras                                                 as Language,
            hrytyp                                                as HierarchyType,
            @Semantics.businessDate.from: true
            cast(hryvalfrom as fis_datab preserving type)         as ValidityStartDate,

            @Semantics.text: true
            nodetxt                                               as HierarchyNodeText,
            //HRRP_SI_CLFD

            kokrs                                                 as ControllingArea, //FIS_KOKRS

            ktopl                                                 as ChartOfAccounts, //FIS_KTOPL

            itclg                                                 as ConsolidationChartOfAccounts,
            sityp                                                 as SubItemCategory,
            scen_id                                               as ValidationScenarioID,
            fikrs                                                 as FinancialManagementArea,
            fma_fisyear                                           as FinMgmtAreaFiscalYear,
            node_timedep                                          as HierarchyNodeIsTimeDependent,
            _Hierarchy,
            _Language
}
where hrytyp not like 'C$%'