R_ChgRecdRefOpSetTskListTP

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Chg Recd Obj Op Set Task List'
@ObjectModel.usageType:{
     serviceQuality: #C,
     sizeCategory: #L,
     dataClass: #MIXED
}
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@VDM.viewType:#TRANSACTIONAL
define root view entity R_ChgRecdRefOpSetTskListTP
  as select from           I_ChgRecdRefOpSetTskListBsc as RefOpSetTaskListReference
    left outer to one join I_BillOfOperations          as RefOpSetTaskList on  RefOpSetTaskListReference.ChgRecRefInternalKey1 = RefOpSetTaskList.BillOfOperationsType
                                                                           and RefOpSetTaskListReference.ChgRecRefInternalKey2 = RefOpSetTaskList.BillOfOperationsGroup
                                                                           and RefOpSetTaskListReference.ChgRecRefInternalKey3 = RefOpSetTaskList.BillOfOperationsVariant

  association [1..1] to I_ChangeRecordDraftTP       as _ChangeRecordTP            on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefOpSetTskListBsc as _RefOpSetTaskListExtension on $projection.ChangeRecordReferenceUUID = _RefOpSetTaskListExtension.ChangeRecordReferenceUUID
  association [0..1] to I_ChangeRecordRefObjIcons   as _ChangeRecordRefObjIcons on  $projection.ChangeRecordUUID          = _ChangeRecordRefObjIcons.ChangeRecordUUID
                                                                                and $projection.ChangeRecordReferenceType = _ChangeRecordRefObjIcons.ChangeRecordReferenceType
  association [1..1] to R_ChangeRecordHeader     as _ChangeRecord        on  $projection.ChangeRecordUUID = _ChangeRecord.ChangeRecordUUID
{
  key   RefOpSetTaskListReference.ChangeRecordReferenceUUID,
        case
           when RefOpSetTaskList.BillOfOperationsType is null then cast(substring( RefOpSetTaskListReference.ChangeRecordReference, 1, 1) as plnty)
           else cast(RefOpSetTaskList.BillOfOperationsType as plnty)
           end                          as BillOfOperationsType,


        case
        when RefOpSetTaskList.BillOfOperationsGroup is null then  cast(substring( RefOpSetTaskListReference.ChangeRecordReference, 2, 9) as plnnr)
        else cast(RefOpSetTaskList.BillOfOperationsGroup as plnnr)
        end                             as BillOfOperationsGroup,


        case
         when RefOpSetTaskList.BillOfOperationsVariant is null then cast (substring( RefOpSetTaskListReference.ChangeRecordReference, 10, 2) as plnal)
         else cast(RefOpSetTaskList.BillOfOperationsVariant as plnal)
         end                            as BillOfOperationsVariant,

        //  deprecated,should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter,
        // deprecated,  should not be used

        cast ('00000000' as plantext )  as BillOfOperationsDesc,

        RefOpSetTaskListReference.ChangeRecordUUID,
        RefOpSetTaskListReference.ChangeRecordReferenceType,
        RefOpSetTaskListReference.ChangeRecordReferenceSubtype,
        RefOpSetTaskListReference.ChangeRecordRefObjectUUID,
        RefOpSetTaskListReference.ChangeRecordReference,
        RefOpSetTaskListReference.ParentChangeRecordRefUUID,
        RefOpSetTaskListReference.IsMainReference,
        RefOpSetTaskListReference.ChgRecdReasonForChange,
        RefOpSetTaskListReference.ExpdCompltnDte,
        RefOpSetTaskListReference.ChgRecdAuthznGrpText,
        RefOpSetTaskListReference.ChgRecdNmbrChgSts,
        
        @UI.hidden: true
        @Semantics.imageUrl: true
        _ChangeRecordRefObjIcons[ChangeRecordType = ChangeRecordType].ChangeRecordRefObjIcon as ChangeRecordRefObjIcon,
        
        @Semantics.user.createdBy: true
        //@ObjectModel.readOnly: true

        RefOpSetTaskListReference.CreatedByUser,
        RefOpSetTaskListReference.CreationDateTime,
        @Semantics.user.lastChangedBy: true
        //@ObjectModel.readOnly: true

        RefOpSetTaskListReference.LastChangedByUser,
        RefOpSetTaskListReference.LastChangeDateTime,

        RefOpSetTaskListReference.ChangeRecordItemRelevance,
        RefOpSetTaskListReference.ChangeRecordVirtualRefInd,

        RefOpSetTaskListReference.ChangeRecordItemProcgStatus,
        //@ObjectModel.readOnly: true

        RefOpSetTaskListReference.ChgRecdCurrentItemProcgStatus,
        RefOpSetTaskListReference.ChangeNumber,
        //@ObjectModel.readOnly: true

        RefOpSetTaskListReference.ChgRecdItmTgtSts,
        //@ObjectModel.readOnly: true

        RefOpSetTaskListReference.ChgRecdItmDSgntr,
        _ChangeRecordRefObjIcons,
        //@ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]

        _ChangeRecordTP,
        _ChangeRecord
}
where
     RefOpSetTaskList.BillOfOperationsType = 'S'
  or RefOpSetTaskList.BillOfOperationsType is null