P_EventBasedOverheadOrderVH

@AbapCatalog.sqlViewName: 'PEBOVHDOVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Order details'
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE

define view P_EventBasedOverheadOrderVH
  as select from I_ProductCostCtrlgOrder as _ProductCostCtrlgOrder
  association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
{
  key OrderID          as OrderID,
      OrderDescription as OrderDescription,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      CompanyCode      as CompanyCode,
      @ObjectModel.foreignKey.association: '_OrderCategory'
      OrderCategory    as OrderCategory,
      @ObjectModel.foreignKey.association: '_OrderType'
      OrderType        as OrderType,
      Plant,
      _CompanyCode,
      _OrderCategory,
      _OrderType
}
where OrderIsEventBasedPosting = 'X'

union select from I_MaintenanceOrder as _MaintenanceOrder
{

  key MaintenanceOrder          as OrderID,
      MaintenanceOrderDesc      as OrderDescription,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      CompanyCode               as CompanyCode,
      @ObjectModel.foreignKey.association: '_MaintenanceOrderCategory'
      MaintenanceOrderCategory  as OrderCategory,
      @ObjectModel.foreignKey.association: '_MaintenanceOrderType'
      MaintenanceOrderType      as OrderType,
      MaintenancePlant          as Plant,
      _CompanyCode,
      _MaintenanceOrderCategory as _OrderCategory,
      _MaintenanceOrderType     as _OrderType
}
union select from I_InternalOrder as _InternalOrder
association [1..1] to I_OrderCategory as _OrderCategory on $projection.OrderCategory = _OrderCategory.OrderCategory
association [1..1] to I_OrderType     as _OrderType     on $projection.OrderType = _OrderType.OrderType
{
  key InternalOrder            as OrderID,
      InternalOrderDescription as OrderDescription,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      CompanyCode              as CompanyCode,
      @ObjectModel.foreignKey.association: '_OrderCategory'
      OrderCategory            as OrderCategory,
      @ObjectModel.foreignKey.association: '_OrderType'
      OrderType                as OrderType,
      Plant,
      _CompanyCode,
      _OrderCategory,
      _OrderType
}