R_CONDITIONCONTRACT

@EndUserText.label: 'Condition Contract'
@AccessControl: {
    authorizationCheck:     #MANDATORY,
    personalData.blocking:  #('TRANSACTIONAL_DATA'),
    privilegedAssociations: [  '_LastChangedByUser', '_CreatedByUser'  ]
    }
@ObjectModel: {
    representativeKey:        'ConditionContract',
    compositionRoot:          true,
    usageType: {
      serviceQuality: #A,
      dataClass:      #TRANSACTIONAL,
      sizeCategory:   #XXL
      }
    }
@Analytics.technicalName: 'RCNDNCNTR'
@VDM: {
    viewType: #COMPOSITE,
    lifecycle.contract.type: #SAP_INTERNAL_API
    }
@Metadata: {
    ignorePropagatedAnnotations: true,
    allowExtensions: false
    }

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view entity R_ConditionContract
  as select from R_ConditionDocument

  association [0..*] to R_CndnContrBusVolSelCriteria as _CndnContrBusVolSelCriteria on $projection.ConditionContract = _CndnContrBusVolSelCriteria.ConditionContract
  association [0..*] to R_CndnContrSettlmtCal        as _CndnContrSettlmtCal        on $projection.ConditionContract = _CndnContrSettlmtCal.ConditionContract
  association [0..*] to R_CndnContrConditionUsage    as _CndnContrConditionUsage    on $projection.ConditionContract = _CndnContrConditionUsage.ConditionContract

  association [0..1] to I_CndnContrActvtnStatus      as _CndnContrActvtnStatus      on $projection.CndnContrActvtnStatus = _CndnContrActvtnStatus.CndnContrActvtnStatus
  association [0..1] to I_Currency                   as _CndnContrCurrency          on $projection.CndnContrCurrency = _CndnContrCurrency.Currency
  association [0..1] to I_CndnContrSuplrSettlmtCat   as _CndnContrSuplrSettlmtCat   on $projection.CndnContrSuplrSettlmtCat = _CndnContrSuplrSettlmtCat.CndnContrSuplrSettlmtCat
  association [0..1] to I_CndnContrCustSettlmtCat    as _CndnContrCustSettlmtCat    on $projection.CndnContrCustSettlmtCat = _CndnContrCustSettlmtCat.CndnContrCustSettlmtCat

  association [0..1] to I_UnitOfMeasure              as _CndnContrUnit              on $projection.CndnContrUnit = _CndnContrUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure              as _CndnContrWeightUnit        on $projection.CndnContrWeightUnit = _CndnContrWeightUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure              as _CndnContrVolumeUnit        on $projection.CndnContrVolumeUnit = _CndnContrVolumeUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure              as _CndnContrPointsQtyUnit     on $projection.CndnContrPointsQtyUnit = _CndnContrPointsQtyUnit.UnitOfMeasure

  association [0..1] to I_CndnContrPurposeCat        as _CndnContrPurposeCat        on $projection.CndnContrPurposeCat = _CndnContrPurposeCat.CndnContrPurposeCat
  association [0..1] to I_CndnContrSourceDocCat      as _CndnContrSourceDocCat      on $projection.CndnContrSourceDocCat = _CndnContrSourceDocCat.CndnContrSourceDocCat
  association [0..1] to I_CndnContrPrcgDetnRlvnceCat as _CndnContrPrcgDetnRlvnceCat on $projection.CndnContrPrcgDetnRlvnceCat = _CndnContrPrcgDetnRlvnceCat.CndnContrPrcgDetnRlvnceCat

  //Extension Association

  association [1..1] to E_ConditionContract          as _Extension                  on $projection.ConditionContract = _Extension.ConditionContract
{

  key cast( ConditionDocument as wcb_coco_num  preserving type )               as ConditionContract,
      @ObjectModel.foreignKey.association: '_CndnContrType'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_CndnContrTypeStdVH', element: 'CndnContrType' } }]
      }
      CndnContrType,
      @ObjectModel.foreignKey.association: '_CndnContrClassfctnType'
      CndnContrClassfctnType,
      @ObjectModel.foreignKey.association: '_CndnContrProcVar'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_CndnContrProcVarStdVH', element: 'CndnContrProcVar' } }]
      }
      CndnContrProcVar,
      DocumentReferenceID,
      CndnDocAssignmentReference                                               as CndnContrAssgmtRef,
      ExternalDocumentReferenceID,
      CndnDocExternalPartner                                                   as CndnContrExternalPartner,
      @ObjectModel.foreignKey.association: '_CndnContrActvtnStatus'
      CndnDocActivationStatus                                                  as CndnContrActvtnStatus,

      /* Validity */
      ConditionDocumentValidFromDate                                           as CndnContrValidFrom,
      ConditionDocumentValidToDate                                             as CndnContrValidTo,

      /* Partners */
      @ObjectModel.foreignKey.association: '_Supplier'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier' } }]
      }
      Supplier,
      @ObjectModel.foreignKey.association: '_Customer'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_Customer_VH', element: 'Customer' } }]
      }
      Customer,
      @ObjectModel.foreignKey.association: '_PriorSupplier'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier' } }]
      }
      PriorSupplier,
      @Consumption:{
        valueHelpDefinition: [{ entity: { name:'I_PersWrkAgrmtSrchHelp_1' , element: 'PersonWorkAgreement' } }]
      }
      PersonWorkAgreement,

      /* Organizational Data */
      @ObjectModel.foreignKey.association: '_CompanyCode'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } }]
      }
      CompanyCode,
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      PurchasingOrganization,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      PurchasingGroup,
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,
      @ObjectModel.foreignKey.association: '_Division'
      Division,
      @ObjectModel.foreignKey.association: '_SalesGroup'
      SalesGroup,
      @ObjectModel.foreignKey.association: '_SalesOffice'
      SalesOffice,

      /* Administrative Data */
      @Semantics.user.createdBy: true
      CreatedByUser,
      CreationDate,
      CreationTime,
      CreationTimeZone,
      CreationUTCDateTime,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      LastChangedDate,
      LastChangeTime,
      LastChangeUTCDateTime,

      /* Currency and Exchange Rate */
      @ObjectModel.foreignKey.association: '_CndnContrCurrency'
      cast( ConditionDocumentCurrency as wcb_cc_curr  preserving type )        as CndnContrCurrency,
      ExchangeRate,
      @ObjectModel.foreignKey.association: '_ExchangeRateType'
      ExchangeRateType,
      ExchangeRateDate,

      /* Payment terms and method */
      PaymentTerms,
      CashDiscount1Days,
      CashDiscount1Percent,
      CashDiscount2Days,
      CashDiscount2Percent,
      NetPaymentDays,
      //@ObjectModel.foreignKey.association: '_PaymentMethod'

      PaymentMethod,

      @ObjectModel.foreignKey.association: '_CndnContrSuplrSettlmtCat'
      CndnDocSuplrSettlmtCat                                                   as CndnContrSuplrSettlmtCat,
      @ObjectModel.foreignKey.association: '_CndnContrCustSettlmtCat'
      CndnDocCustSettlmtCat                                                    as CndnContrCustSettlmtCat,
      @ObjectModel.foreignKey.association: '_SettlmtProduct'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_ProductVH_2', element: 'Product' } }]
      }
      SettlmtProduct,

      /* Calendars */
      @ObjectModel.foreignKey.association: '_FinalSettlmtCalendar'
      FinalSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_PartialSettlmtCalendar'
      PartialSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_DeltaSettlmtCalendar'
      DeltaSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_DeltaAccrualSettlmtCalendar'
      DeltaAccrualSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_AccrualClearingSettlmtCal'
      AccrualClearingSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_CndnContrExtensionCalendar'
      CndnContrExtensionCalendar,

      PrecedingConditionDocument,

      @ObjectModel.foreignKey.association: '_CndnContrPurposeCat'
      CndnDocPurposeCategory                                                   as CndnContrPurposeCat,

      /* Source Document */
      @ObjectModel.foreignKey.association: '_CndnContrSourceDocCat'
      CndnDocSourceDocumentCategory                                            as CndnContrSourceDocCat,
      CndnDocSourceDocument                                                    as CndnContrSourceDoc,
      CndnDocSourceDocumentItem                                                as CndnContrSourceDocItem,

      @ObjectModel.foreignKey.association: '_BusVolTableGroup'
      BusVolTableGroup,
      @ObjectModel.foreignKey.association: '_AmountFieldGroup'
      AmountFieldGroup,

      /* Units */
      @ObjectModel.foreignKey.association: '_CndnContrUnit'
      ConditionDocumentUnit                                                    as CndnContrUnit,
      @ObjectModel.foreignKey.association: '_CndnContrWeightUnit'
      ConditionDocumentWeightUnit                                              as CndnContrWeightUnit,
      @ObjectModel.foreignKey.association: '_CndnContrVolumeUnit'
      ConditionDocumentVolumeUnit                                              as CndnContrVolumeUnit,
      @ObjectModel.foreignKey.association: '_CndnContrPointsQtyUnit'
      CndnDocPointsQuantityUnit                                                as CndnContrPointsQtyUnit,

      AccrualUpdateIsRequired,

      /* UUIDs */
      cast( ConditionDocumentUUID as wcb_guid preserving type )                as CndnContrUUID,
      cast( ConditionDocumentSourceUUID as wcb_ext_guid_cc   preserving type ) as CndnContrSourceUUID,

      /* Tax */
      @ObjectModel.foreignKey.association: '_TaxCountry'
      TaxCountry,
      @ObjectModel.foreignKey.association: '_SettlmtPartTxRegnCntry'
      SettlmtPartTxRegnCntry,

      /* VAT Registration */
      SettlmtPartTxRegnNmbr,

      @ObjectModel.foreignKey.association: '_CndnContrPrcgDetnRlvnceCat'
      CndnDocPrcgDetnRlvnceCat                                                 as CndnContrPrcgDetnRlvnceCat,
      @ObjectModel.foreignKey.association: '_BusVolTotAmtSpltCritraGrp'
      BusVolTotAmtSpltCritraGrp,
      CndnDocSettlementVariant                                                 as CndnContrSettlementVariant,

      BasicConditionContract,

      @ObjectModel.foreignKey.association: '_CndnContrPartnerCat'
      CndnContrPartnerCat,
      @ObjectModel.foreignKey.association: '_CndnContrProcessCategory'
      CndnContrProcessCategory,
      @ObjectModel.foreignKey.association: '_CndnContrSettlmtType'
      CndnContrSettlmtType,
      @ObjectModel.foreignKey.association: '_CndnContrSettlmtCalcMethod'
      CndnContrSettlmtCalcMethod,

      /* Worker related fields */
      CndnDocWorkerCostCenter                                                  as CndnContrWorkerCostCenter,
      CndnDocWrkrControllingArea                                               as CndnContrWrkrControllingArea,
      CndnDocWorkerSettlmtCat                                                  as CndnContrWorkerSettlmtCat,

      DataController,

      /* Object semantics */
      CndnDocSemanticCode                                                      as CndnContrSemanticCode,

      /* Associations */
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _CndnContrBusVolSelCriteria,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _CndnContrSettlmtCal,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _CndnContrConditionUsage,
      _CndnContrType,
      _CndnContrClassfctnType,
      _CndnContrProcVar,
      _CndnContrActvtnStatus,
      _Supplier,
      _Customer,
      _PriorSupplier,
      _PersonWorkAgreement,
      _CompanyCode,
      _PurchasingOrganization,
      _PurchasingGroup,
      _SalesOrganization,
      _DistributionChannel,
      _Division,
      _SalesGroup,
      _SalesOffice,
      _CreatedByUser,
      _LastChangedByUser,
      _CndnContrCurrency,
      _ExchangeRateType,
      //  _PaymentMethod,

      _CndnContrSuplrSettlmtCat,
      _CndnContrCustSettlmtCat,
      _SettlmtProduct,
      _FinalSettlmtCalendar,
      _PartialSettlmtCalendar,
      _DeltaSettlmtCalendar,
      _DeltaAccrualSettlmtCalendar,
      _AccrualClearingSettlmtCal,
      _CndnContrExtensionCalendar,
      _PrecedingConditionDocument,
      _CndnContrPurposeCat,
      _CndnContrSourceDocCat,
      _BusVolTableGroup,
      _AmountFieldGroup,
      _CndnContrUnit,
      _CndnContrWeightUnit,
      _CndnContrVolumeUnit,
      _CndnContrPointsQtyUnit,
      _TaxCountry,
      _SettlmtPartTxRegnCntry,
      _CndnContrPrcgDetnRlvnceCat,
      _BusVolTotAmtSpltCritraGrp,
      _CndnDocSettlementVariant                                                as _CndnContrSettlementVariant,
      _CndnContrPartnerCat,
      _CndnContrProcessCategory,
      _CndnContrSettlmtType,
      _CndnContrSettlmtCalcMethod,
      _CndnDocWorkerCostCenter                                                 as _CndnContrWorkerCostCenter,
      _CndnDocWrkrControllingArea                                              as _CndnContrWrkrControllingArea,
      _CndnDocWorkerSettlmtCat                                                 as _CndnContrWorkerSettlmtCat,
      _CndnDocSemanticCode                                                     as _CndnContrSemanticCode
}
where
  (
         CndnContrProcessCategory <> '6'
    and(
         CndnDocObjNodeTypeAbbr   =  ''
      or CndnDocObjNodeTypeAbbr   =  'CC'
    )
  )