R_FixedAssetTP

@EndUserText.label: 'Fixed Asset'
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: [ '_ChangeDocument', '_UserCreatedBy', '_UserChangedBy', '_HDMRelation' ]
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  semanticKey : ['CompanyCode', 'MasterFixedAsset', 'FixedAsset'],
  usageType: {
        serviceQuality: #B,
        sizeCategory: #XXL,
        dataClass: #MASTER
    },
  lifecycle.enqueue.expiryBehavior: #RELATIVE_TO_ENQUEUE_START,
  lifecycle.enqueue.expiryInterval: 'PT15M'
 }
@ObjectModel.sapObjectNodeType.name: 'FixedAsset'
@ObjectModel.uniqueIdField: 'ChangeDocObject'
@AbapCatalog.extensibility: {
  extensible: true,
  allowNewCompositions: true
}

@Consumption.dbHints: [ '&PREFER_JOIN_WITH_FDA 0&', 'USE_HEX_PLAN' ]

define root view entity R_FixedAssetTP
  as select from I_FixedAsset as FixedAsset

  composition [1..*] of R_FixedAssetAssignmentTP       as _FixedAssetAssgmt

  composition [0..*] of R_FixedAssetLedgerTP           as _FixedAssetLedger

  composition [0..*] of R_FixedAssetValuationTP        as _FixedAssetValuation

  composition [0..*] of R_FixedAssetMultipleCreationTP as _FixedAssetMultipleCreation

  association [1..1] to E_FixedAsset                   as _Extension                   on  $projection.CompanyCode      = _Extension.CompanyCode
                                                                                       and $projection.MasterFixedAsset = _Extension.MasterFixedAsset
                                                                                       and $projection.FixedAsset       = _Extension.FixedAsset
  association [0..1] to I_PPM_ProjectTask              as _InvestmentProject           on  $projection.InvestmentProjectWBSElement = _InvestmentProject.WBSElementInternalID
                                                                                       and _InvestmentProject.WBSElementInternalID is not initial
  association [0..1] to I_WBSElementBasicData          as _InvestmentProjectWBSElement on  $projection.InvestmentProjectWBSElement = _InvestmentProjectWBSElement.WBSElementInternalID
  association [0..*] to I_ChangeDocument_2             as _ChangeDocument              on  _ChangeDocument.ChangeDocObjectClass = 'FAA_MD'
                                                                                       and _ChangeDocument.ChangeDocObject      = $projection.ChangeDocObject
  association [0..1] to I_UserContactCard              as _UserCreatedBy               on  $projection.CreatedByUser = _UserCreatedBy.ContactCardID
  association [0..1] to I_UserContactCard              as _UserChangedBy               on  $projection.LastChangedByUser = _UserChangedBy.ContactCardID
  association [0..*] to I_HDMRelationTP                as _HDMRelation                 on  $projection.ChangeDocObject   = _HDMRelation.LinkedSAPObjectKey
                                                                                       and $projection.SAPObjectNodeType = _HDMRelation.SAPObjectNodeType

  //Current TDD

  //  association [1..1] to R_FixedAssetAssignmentTP       as _CurrentTDD                  on  $projection.CompanyCode       = _CurrentTDD.CompanyCode

  //                                                                                       and $projection.MasterFixedAsset  = _CurrentTDD.MasterFixedAsset

  //                                                                                       and $projection.FixedAsset        = _CurrentTDD.FixedAsset

  //                                                                                       and _CurrentTDD.ValidityStartDate <= $session.system_date

  //                                                                                       and _CurrentTDD.ValidityEndDate   >= $session.system_date


{
  key   CompanyCode,

  key   MasterFixedAsset,

  key   FixedAsset,

        case when length( CompanyCode ) =  4 then cast( concat( concat( CompanyCode, MasterFixedAsset ), FixedAsset ) as cdobjectv )
             else cast( concat( concat_with_space( CompanyCode, MasterFixedAsset, 1 ), FixedAsset ) as cdobjectv )
        end                                                                     as ChangeDocObject,

        cast('FixedAsset' as abap.char( 30 ))                                   as SAPObjectNodeType,

        FixedAssetExternalID,

        AssetCompletenessStatus,

        AssetLifecycleStatus,

        AssetUnderConstructionStatus,

        IsMainAsset,

        HasHistory,

        AccountIsBlockedForPosting,

        cast(
            (case
              when LegacyDataTransferDate is not null and LegacyDataTransferDate <> '00000000' then 'X'
              else cast ( '' as abap.char(1))
             end
            ) as faa_md_xlegacyasset )                                          as IsLegacyAsset,

        AssetIsForPostCapitalization,

        AssetCreationValidityDate,

        AssetClass,

        AssetScreenLayout,

        AssetAccountDetermination,

        //General

        FixedAssetDescription,

        AssetAdditionalDescription,

        AssetSerialNumber,

        FixedAssetOrderDate,

        BaseUnit,

        //Origin

        Supplier,

        AssetIsAcquiredUsed,

        AssetCountryOfOrigin,

        AssetManufacturerName,

        OriginalMasterFixedAsset,

        OriginalFixedAsset,

        OriginalFixedAssetValueDate,

        OriginalAcquisitionFiscalYear,

        OriginalAcquisitionCurrency,
        @Semantics.amount.currencyCode: 'OriginalAcquisitionCurrency'
        OriginalAcquisitionAmount,

        InHouseProdnPercent,

        AssetTypeName,

        PartnerCompany,

        //Inventory

        Inventory,

        LastInventoryDate,

        InventoryNote,

        InventoryIsCounted,

        //Allocation

        InvestmentReason,

        EnvrnmtlInvestmentReason,

        FixedAssetGroup,

        //RealEstate

        LocalTaxOffice,

        NoticeOfAssessmentTaxID,

        LastAssessmentNoticeDate,

        Municipality,

        LandRegisterDate,

        LandRegisterEntrySequence,

        LandRegisterEntryDate,

        LandRegisterVolume,

        LandRegisterPage,

        LandRegisterMap,

        LandPlot,

        ConveyanceDate,

        @Semantics.quantity.unitOfMeasure: 'AreaSizeUnit'
        AreaSize,

        AreaSizeUnit,

        AssetIsRealEstate,

        //Leasing

        LeaseSupplier,

        LeaseAgreement,

        LeaseAgreementDate,

        LeaseTermEndDate,

        LeaseTermStartDate,

        LeaseDurationInFiscalYears,

        LeaseDurationInFiscalPeriods,

        LeaseType,

        LeasedAssetNote,

        //Property

        PropertyClass,

        FixedAssetPropertyType,

        //Org Change

        LastReorganizationDate,

        //Legacy Information


        LegacyMasterFixedAsset,

        LegacyFixedAsset,

        LegacyFixedAssetCompanyCode,

        LegacyDataTransferDate,

        LegacyDataTransferSequence,


        //AUC

        @Consumption.hidden: true
        ObjectInternalID, //For AuC ANLI


        //Origianl InvestmentProjectWBSElement is with conversion and deprecated in I View

        InvestmentProjectWBSElement_2                                           as InvestmentProjectWBSElement,

        InvestmentOrder, //Not supported yet


        //Admin

        @Semantics.user.createdBy: true
        CreatedByUser,

        CreationDate,
        @Semantics.systemDateTime.createdAt: true
        CreationDateTime,
        @Semantics.user.lastChangedBy: true
        LastChangedByUser,

        LastChangeDate,
        @Semantics.systemDateTime.localInstanceLastChangedAt: true
        @Semantics.systemDateTime.lastChangedAt: true
        LastChangeDateTime,

        //Technical

        @Consumption.hidden: true //Added from CE2108 for technical usage

        cast (cast('' as abap.char(2)) as faa_md_caller_code preserving type  ) as FixedAssetCallerCode,
        @Consumption.hidden: true
        cast( '' as abap_boolean preserving type )                              as IsChanged,
        @Consumption.hidden: true
        cast( '' as abap_boolean preserving type )                              as FxdAstIsRecalculateTriggered,

        cast( '' as abap_boolean preserving type )                              as FxdAstIsTimeRstrcnTriggered,

        cast( '' as faa_md_multi_creation_status preserving type )              as AssetMultipleCreationStatus,

        //Filter only, DO NOT use for other purpose

        cast('' as xafar)                                                       as DepreciationErrorStatus,


        _FixedAssetAssgmt,

        _FixedAssetLedger,

        _FixedAssetValuation,

        _FixedAssetMultipleCreation,

        _InvestmentProject,

        _InvestmentProjectWBSElement,

        _CompanyCode,
        _MasterFixedAsset,
        _AssetClass,
        _UnitOfMeasure,
        _PartnerCompany,
        _AssetAccountDetermination,
        _Supplier,
        _AssetCountryOfOrigin,
        _InvestmentReason,
        _EnvrnmtlInvestmentReason,
        _FixedAssetPropertyType,
        _FixedAssetGroup,
        _InvestmentOrder,
        _AssetLifecycleStatus,
        _AssetCompletenessStatus,
        _AssetUnderConstructionStatus,
        _OriginalAcquisitionCurrency,
        _ChangeDocument,
        _UserCreatedBy,
        _UserChangedBy,
        _HDMRelation
        //        ,_CurrentTDD

}