R_ContractAccountTP

@AccessControl: { authorizationCheck: #MANDATORY,
                  privilegedAssociations: [ '_ContractAccountChangeDocument', '_CreatedByContactCard', '_LastChangedByContactCard', '_NoteBasic' ] }

@EndUserText.label: 'Contract Account - TP'

@ObjectModel: { representativeKey:      'ContractAccount',
                sapObjectNodeType.name: 'ContractAccount',
                usageType:              { dataClass: #MASTER,
                                          serviceQuality: #C,
                                          sizeCategory: #XL } }

@VDM: { lifecycle.contract.type: #SAP_INTERNAL_API,
        viewType:                #TRANSACTIONAL }

@AbapCatalog.extensibility: {
  extensible: true,
  elementSuffix: 'VKK',
  dataSources: [ '_Extension' ],
  quota: {
    maximumFields: 170,
    maximumBytes: 3400
  },
  allowNewCompositions: true
}

define root view entity R_ContractAccountTP
  as select from I_ContractAccountHeader

  composition [0..*] of R_ContractAccountPartnerTP as _ContractAccountPartner
  composition [0..*] of R_ContrAcctTaxExemptionTP  as _ContractAccountTaxExemption

  association [0..*] to I_ChangeDocument_2         as _ContractAccountChangeDocument on  _ContractAccountChangeDocument.ChangeDocObjectClass = 'MKK_VKONT'
                                                                                     and $projection.ContractAccount                         = _ContractAccountChangeDocument.ChangeDocObject

  association [0..1] to I_UserContactCard          as _CreatedByContactCard          on  $projection.CreatedByUser = _CreatedByContactCard.ContactCardID
  association [0..1] to I_UserContactCard          as _LastChangedByContactCard      on  $projection.LastChangedByUser = _LastChangedByContactCard.ContactCardID
  association [0..*] to I_NoteBasicTP              as _NoteBasic                     on  $projection.ContractAccountCharUUID = _NoteBasic.NoteBasicObject
                                                                                     and _NoteBasic.NoteBasicObjectNodeType  = 'CONTRACTACCOUNT'
  association [1..1] to E_ContractAccountHeader    as _Extension                     on  $projection.ContractAccount = _Extension.ContractAccount

{
  key ContractAccount,

      @ObjectModel.editableFieldFor: 'ContractAccount'
      ContractAccount                                                                                                 as ContractAccountForEdit,

      CreationDate,
      CreationTime,

      @Semantics.user.createdBy: true
      CreatedByUser,
      IsMarkedForDeletion,
      LastChangeDate,
      LastChangeTime,
      LastChangedByUser,
      @ObjectModel.foreignKey.association: '_CAApplicationArea'
      CAApplicationArea,
      @ObjectModel.foreignKey.association: '_ContractAccountCategory'
      ContractAccountCategory,
      ContractAccountExtReference,
      ContractAccountName,
      ContractAccountUUID,
      bintohex( ContractAccountUUID )                                                                                 as ContractAccountCharUUID,

      cast('00000000' as valdt_acc_kk)                                                                                as PlannedChangeValidityDate,

      cast( dats_tims_to_tstmp( CreationDate, CreationTime, 'UTC', $session.client, 'NULL' ) as vdm_creationdatetime) as CreationDateTime,
      //etag

      @Semantics.systemDateTime.lastChangedAt: true
      case when ( LastChangeDate is initial or LastChangeDate is null )
        then cast( dats_tims_to_tstmp( LastChangeDate, LastChangeTime, 'UTC', $session.client, 'NULL') as vdm_lastchangedon )
        else cast( dats_tims_to_tstmp( CreationDate, CreationTime, 'UTC', $session.client, 'NULL') as vdm_lastchangedon )
      end                                                                                                             as LastChangeDateTime,

      /* Associations */
      _ContractAccountPartner,
      _ContractAccountTaxExemption,

      _ContractAccountChangeDocument,
      _CreatedByContactCard,
      _LastChangedByContactCard,
      _NoteBasic,
      _ApplArea                                                                                                       as _CAApplicationArea,
      _Category                                                                                                       as _ContractAccountCategory
}