R_FixedAssetAssignmentTP

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  semanticKey: ['CompanyCode','MasterFixedAsset','FixedAsset','ValidityEndDate'],
  usageType: {
        serviceQuality: #C,
        sizeCategory: #XXL,
        dataClass: #MASTER
    }
 }
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Fixed Asset Assignment'

@AbapCatalog.extensibility: {
  extensible: true,
  allowNewCompositions: true
}

@Consumption.dbHints: [ '&PREFER_JOIN_WITH_FDA 0&' ]

define view entity R_FixedAssetAssignmentTP
  as select from I_FixedAssetAssgmt

  association        to parent R_FixedAssetTP          as _FixedAsset                  on  $projection.CompanyCode      = _FixedAsset.CompanyCode
                                                                                       and $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset
                                                                                       and $projection.FixedAsset       = _FixedAsset.FixedAsset

  association [0..1] to I_BudgetPeriod                 as _BudgetPeriod                on  $projection.BudgetPeriod = _BudgetPeriod.BudgetPeriod
  association [0..1] to I_Grant                        as _Grant                       on  $projection.GrantID = _Grant.GrantID
  association [0..1] to I_WBSElementBasicData          as _WBSElement                  on  $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
  association [0..1] to I_PPM_ProjectTask              as _InvestmentProject           on  $projection.WBSElementInternalID        = _InvestmentProject.WBSElementInternalID
                                                                                       and _InvestmentProject.WBSElementInternalID is not initial
  association [0..1] to I_Fund                         as _Fund                        on  $projection.Fund                    = _Fund.Fund
                                                                                       and $projection.financialmanagementarea = _Fund.FinancialManagementArea
  association [0..1] to I_FundsCenter                  as _FundsCenter                 on  $projection.FundsCenter             = _FundsCenter.FundsCenter
                                                                                       and $projection.financialmanagementarea = _FundsCenter.FinancialManagementArea
                                                                                       and _FundsCenter.ValidityStartDate      <= $session.system_date
                                                                                       and _FundsCenter.ValidityEndDate        >= $session.system_date
  association [0..1] to I_CostCenter                   as _CostCenter                  on  $projection.CostCenter        = _CostCenter.CostCenter
                                                                                       and $projection.ControllingArea   = _CostCenter.ControllingArea
                                                                                       and _CostCenter.ValidityEndDate   >= $session.system_date
                                                                                       and _CostCenter.ValidityStartDate <= $session.system_date
  association [0..1] to I_ProfitCenter                 as _ProfitCenter                on  $projection.ProfitCenter        = _ProfitCenter.ProfitCenter
                                                                                       and $projection.ControllingArea     = _ProfitCenter.ControllingArea
                                                                                       and _ProfitCenter.ValidityEndDate   >= $session.system_date
                                                                                       and _ProfitCenter.ValidityStartDate <= $session.system_date
  association [0..1] to I_TaxJurisdiction              as _TaxJurisdiction             on  $projection.taxcalculationprocedure = _TaxJurisdiction.TaxJurisdictionCalcProcedure
                                                                                       and $projection.TaxJurisdiction         = _TaxJurisdiction.TaxJurisdiction
  association [0..*] to R_HierRuntimeRprstnDplLeafNode as _CostCenterHierarchyLeafNode on  $projection.CostCenter                         = _CostCenterHierarchyLeafNode.UnivHierarchyBusinessEntity
                                                                                       and $projection.ControllingArea                    = _CostCenterHierarchyLeafNode.HierarchyNodeClass
                                                                                       and _CostCenterHierarchyLeafNode.ValidityEndDate   >= $session.system_date
                                                                                       and _CostCenterHierarchyLeafNode.ValidityStartDate <= $session.system_date
                                                                                       and _CostCenterHierarchyLeafNode.HierarchyType     = '0101'
  association [0..*] to R_HierRuntimeRprstnDplLeafNode as _ProfitCenterHierLeafNode    on  $projection.ProfitCenter                    = _ProfitCenterHierLeafNode.UnivHierarchyBusinessEntity
                                                                                       and $projection.ControllingArea                 = _ProfitCenterHierLeafNode.HierarchyNodeClass
                                                                                       and _ProfitCenterHierLeafNode.ValidityEndDate   >= $session.system_date
                                                                                       and _ProfitCenterHierLeafNode.ValidityStartDate <= $session.system_date
                                                                                       and _ProfitCenterHierLeafNode.HierarchyType     = '0106'

  //  association [0..*] to I_JournalEntryItem    as _JournalEntryItem on  $projection.CompanyCode              = _JournalEntryItem.CompanyCode

  //                                                                   and $projection.ReferenceDocumentType    = _JournalEntryItem.ReferenceDocumentType

  //                                                                   and $projection.LogicalSystem            = _JournalEntryItem.LogicalSystem

  //                                                                   and $projection.ReferenceDocumentContext = _JournalEntryItem.ReferenceDocumentContext

  //                                                                   and $projection.ReferenceDocument        = _JournalEntryItem.ReferenceDocument

  //                                                                   and not(

  //    _JournalEntryItem.ReferenceDocumentType                                                                 is initial

  //    and _JournalEntryItem.LogicalSystem                                                                     is initial

  //    and _JournalEntryItem.ReferenceDocumentContext                                                          is initial

  //    and _JournalEntryItem.ReferenceDocument                                                                 is initial

  //  )

  association [1..1] to E_FixedAssetAssgmt             as _Extension                   on  $projection.CompanyCode      = _Extension.CompanyCode
                                                                                       and $projection.MasterFixedAsset = _Extension.MasterFixedAsset
                                                                                       and $projection.FixedAsset       = _Extension.FixedAsset
                                                                                       and $projection.ValidityEndDate  = _Extension.ValidityEndDate
{
  key    CompanyCode,

  key    MasterFixedAsset,

  key    FixedAsset,
         @Semantics.businessDate.to: null
  key    ValidityEndDate,

         ValidityStartDate,

         ControllingArea,

         //_CompanyCode.FinancialManagementArea as FinancialManagementArea,


         CostCenter,

         CostCtrActivityType,

         InternalOrder,

         Fund,

         GrantID,

         FunctionalArea,

         FundsCenter,

         //Original WBSElementInternalID is with conversion and deprecated in I View

         WBSElementInternalID_2                     as WBSElementInternalID,

         _WBSElement.WBSElementExternalID,

         TaxJurisdiction,

         REInternalFinNumber                        as RealEstateObject,

         Segment,

         ProfitCenter,

         BudgetPeriod,

         //Always hidden

         ResponsibleCostCenter,

         Room,

         Plant,

         AssetLocation,

         VehicleLicensePlateNumber,

         //Always hidden

         PersonnelNumber,

         BusinessPlace,

         //Technical fields for document

         ReferenceDocumentType,

         LogicalSystem,

         ReferenceDocumentContext,

         ReferenceDocument,

         _CompanyCode.FinancialManagementArea,
         
         _CompanyCode._Country.TaxCalculationProcedure,

         //Technical

         @Consumption.hidden: true
         cast( '' as abap_boolean preserving type ) as ProfitCenterIsUnauthorized,
         
         
         //Filter only, DO NOT use for other purpose

        cast('' as  fis_cctr_hryid_42)                                          as CostCenterHierarchy,
        cast('' as  fis_cctr_hrynid_50)                                         as CostCenterHierarchyNode,
        cast('' as fis_prctr_hryid_42)                                          as ProfitCenterHierarchy,
        cast('' as fis_prctr_hrynid_50)                                         as ProfitCenterHierarchyNode,
        
         //association

         _FixedAsset,

         _CompanyCode,
         _MasterFixedAsset,
         _CostCenter,
         _CostCenterHierarchyLeafNode,
         _ResponsibleCostCenter,
         _CostCenterActivityType,
         _Plant,
         _InternalOrder,
         _ProfitCenter,
         _ProfitCenterHierLeafNode,
         _Segment,
         _FunctionalArea,
         _ControllingArea,
         _AssetLocation,
         _BudgetPeriod,
         _Employment,
         _Grant,
         _WBSElement,
         _InvestmentProject,
         _Fund,
         _FundsCenter,
         _TaxJurisdiction
         //         _JournalEntryItem

}