R_CndnContrConditionUsage

@AbapCatalog: {
  viewEnhancementCategory: [#NONE],
  dataMaintenance: #DISPLAY_ONLY  
}
@EndUserText.label: 'Condition Contract Condition Usage'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  representativeKey: 'DocRelationshipUUID',
  usageType: {
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory:   #XXL
  }
}
@Analytics.technicalName: 'RWLFCCCNDUSAGE'
@Metadata: {
  ignorePropagatedAnnotations: true
}

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view entity R_CndnContrConditionUsage
  as select from R_CndnDocConditionUsage
    inner join   R_ConditionContract on R_CndnDocConditionUsage.ConditionDocument = R_ConditionContract.ConditionContract

  association [1..1] to R_ConditionContract   as _ConditionContract   on $projection.ConditionContract = _ConditionContract.ConditionContract
  association [0..1] to I_CndnContrAccrSource as _CndnContrAccrSource on $projection.CndnContrAccrSource = _CndnContrAccrSource.CndnContrAccrSource

{
  key R_CndnDocConditionUsage.DocRelationshipUUID,
      R_CndnDocConditionUsage.PricingDocument,
      R_CndnDocConditionUsage.PricingProcedureStep,
      R_CndnDocConditionUsage.PricingProcedureCounter,

      @ObjectModel.foreignKey.association: '_ConditionContract'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_ConditionContractStdVH', element: 'ConditionContract' } }]
      }
      cast( R_CndnDocConditionUsage.ConditionDocument as wcb_coco_num preserving type ) as ConditionContract,
      cast( R_CndnDocConditionUsage.ConditionDocumentUUID as wcb_guid preserving type ) as CndnContrUUID,
      R_CndnDocConditionUsage.ConditionRecord,
      R_CndnDocConditionUsage.ConditionSequentialNumberShort,
      @ObjectModel.foreignKey.association: '_CndnContrAccrRvslSts'
      R_CndnDocConditionUsage.CndnDocAccrReversalStatus                                 as CndnContrAccrRvslSts,

      /* Accrual Source Document - Generic*/
      R_CndnDocConditionUsage.AccrSrceDocCategory,
      R_CndnDocConditionUsage.AccrSrceDocument,
      R_CndnDocConditionUsage.AccrSrceDocumentYear,
      R_CndnDocConditionUsage.AccrSrceDocumentItem,
      @ObjectModel.foreignKey.association: '_ConditionApplication'
      R_CndnDocConditionUsage.ConditionApplication,
      @ObjectModel.foreignKey.association: '_ConditionType'
      R_CndnDocConditionUsage.ConditionType,
      @Semantics.amount.currencyCode: 'AccrSrceDocCurrency'
      @DefaultAggregation: #SUM
      R_CndnDocConditionUsage.ConditionAmount,
      @ObjectModel.foreignKey.association: '_AccrSrceDocCurrency'
      R_CndnDocConditionUsage.AccrSrceDocCurrency,
      R_CndnDocConditionUsage.AccrSrceDocPostingDate,
      R_CndnDocConditionUsage.SettlmtDate,
      R_CndnDocConditionUsage.SettlmtDateSequentialID,
      R_CndnDocConditionUsage.RefSettlmtDate,
      R_CndnDocConditionUsage.RefSettlmtDateSequentialID,
      R_CndnDocConditionUsage.AccrSrceDocFiscalYear,
      @ObjectModel.foreignKey.association: '_AccrSrceDocItemPlant'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_PlantStdVH', element: 'Plant' } }]
      }
      R_CndnDocConditionUsage.AccrSrceDocItemPlant,
      @ObjectModel.foreignKey.association: '_AccrSrceDocCompanyCode'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } }]
      }
      R_CndnDocConditionUsage.AccrSrceDocCompanyCode,

      R_CndnDocConditionUsage.CndnDocAccrualSource                                      as CndnContrAccrSource,

      /* Material Document*/
      R_CndnDocConditionUsage.MaterialDocument,
      R_CndnDocConditionUsage.MaterialDocumentYear,
      R_CndnDocConditionUsage.MaterialDocumentItem,

      /* Settlement Management Document*/
      R_CndnDocConditionUsage.SettlmtMgmtDoc,
      R_CndnDocConditionUsage.SettlmtMgmtDocItem,

      /* Billing Document*/
      @ObjectModel.foreignKey.association: '_BillingDocument'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_BillingDocumentStdVH', element: 'BillingDocument' } }]
      }
      R_CndnDocConditionUsage.BillingDocument,
      @ObjectModel.foreignKey.association: '_BillingDocumentItem'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_BillingDocumentItemStdVH', element: 'BillingDocumentItem' } }]
      }
      R_CndnDocConditionUsage.BillingDocumentItem,

      /* Associations */
      R_CndnDocConditionUsage._BillingDocument,
      R_CndnDocConditionUsage._BillingDocumentItem,

      R_CndnDocConditionUsage._AccrSrceDocCompanyCode,
      R_CndnDocConditionUsage._AccrSrceDocCurrency,
      R_CndnDocConditionUsage._AccrSrceDocItemPlant,
      _CndnContrAccrSource,
      R_CndnDocConditionUsage._CndnDocAccrReversalStatus                                as _CndnContrAccrRvslSts,
      R_CndnDocConditionUsage._ConditionApplication,
      _ConditionContract,
      R_CndnDocConditionUsage._ConditionType,
      R_CndnDocConditionUsage._CndnContrAccrSrceDocCat
      
}