R_ChgRecdFuncLocTskListTP

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Chg Recd Obj FuncLoc Task List'
@ObjectModel.usageType:{
     serviceQuality: #C,
     sizeCategory: #L,
     dataClass: #MIXED
}
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@VDM.viewType:#TRANSACTIONAL
define root view entity R_ChgRecdFuncLocTskListTP
  as select from           I_ChgRecdFuncLocTskListBsc as FuncLocTaskListReference
    left outer to one join I_BillOfOperations         as FuncLocTaskList on  FuncLocTaskListReference.ChgRecRefInternalKey1 = FuncLocTaskList.BillOfOperationsType
                                                                         and FuncLocTaskListReference.ChgRecRefInternalKey2 = FuncLocTaskList.BillOfOperationsGroup
                                                                         and FuncLocTaskListReference.ChgRecRefInternalKey3 = FuncLocTaskList.BillOfOperationsVariant

  association [1..1] to I_ChangeRecordDraftTP      as _ChangeRecordTP           on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdFuncLocTskListBsc as _FuncLocTaskListExtension on $projection.ChangeRecordReferenceUUID = _FuncLocTaskListExtension.ChangeRecordReferenceUUID
  association [0..1] to I_ChangeRecordRefObjIcons   as _ChangeRecordRefObjIcons on  $projection.ChangeRecordUUID          = _ChangeRecordRefObjIcons.ChangeRecordUUID
                                                                                and $projection.ChangeRecordReferenceType = _ChangeRecordRefObjIcons.ChangeRecordReferenceType
  association [1..1] to R_ChangeRecordTP     as _ChangeRecord        on  $projection.ChangeRecordUUID = _ChangeRecord.ChangeRecordUUID
{
  key   FuncLocTaskListReference.ChangeRecordReferenceUUID,
        case
           when FuncLocTaskList.BillOfOperationsType is null then cast(substring( FuncLocTaskListReference.ChangeRecordReference, 1, 1) as plnty)
           else cast(FuncLocTaskList.BillOfOperationsType as plnty)
           end                          as BillOfOperationsType,


        case
        when FuncLocTaskList.BillOfOperationsGroup is null then  cast(substring( FuncLocTaskListReference.ChangeRecordReference, 2, 9) as plnnr)
        else cast(FuncLocTaskList.BillOfOperationsGroup as plnnr)
        end                             as BillOfOperationsGroup,


        case
         when FuncLocTaskList.BillOfOperationsVariant is null then cast (substring( FuncLocTaskListReference.ChangeRecordReference, 10, 2) as plnal)
         else cast(FuncLocTaskList.BillOfOperationsVariant as plnal)
         end                            as BillOfOperationsVariant,

        //  deprecated,should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter,
        // deprecated,  should not be used

        cast ('00000000' as plantext )  as BillOfOperationsDesc,

        FuncLocTaskListReference.ChangeRecordUUID,
        FuncLocTaskListReference.ChangeRecordReferenceType,
        FuncLocTaskListReference.ChangeRecordReferenceSubtype,
        FuncLocTaskListReference.ChangeRecordRefObjectUUID,
        FuncLocTaskListReference.ChangeRecordReference,
        FuncLocTaskListReference.ParentChangeRecordRefUUID,
        FuncLocTaskListReference.IsMainReference,
        FuncLocTaskListReference.ChgRecdReasonForChange,
        FuncLocTaskListReference.ExpdCompltnDte,
        FuncLocTaskListReference.ChgRecdAuthznGrpText,
        FuncLocTaskListReference.ChgRecdNmbrChgSts,   
        
        @UI.hidden: true
        @Semantics.imageUrl: true
        _ChangeRecordRefObjIcons[ChangeRecordType = ChangeRecordType].ChangeRecordRefObjIcon as ChangeRecordRefObjIcon,
             
        @Semantics.user.createdBy: true
        //@ObjectModel.readOnly: true

        FuncLocTaskListReference.CreatedByUser,
        FuncLocTaskListReference.CreationDateTime,
        @Semantics.user.lastChangedBy: true
        //@ObjectModel.readOnly: true

        FuncLocTaskListReference.LastChangedByUser,
        FuncLocTaskListReference.LastChangeDateTime,

        FuncLocTaskListReference.ChangeRecordItemRelevance,
        FuncLocTaskListReference.ChangeRecordVirtualRefInd,

        FuncLocTaskListReference.ChangeRecordItemProcgStatus,
        //@ObjectModel.readOnly: true

        FuncLocTaskListReference.ChgRecdCurrentItemProcgStatus,
        FuncLocTaskListReference.ChangeNumber,
        //@ObjectModel.readOnly: true

        FuncLocTaskListReference.ChgRecdItmTgtSts,
        //@ObjectModel.readOnly: true

        FuncLocTaskListReference.ChgRecdItmDSgntr,
        _ChangeRecordRefObjIcons,
        //@ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]

        _ChangeRecordTP,
        _ChangeRecord
        
}
where
     FuncLocTaskList.BillOfOperationsType = 'T'
  or FuncLocTaskList.BillOfOperationsType is null