R_ContrAcctTaxExemptionTP

DDL: R_CONTRACCTTAXEXEMPTIONTP Type: view_entity TRANSACTIONAL Package: RAP_FICA_CONTRACCT

Contract Account Tax Exemption - TP

R_ContrAcctTaxExemptionTP is a Transactional CDS View that provides data about "Contract Account Tax Exemption - TP" in SAP S/4HANA. It reads from 1 data source (I_ContractAccountTaxExemption) and exposes 21 fields with key fields ContractAccount, TaxCode, CAConditionType, CustTaxGroupExemptionStartDate. It has 1 association to related views. Part of development package RAP_FICA_CONTRACCT.

1 data source(s) 21 fields

Data Sources (1)

SourceAliasJoin Type
I_ContractAccountTaxExemption I_ContractAccountTaxExemption from

Associations (1)

CardinalityTargetAliasCondition
[1] I_ContrAcctTaxExemptionUI _ContrAcctTaxExemptionUI $projection.ContractAccount = _ContrAcctTaxExemptionUI.ContractAccount and $projection.TaxCode = _ContrAcctTaxExemptionUI.TaxCode and $projection.CAConditionType = _ContrAcctTaxExemptionUI.CAConditionType and $projection.CustTaxGroupExemptionStartDate = _ContrAcctTaxExemptionUI.CustTaxGroupExemptionStartDate

Annotations (9)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label Contract Account Tax Exemption - TP view
ObjectModel.modelingPattern #NONE view
ObjectModel.sapObjectNodeType.name ContractAccountTaxExemption view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #L view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #TRANSACTIONAL view

Fields (21)

KeyFieldSource TableSource FieldDescription
KEY ContractAccount ContractAccount
KEY TaxCode TaxCode
KEY CAConditionType CAConditionType
KEY CustTaxGroupExemptionStartDate CustTaxGroupExemptionStartDate
TaxCodeForEdit TaxCode
CAConditionTypeForEdit CAConditionType
CustTxGrpExmpStrtDtFoEd CustTaxGroupExemptionStartDate
CustTaxGroupExemptionEndDate CustTaxGroupExemptionEndDate
CATaxExemptionLicense CATaxExemptionLicense
CATaxExemptionRate CATaxExemptionRate
CAMassRunDate CAMassRunDate
CAMassRunID CAMassRunID
CATaxExemptionLicenseExtended CATaxExemptionLicenseExtended
CATaxExemptionLicenseAmount CATaxExemptionLicenseAmount
CATaxExemptionLicenseCurrency CATaxExemptionLicenseCurrency
CATaxExemptionLicenseIssueDate CATaxExemptionLicenseIssueDate
IT_TaxCalculationProcedure _ContrAcctTaxExemptionUI IT_TaxCalculationProcedure
_ContractAccount _ContractAccount
_ContrAcctTaxExemptionUI _ContrAcctTaxExemptionUI
_CAConditionType _CAConditionType
_CATaxExemptionLicenseCurrency _CATaxExemptionLicenseCurrency 
@AccessControl.authorizationCheck: #MANDATORY

@EndUserText.label: 'Contract Account Tax Exemption - TP'

@ObjectModel: { modelingPattern: #NONE,
                sapObjectNodeType.name: 'ContractAccountTaxExemption',
                usageType: { dataClass: #MASTER,
                             serviceQuality: #A,
                             sizeCategory: #L } }

@VDM: { lifecycle.contract.type: #SAP_INTERNAL_API,
        viewType: #TRANSACTIONAL }

define view entity R_ContrAcctTaxExemptionTP
  as select from I_ContractAccountTaxExemption

  association     to parent R_ContractAccountTP as _ContractAccount         on  _ContractAccount.ContractAccount = $projection.ContractAccount

  association [1] to I_ContrAcctTaxExemptionUI  as _ContrAcctTaxExemptionUI on  $projection.ContractAccount                = _ContrAcctTaxExemptionUI.ContractAccount
                                                                            and $projection.TaxCode                        = _ContrAcctTaxExemptionUI.TaxCode
                                                                            and $projection.CAConditionType                = _ContrAcctTaxExemptionUI.CAConditionType
                                                                            and $projection.CustTaxGroupExemptionStartDate = _ContrAcctTaxExemptionUI.CustTaxGroupExemptionStartDate

{
      @ObjectModel.foreignKey.association: '_ContractAccount'
  key ContractAccount,
  key TaxCode,
  key CAConditionType,
  key CustTaxGroupExemptionStartDate,

      @ObjectModel.editableFieldFor: 'TaxCode'
      TaxCode                        as TaxCodeForEdit,
      @ObjectModel.editableFieldFor: 'CAConditionType'
      CAConditionType                as CAConditionTypeForEdit,
      @ObjectModel.editableFieldFor: 'CustTaxGroupExemptionStartDate'
      CustTaxGroupExemptionStartDate as CustTxGrpExmpStrtDtFoEd,

      CustTaxGroupExemptionEndDate,
      CATaxExemptionLicense,
      CATaxExemptionRate,
      CAMassRunDate,
      CAMassRunID,
      CATaxExemptionLicenseExtended,
      @Semantics: { amount : {currencyCode: 'CATaxExemptionLicenseCurrency'} }
      CATaxExemptionLicenseAmount,
      CATaxExemptionLicenseCurrency,
      CATaxExemptionLicenseIssueDate,
      
      // used for tax code value help

      _ContrAcctTaxExemptionUI.IT_TaxCalculationProcedure,
      /* Associations */
      // own associations

      _ContractAccount,
      _ContrAcctTaxExemptionUI,
      // inherited associations

      _CAConditionType,
      _CATaxExemptionLicenseCurrency
}

Learn More