R_AccCtrlObjectAuthorization

@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel: {
    representativeKey: 'AccCtrlObjAuthorizationUUID',

    usageType: {
      dataClass:       #TRANSACTIONAL,
      serviceQuality:  #A,
      sizeCategory:    #L
    }
}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Access Control Object Authorization'
define view entity R_AccCtrlObjectAuthorization
  as select from /s4ppm/obj_auth as OAT
  /* my Parent */
  association [1] to R_AccessControlList as _Root            on $projection.AccessControlHeaderUUID = _Root.AccessControlHeaderUUID
  /* root of a user group */
  association [1] to R_AccessControlList as _UserGroup       on $projection.AccessControlGroupUUID = _UserGroup.AccessControlHeaderUUID
  /* root of a user group */
  association [1] to R_AccessControlList as _ObjectReference on $projection.AccCtrlReferencedObjectUUID = _ObjectReference.AccessControlHeaderUUID
  
  /* FK */
  association [1] to I_AccessControlRestriction as _Restriction on $projection.AccessControlRestrictionCode = _Restriction.AccessControlRestrictionCode

{
  key accctrlobjauthorizationuuid  as AccCtrlObjAuthorizationUUID,
      @ObjectModel.foreignKey.association: '_Root'
      accesscontrolheaderuuid      as AccessControlHeaderUUID,

      /* this reference is framework (use case) specifc */
      // root object this ACL belongs to, not used in evaluation, in PPM it is the top node

      accctrlreferencedobjectuuid  as AccCtrlReferencedObjectUUID,
      
      @ObjectModel.foreignKey.association: '_Restriction'
      accesscontrolrestrictioncode as AccessControlRestrictionCode,

      accesscontrolgroupuuid       as AccessControlGroupUUID,

      //accesscontrolobjectuuid        as AccessControlObjectUUID,

      @Semantics.systemDateTime.createdAt: true
      creationdatetime            as CreationDateTime,
      @Semantics.user.createdBy: true
      createdby                   as CreatedByUser,
      @Semantics.systemDateTime.localInstanceLastChangedAt: true
      lastchangedon               as LastChangeDateTime,
      @Semantics.user.localInstanceLastChangedBy: true
      lastchangedby               as LastChangedByUser,

      _Root,
      _UserGroup,
      _ObjectReference,
      _Restriction
}