R_AccControlIsUserAuthorized

@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@ObjectModel: {
    representativeKey: 'AccCtrlReferencedObjectUUID',

    usageType: {
      dataClass:       #TRANSACTIONAL,
      serviceQuality:  #A,
      sizeCategory:    #L
    }
}

@AccessControl: {
    authorizationCheck:      #NOT_REQUIRED, // not permitted on this view, this is access control

    auditing: {
        type: #CUSTOM,
        specification: 'change documents on Enterprise Projects'
    },
    personalData.blocking:   #BLOCKED_DATA_EXCLUDED
}
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]

@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'ACL Check for user'
define view entity R_AccControlIsUserAuthorized
  as select from /s4ppm/obj_auth        as Auth
    inner to many join /s4ppm/usr_grp   as User             on Auth.accesscontrolgroupuuid      = User.accesscontrolheaderuuid
    inner to many join /s4ppm/obj_ref   as Object           on Auth.accctrlreferencedobjectuuid = Object.accesscontrolheaderuuid
  /* FK */
  association [1] to I_AccessControlRestriction   as _Restriction on $projection.AccessControlRestrictionCode = _Restriction.AccessControlRestrictionCode
  association [1] to I_User                       as _User        on $projection.UserID = _User.UserID
  association [1] to R_AccCtrlObjectAuthorization as _Auth        on $projection.AccCtrlObjAuthorizationUUID = _Auth.AccCtrlObjAuthorizationUUID
{
      @ObjectModel.foreignKey.association: '_Auth'
  key Auth.accctrlobjauthorizationuuid      as AccCtrlObjAuthorizationUUID,
      @ObjectModel.foreignKey.association: '_User'
  key User.userid                           as UserID,     
  key Object.accctrlreferencedobjectuuid    as AccCtrlReferencedObjectUUID,      // we do not know what this points to, this field is the framework specific object guid 

      @ObjectModel.foreignKey.association: '_Restriction'
  key Auth.accesscontrolrestrictioncode     as AccessControlRestrictionCode,

      Object.acccntrlreferencedobjectid     as AccCntrlReferencedObjectID,       // we do not know what this points to, this field is framework specific object id when present


  _Restriction,
  _User,
  _Auth
  
}