R_DebitMemoRequestPartnerTP

DDL: R_DEBITMEMOREQUESTPARTNERTP Type: view_entity TRANSACTIONAL Package: RAP_SD_SLS_DMR

Debit Memo Request Partner - TP

R_DebitMemoRequestPartnerTP is a Transactional CDS View that provides data about "Debit Memo Request Partner - TP" in SAP S/4HANA. It reads from 1 data source (I_DebitMemoReqPartner) and exposes 56 fields with key fields DebitMemoRequest, PartnerFunction. It has 4 associations to related views. Part of development package RAP_SD_SLS_DMR.

1 data source(s) 56 fields

Data Sources (1)

SourceAliasJoin Type
I_DebitMemoReqPartner DebitMemoRequestPartner from

Associations (4)

CardinalityTargetAliasCondition
[0..1] I_PartnerFunction _PartnerFunction $projection.PartnerFunctionForEdit = _PartnerFunction.PartnerFunction
[0..1] I_Language _CorrespondenceLanguage $projection.CorrespondenceLanguage = _CorrespondenceLanguage.Language
[0..1] I_FormOfAddress _FormOfAddress $projection.FormOfAddress = _FormOfAddress.FormOfAddress
[0..1] I_TransportationZone _TransportationZone $projection.transportzone = _TransportationZone.TransportZone and $projection.country = _TransportationZone.CountryCode

Annotations (8)

NameValueLevelField
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #TRANSACTIONAL view
AccessControl.authorizationCheck #MANDATORY view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
Metadata.ignorePropagatedAnnotations true view
EndUserText.label Debit Memo Request Partner - TP view

Fields (56)

KeyFieldSource TableSource FieldDescription
KEY DebitMemoRequest DebitMemoRequest
KEY PartnerFunction
PartnerFunctionForEdit
Customer I_DebitMemoReqPartner Customer
Supplier I_DebitMemoReqPartner Supplier
Personnel I_DebitMemoReqPartner Personnel
ContactPerson I_DebitMemoReqPartner ContactPerson
ReferenceBusinessPartner I_DebitMemoReqPartner ReferenceBusinessPartner
Partner I_DebitMemoReqPartner Partner
FullName I_DebitMemoReqPartner FullName
SDDocumentPartnerType _PartnerFunction SDDocumentPartnerType
FormOfAddress I_DebitMemoReqPartner FormOfAddress
PostalCode
CityName
DistrictName
Country
Region
StreetName
StreetPrefixName1
StreetPrefixName2
StreetSuffixName1
StreetSuffixName2
HouseNumber
InternationalPhoneNumber I_DebitMemoReqPartner InternationalPhoneNumber
InternationalMobilePhoneNumber I_DebitMemoReqPartner InternationalMobilePhoneNumber
EmailAddress I_DebitMemoReqPartner EmailAddress
InternationalFaxNumber I_DebitMemoReqPartner InternationalFaxNumber
POBox
POBoxPostalCode
CorrespondenceLanguage I_DebitMemoReqPartner CorrespondenceLanguage
TaxJurisdiction
TransportZone
UnloadingPointName I_DebitMemoReqPartner UnloadingPointName
VATRegistration I_DebitMemoReqPartner VATRegistration
SDDocPartnerAddrIsDocSpecific I_DebitMemoReqPartner SDDocPartnerAddrIsDocSpecific
AddressID I_DebitMemoReqPartner AddressID
AddressPersonID I_DebitMemoReqPartner AddressPersonID
AddressObjectType I_DebitMemoReqPartner AddressObjectType
SDDocPartnerAddressRefType I_DebitMemoReqPartner SDDocPartnerAddressRefType
BPAddrDeterminationTransaction I_DebitMemoReqPartner BPAddrDeterminationTransaction
BPRefAddressIDForDocSpcfcAddr I_DebitMemoReqPartner BPRefAddressIDForDocSpcfcAddr
DebitMemoRequestType _DebitMemoRequest DebitMemoRequestType
SalesOrganization _DebitMemoRequest SalesOrganization
DistributionChannel _DebitMemoRequest DistributionChannel
OrganizationDivision _DebitMemoRequest OrganizationDivision
_DebitMemoRequest _DebitMemoRequest
_PartnerFunction _PartnerFunction
_CorrespondenceLanguage _CorrespondenceLanguage
_FormOfAddress _FormOfAddress
_TransportationZone _TransportationZone
_DfltAddrRprstn I_DebitMemoReqPartner _DfltAddrRprstn
_OrgNamePostalAddress I_DebitMemoReqPartner _OrgNamePostalAddress
_BusinessPartnerAddress I_DebitMemoReqPartner _BusinessPartnerAddress
_BPRefAddressForDocSpcfcAddr I_DebitMemoReqPartner _BPRefAddressForDocSpcfcAddr
_Country
_Region 
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_DfltAddrRprstn' ]
}

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}

@ObjectModel.semanticKey: ['DebitMemoRequest', 'PartnerFunction']

@Metadata.ignorePropagatedAnnotations: true

@Consumption.dbHints: [ 'USE_HEX_PLAN', 'NO_SUBPLAN_SHARING' ]

@EndUserText.label: 'Debit Memo Request Partner - TP'
define view entity R_DebitMemoRequestPartnerTP
  as select from I_DebitMemoReqPartner as DebitMemoRequestPartner

  association        to parent R_DebitMemoRequestTP as _DebitMemoRequest on $projection.DebitMemoRequest = _DebitMemoRequest.DebitMemoRequest

  association [0..1] to I_PartnerFunction            as _PartnerFunction        on $projection.PartnerFunctionForEdit = _PartnerFunction.PartnerFunction

  association [0..1] to I_Language                   as _CorrespondenceLanguage on $projection.CorrespondenceLanguage = _CorrespondenceLanguage.Language
   
  association [0..1] to I_FormOfAddress              as _FormOfAddress          on  $projection.FormOfAddress = _FormOfAddress.FormOfAddress

  association [0..1] to I_TransportationZone         as _TransportationZone     on  $projection.transportzone = _TransportationZone.TransportZone
                                                                                    and $projection.country       = _TransportationZone.CountryCode
 
 {
  key DebitMemoRequest,      

  key cast(DebitMemoRequestPartner.PartnerFunction as parvw_unv preserving type )        as PartnerFunction,
      
      @ObjectModel.editableFieldFor: 'PartnerFunction'
      @ObjectModel.foreignKey.association: '_PartnerFunction'
      cast(DebitMemoRequestPartner.PartnerFunction as parvw_unv preserving type )        as PartnerFunctionForEdit,

      @Consumption.hidden: true
      DebitMemoRequestPartner.Customer,

      @Consumption.hidden: true
      DebitMemoRequestPartner.Supplier,

      @Consumption.hidden: true
      DebitMemoRequestPartner.Personnel,

      @Consumption.hidden: true
      DebitMemoRequestPartner.ContactPerson,
      
      DebitMemoRequestPartner.ReferenceBusinessPartner,

      @ObjectModel.text.element: ['FullName']
      DebitMemoRequestPartner.Partner,
      
      @Semantics.name.fullName: true
      @Semantics.text: true
      DebitMemoRequestPartner.FullName,
      
      _PartnerFunction.SDDocumentPartnerType,

      @ObjectModel.foreignKey.association: '_FormOfAddress'
      @Semantics.name.jobTitle: true
      DebitMemoRequestPartner.FormOfAddress,

      @Semantics.address.zipCode:true
      DebitMemoRequestPartner._OrgNamePostalAddress.PostalCode,

      @Semantics.address.city:true
      DebitMemoRequestPartner._OrgNamePostalAddress.CityName,
      
      DebitMemoRequestPartner._OrgNamePostalAddress.DistrictName,

      @Semantics.address.country:true
      @ObjectModel.foreignKey.association: '_Country'
      DebitMemoRequestPartner._OrgNamePostalAddress.Country,

      @ObjectModel.foreignKey.association: '_Region'
      @Semantics.address.region: true
      DebitMemoRequestPartner._OrgNamePostalAddress.Region,

      @Semantics.address.street: true
      DebitMemoRequestPartner._OrgNamePostalAddress.StreetName,

      @Semantics.address.street: true
      DebitMemoRequestPartner._OrgNamePostalAddress.StreetPrefixName1,

      @Semantics.address.street: true
      DebitMemoRequestPartner._OrgNamePostalAddress.StreetPrefixName2,

      @Semantics.address.street: true
      DebitMemoRequestPartner._OrgNamePostalAddress.StreetSuffixName1,

      @Semantics.address.street: true
      DebitMemoRequestPartner._OrgNamePostalAddress.StreetSuffixName2,

      @Semantics.address.streetNoNumber: true
      DebitMemoRequestPartner._OrgNamePostalAddress.HouseNumber,
      
      @Semantics.telephone.type: [#WORK]
      DebitMemoRequestPartner.InternationalPhoneNumber,

      @Semantics.telephone.type:  [#CELL]
      DebitMemoRequestPartner.InternationalMobilePhoneNumber,

      @Semantics.eMail.address: true
      @Semantics.eMail.type:  [#WORK]
      DebitMemoRequestPartner.EmailAddress,

      @Semantics.telephone.type: [#FAX]
      DebitMemoRequestPartner.InternationalFaxNumber,

      @Semantics.address.postBox: true
      DebitMemoRequestPartner._OrgNamePostalAddress.POBox,

      @Semantics.address.zipCode:true
      DebitMemoRequestPartner._OrgNamePostalAddress.POBoxPostalCode,

      @ObjectModel.foreignKey.association: '_CorrespondenceLanguage'
      DebitMemoRequestPartner.CorrespondenceLanguage,

      DebitMemoRequestPartner._OrgNamePostalAddress.TaxJurisdiction,

      @ObjectModel.foreignKey.association: '_TransportationZone'
      DebitMemoRequestPartner._OrgNamePostalAddress.TransportZone,

      @Semantics.text: true
      DebitMemoRequestPartner.UnloadingPointName,

      DebitMemoRequestPartner.VATRegistration,
      
      DebitMemoRequestPartner.SDDocPartnerAddrIsDocSpecific,

      //    On Conditions For Associations

      @Consumption.hidden: true
      DebitMemoRequestPartner.AddressID,
      @Consumption.hidden: true
      DebitMemoRequestPartner.AddressPersonID,
      @Consumption.hidden: true
      DebitMemoRequestPartner.AddressObjectType,
      @Consumption.hidden: true
      DebitMemoRequestPartner.SDDocPartnerAddressRefType,
      @Consumption.hidden: true
      DebitMemoRequestPartner.BPAddrDeterminationTransaction,
      @Consumption.hidden: true
      DebitMemoRequestPartner.BPRefAddressIDForDocSpcfcAddr,

      //DCL

      @Consumption.hidden: true
      _DebitMemoRequest.DebitMemoRequestType,
      @Consumption.hidden: true
      _DebitMemoRequest.SalesOrganization,
      @Consumption.hidden: true
      _DebitMemoRequest.DistributionChannel,
      @Consumption.hidden: true
      _DebitMemoRequest.OrganizationDivision,

      //    Associations

      _DebitMemoRequest,
      _PartnerFunction,
      _CorrespondenceLanguage,
      _FormOfAddress,
      _TransportationZone,
      
      DebitMemoRequestPartner._DfltAddrRprstn,
      DebitMemoRequestPartner._OrgNamePostalAddress,
      DebitMemoRequestPartner._BusinessPartnerAddress,
      DebitMemoRequestPartner._BPRefAddressForDocSpcfcAddr,
      DebitMemoRequestPartner._OrgNamePostalAddress._Country,
      DebitMemoRequestPartner._OrgNamePostalAddress._Region 
}

Learn More