R_DebitMemoRequestTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_CreatedByUser', '_LastChangedByUser', '_OutputRequest']
}

@ObjectModel: {
   sapObjectNodeType:{
        name: 'DebitMemoRequest'
   },
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}

@ObjectModel.semanticKey: ['DebitMemoRequest']

@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_Extension'],  
  elementSuffix: 'SDH',
  quota: {
    maximumFields: 204, 
    maximumBytes: 6800
  }  
}  

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Debit Memo Request - TP'

define root view entity R_DebitMemoRequestTP
  as select from I_DebitMemoRequest as DebitMemoRequest
    left outer to one join I_OutputRequest             as OutputRequest on  OutputRequest.OutputControlApplicationObject = DebitMemoRequest.DebitMemoRequest
                                                                        and OutputRequest.OutputControlApplObjectType    = 'SALES_DOCUMENT'
  
  composition [0..*] of R_DebitMemoRequestItemTP       as _Item
  composition [0..*] of R_DebitMemoRequestPartnerTP    as _Partner
  composition [0..*] of R_DebitMemoRequestPrcgElmntTP  as _PricingElement
  composition [0..*] of R_DebitMemoRequestTextTP       as _Text
  association [0..1] to R_OutputRequestTP             as _OutputRequest             on  $projection.OutputRequestUUID = _OutputRequest.OutputRequestUUID
  association [0..1] to I_SlsOrganizationDistrChnl     as _SlsOrganizationDistrChnl on  $projection.SalesOrganization   = _SlsOrganizationDistrChnl.SalesOrganization
                                                                                    and $projection.DistributionChannel = _SlsOrganizationDistrChnl.DistributionChannel
  association [0..1] to I_DebitMemoReqPartner          as _SoldToParty              on  $projection.DebitMemoRequest = _SoldToParty.DebitMemoRequest
                                                                                    and _SoldToParty.PartnerFunction  = 'AG'
  association [0..1] to I_DebitMemoReqPartner         as _Payer                     on  $projection.DebitMemoRequest = _Payer.DebitMemoRequest
                                                                                    and _Payer.PartnerFunction  = 'RG'   
  //Extension Association

  association [1]    to E_SalesDocumentBasic           as _Extension                on  $projection.DebitMemoRequest   = _Extension.SalesDocument                                                                                                                                                                 
{
  key DebitMemoRequest.DebitMemoRequest,

      @ObjectModel.foreignKey.association: '_DebitMemoRequestType'
      DebitMemoRequest.DebitMemoRequestType,

      DebitMemoRequest.DebitMemoRequestDate,
      
      @ObjectModel.foreignKey.association: '_ControllingArea'
      DebitMemoRequest.ControllingArea,

      @ObjectModel.text.element: ['CustomerName']
      DebitMemoRequest.SoldToParty,
      @Semantics.text:true
      _SoldToParty._DfltAddrRprstn.AddresseeFullName                               as CustomerName,

      _Payer.Customer as PayerParty,
      
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      DebitMemoRequest.SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DebitMemoRequest.DistributionChannel,
      @ObjectModel.foreignKey.association: '_OrganizationDivision'
      DebitMemoRequest.OrganizationDivision,

      _SlsOrganizationDistrChnl.ReferenceDistributionChannel,

      @ObjectModel.foreignKey.association: '_SalesOffice'
      DebitMemoRequest.SalesOffice,

      @ObjectModel.foreignKey.association: '_SalesGroup'
      DebitMemoRequest.SalesGroup,

      @ObjectModel.foreignKey.association: '_SalesDistrict'
      DebitMemoRequest.SalesDistrict,

      DebitMemoRequest.PurchaseOrderByCustomer,

      @ObjectModel.foreignKey.association: '_CustomerPurchaseOrderType'
      DebitMemoRequest.CustomerPurchaseOrderType,
      
      @ObjectModel.foreignKey.association: '_CustPurOrdTypeByShipToParty'
      DebitMemoRequest.CustPurOrdTypeByShipToParty,

      DebitMemoRequest.CustomerPurchaseOrderDate,
      
      DebitMemoRequest.PurchaseOrderByShipToParty,
      
      DebitMemoRequest.CorrespncExternalReference,
      
      DebitMemoRequest.CorrespncExtRefByShipToParty,

      @ObjectModel.foreignKey.association: '_CustomerGroup'
      DebitMemoRequest.CustomerGroup,
      
      @ObjectModel.foreignKey.association: '_SDDocumentReason'
      DebitMemoRequest.SDDocumentReason,

      DebitMemoRequest.PricingDate,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      DebitMemoRequest.TotalNetAmount,

      DebitMemoRequest.TransactionCurrency,

      @ObjectModel.foreignKey.association: '_HeaderBillingBlockReason'
      DebitMemoRequest.HeaderBillingBlockReason,
      @ObjectModel.foreignKey.association: '_SDPricingProcedure'
      DebitMemoRequest.SDPricingProcedure,
      
      @ObjectModel.foreignKey.association: '_CustomerPriceGroup'
      DebitMemoRequest.CustomerPriceGroup,
      
      @ObjectModel.foreignKey.association: '_PriceListType'
      DebitMemoRequest.PriceListType,

      @ObjectModel.foreignKey.association: '_IncotermsClassification'
      DebitMemoRequest.IncotermsClassification,

      @ObjectModel.foreignKey.association: '_IncotermsVersion'
      DebitMemoRequest.IncotermsVersion,

      DebitMemoRequest.IncotermsLocation1,

      DebitMemoRequest.IncotermsLocation2,
      
      @ObjectModel.foreignKey.association: '_CustomerPaymentTerms'
      DebitMemoRequest.CustomerPaymentTerms,

      @ObjectModel.foreignKey.association: '_BillingCompanyCode'
      DebitMemoRequest.BillingCompanyCode,

      DebitMemoRequest.PaymentMethod,
      
      @ObjectModel.foreignKey.association: '_CustomerAccountAssgmtGroup'
      DebitMemoRequest.CustomerAccountAssignmentGroup,
      DebitMemoRequest.AssignmentReference,
      DebitMemoRequest.AccountingDocExternalReference,

      DebitMemoRequest.BillingDocumentDate,

      DebitMemoRequest.ServicesRenderedDate,

      DebitMemoRequest.ReferenceSDDocument,

      @ObjectModel.foreignKey.association: '_ReferenceSDDocumentCategory'
      DebitMemoRequest.ReferenceSDDocumentCategory,
      
      DebitMemoRequest.CreatedByUser,

      @Consumption.hidden: true
      DebitMemoRequest.CreationDate,

      @Consumption.hidden: true
      DebitMemoRequest.CreationTime,

      cast( dats_tims_to_tstmp( DebitMemoRequest.CreationDate, DebitMemoRequest.CreationTime, abap_system_timezone( $session.client, 'NULL' ),
        $session.client, 'NULL' ) as creation_date_time ) as SalesDocumentCreationDateTime,

      DebitMemoRequest.LastChangedByUser,
      
      @Consumption.hidden: true
      DebitMemoRequest.LastChangeDate,

      case tstmp_is_valid(cast(DebitMemoRequest.LastChangeDateTime as abap.dec(15,0)))
        when 0 then cast( dats_tims_to_tstmp( DebitMemoRequest.CreationDate, DebitMemoRequest.CreationTime, 'UTC', $session.client, 'NULL' ) as timestampl )
        else DebitMemoRequest.LastChangeDateTime
      end                                                 as LastChangeDateTime,

      @ObjectModel.foreignKey.association: '_DebitMemoReqApprovalReason'
      DebitMemoRequest.DebitMemoReqApprovalReason,

      @ObjectModel.foreignKey.association: '_SalesDocApprovalStatus'
      DebitMemoRequest.SalesDocApprovalStatus,

      @ObjectModel.foreignKey.association: '_OverallBillingBlockStatus'
      DebitMemoRequest.OverallBillingBlockStatus,

      @ObjectModel.foreignKey.association: '_OverallSDProcessStatus'
      DebitMemoRequest.OverallSDProcessStatus,

      @ObjectModel.foreignKey.association: '_OverallSDDocumentRejectionSts'
      DebitMemoRequest.OverallSDDocumentRejectionSts,

      @ObjectModel.foreignKey.association: '_OverallOrdReltdBillgStatus'
      DebitMemoRequest.OverallOrdReltdBillgStatus,

      @ObjectModel.foreignKey.association: '_TotalBlockStatus'
      DebitMemoRequest.TotalBlockStatus,

      @ObjectModel.foreignKey.association: '_HdrGeneralIncompletionStatus'
      DebitMemoRequest.HdrGeneralIncompletionStatus,

      @ObjectModel.foreignKey.association: '_OvrlItmGeneralIncompletionSts'
      DebitMemoRequest.OvrlItmGeneralIncompletionSts,

      @ObjectModel.foreignKey.association: '_OverallSDDocReferenceStatus'
      DebitMemoRequest.OverallSDDocReferenceStatus,
      
      @ObjectModel.foreignKey.association: '_TotalCreditCheckStatus'
      DebitMemoRequest.TotalCreditCheckStatus,
      
      OutputRequest.OutputRequestUUID,

      //Compositions

      _Item,
      _Partner,
      _PricingElement,
      _Text,
      
      //Re-use RAP associations

      _OutputRequest,

      //Exposed Associations

      DebitMemoRequest._DebitMemoRequestType,
      DebitMemoRequest._SalesOrganization,
      DebitMemoRequest._DistributionChannel,
      DebitMemoRequest._OrganizationDivision,
      DebitMemoRequest._SalesOffice,
      DebitMemoRequest._SalesGroup,
      DebitMemoRequest._SalesDistrict,
      DebitMemoRequest._CustomerPurchaseOrderType,
      DebitMemoRequest._CustPurOrdTypeByShipToParty, 
      DebitMemoRequest._CustomerGroup,
      DebitMemoRequest._SDDocumentReason,
      DebitMemoRequest._TransactionCurrency,
      DebitMemoRequest._IncotermsClassification,
      DebitMemoRequest._IncotermsVersion,
      DebitMemoRequest._CustomerPaymentTerms,
      DebitMemoRequest._BillingCompanyCode,
      DebitMemoRequest._HeaderBillingBlockReason,
      DebitMemoRequest._ReferenceSDDocumentCategory,
      DebitMemoRequest._DebitMemoReqApprovalReason,
      DebitMemoRequest._OverallSDProcessStatus,
      DebitMemoRequest._OverallBillingBlockStatus,
      DebitMemoRequest._TotalCreditCheckStatus,
      DebitMemoRequest._SalesDocApprovalStatus,
      DebitMemoRequest._OverallSDDocumentRejectionSts,
      DebitMemoRequest._OverallOrdReltdBillgStatus,
      DebitMemoRequest._TotalBlockStatus,
      DebitMemoRequest._OverallSDDocReferenceStatus,
      DebitMemoRequest._HdrGeneralIncompletionStatus,
      DebitMemoRequest._OvrlItmGeneralIncompletionSts,
      DebitMemoRequest._ControllingArea,
      DebitMemoRequest._LastChangedByUser,
      DebitMemoRequest._CreatedByUser,
      DebitMemoRequest._SDPricingProcedure,
      DebitMemoRequest._CustomerPriceGroup,
      DebitMemoRequest._PriceListType,
      DebitMemoRequest._CustomerAccountAssgmtGroup
}