R_ChgRecdRefMaintTskListTP

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Chg Recd Obj Maintenance Task List'
@ObjectModel.usageType:{
     serviceQuality: #C,
     sizeCategory: #L,
     dataClass: #MIXED
}
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@VDM.viewType:#TRANSACTIONAL

define root view entity R_ChgRecdRefMaintTskListTP
  as select from           I_ChgRecdRefMaintTskListBsc as MaintenanceTaskListReference
    left outer to one join I_BillOfOperations          as MaintenanceTaskList on  MaintenanceTaskListReference.ChgRecRefInternalKey1 = MaintenanceTaskList.BillOfOperationsType
                                                                              and MaintenanceTaskListReference.ChgRecRefInternalKey2 = MaintenanceTaskList.BillOfOperationsGroup
                                                                              and MaintenanceTaskListReference.ChgRecRefInternalKey3 = MaintenanceTaskList.BillOfOperationsVariant

  association [1..1] to I_ChangeRecordDraftTP       as _ChangeRecordTP               on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefMaintTskListBsc as _MaintenanceTaskListExtension on $projection.ChangeRecordReferenceUUID = _MaintenanceTaskListExtension.ChangeRecordReferenceUUID
  association [0..1] to I_ChangeRecordRefObjIcons   as _ChangeRecordRefObjIcons on  $projection.ChangeRecordUUID          = _ChangeRecordRefObjIcons.ChangeRecordUUID
                                                                                and $projection.ChangeRecordReferenceType = _ChangeRecordRefObjIcons.ChangeRecordReferenceType
  association [1..1] to R_ChangeRecordHeader     as _ChangeRecord        on  $projection.ChangeRecordUUID = _ChangeRecord.ChangeRecordUUID
{
  key   MaintenanceTaskListReference.ChangeRecordReferenceUUID,
        case
           when MaintenanceTaskList.BillOfOperationsType is null then cast(substring( MaintenanceTaskListReference.ChangeRecordReference, 1, 1) as plnty)
           else cast(MaintenanceTaskList.BillOfOperationsType as plnty)
           end                          as BillOfOperationsType,

        case
        when MaintenanceTaskList.BillOfOperationsGroup is null then  cast(substring( MaintenanceTaskListReference.ChangeRecordReference, 2, 9) as plnnr)
        else cast(MaintenanceTaskList.BillOfOperationsGroup as plnnr)
        end                             as BillOfOperationsGroup,

        case
         when MaintenanceTaskList.BillOfOperationsVariant is null then cast (substring( MaintenanceTaskListReference.ChangeRecordReference, 10, 2) as plnal)
         else cast(MaintenanceTaskList.BillOfOperationsVariant as plnal)
         end                            as BillOfOperationsVariant,

        //  deprecated,should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter,
        // deprecated,  should not be used

        cast ('00000000' as plantext )  as BillOfOperationsDesc,

        MaintenanceTaskListReference.ChangeRecordUUID,
        MaintenanceTaskListReference.ChangeRecordReferenceType,
        MaintenanceTaskListReference.ChangeRecordReferenceSubtype,
        MaintenanceTaskListReference.ChangeRecordRefObjectUUID,
        MaintenanceTaskListReference.ChangeRecordReference,
        MaintenanceTaskListReference.ParentChangeRecordRefUUID,
        MaintenanceTaskListReference.IsMainReference,
        MaintenanceTaskListReference.ChgRecdReasonForChange,
        MaintenanceTaskListReference.ExpdCompltnDte,
        MaintenanceTaskListReference.ChgRecdAuthznGrpText,
        MaintenanceTaskListReference.ChgRecdNmbrChgSts,
        
        @UI.hidden: true
        @Semantics.imageUrl: true
        _ChangeRecordRefObjIcons[ChangeRecordType = ChangeRecordType].ChangeRecordRefObjIcon as ChangeRecordRefObjIcon,

        @Semantics.user.createdBy: true
        //@ObjectModel.readOnly: true

        MaintenanceTaskListReference.CreatedByUser,
        MaintenanceTaskListReference.CreationDateTime,
        @Semantics.user.lastChangedBy: true
        //@ObjectModel.readOnly: true

        MaintenanceTaskListReference.LastChangedByUser,
        MaintenanceTaskListReference.LastChangeDateTime,

        MaintenanceTaskListReference.ChangeRecordItemRelevance,
        MaintenanceTaskListReference.ChangeRecordVirtualRefInd,

        MaintenanceTaskListReference.ChangeRecordItemProcgStatus,
        //@ObjectModel.readOnly: true

        MaintenanceTaskListReference.ChgRecdCurrentItemProcgStatus,
        MaintenanceTaskListReference.ChangeNumber,
        //@ObjectModel.readOnly: true

        MaintenanceTaskListReference.ChgRecdItmTgtSts,
        //@ObjectModel.readOnly: true

        MaintenanceTaskListReference.ChgRecdItmDSgntr,
        _ChangeRecordRefObjIcons,
        //@ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]

        _ChangeRecordTP,
        _ChangeRecord
}
where
     MaintenanceTaskList.BillOfOperationsType = 'A'
  or MaintenanceTaskList.BillOfOperationsType is null