P_EnterpriseProjectForSearch

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@EndUserText.label: 'Enterprise Search for Enterprise Project'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XL,
  dataClass: #MASTER
}
@VDM.private: true
@VDM.viewType: #BASIC
define view entity P_EnterpriseProjectForSearch
  as select from /s4ppm/project as project
    inner join   /s4ppm/task    as task on  task.project_guid = project.guid
                                        and task.object_type  = 'DPO'
    inner join   proj           as proj on proj.pspnr = project.pspnr
    inner join   prps           as prps on prps.pspnr = task.pspnr
  association [0..*] to P_EnterpriseProjectResponsible as _EnterpriseProjectResponsible on  $projection.ProjectSummaryTaskUUID = _EnterpriseProjectResponsible.ReferencedObjectUUID
  association [0..1] to I_CompanyCode                  as _CompanyCode                  on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..*] to I_EntProjProcessingStatusText  as _ProcessingStatusText         on  $projection.ProcessingStatus = _ProcessingStatusText.ProcessingStatus
  association [0..*] to I_ProjectProfileCodeText       as _ProjectProfileText           on  $projection.ProjectProfileCode = _ProjectProfileText.ProjectProfileCode
  association [0..*] to I_CostCenterText               as _CostCenter                   on  $projection.ResponsibleCostCenter = _CostCenter.CostCenter
                                                                                        and $projection.ControllingArea       = _CostCenter.ControllingArea
  association [0..*] to I_ProfitCenterText             as _profitCenter                 on  $projection.ProfitCenter    = _profitCenter.ProfitCenter
                                                                                        and $projection.ControllingArea = _profitCenter.ControllingArea
  association [0..*] to I_PPM_PriorityText             as _PriorityText                 on  $projection.PriorityCode = _PriorityText.PriorityCode
  association [0..*] to I_Projecttypetext              as _EnterpriseProjectTypeText    on  _EnterpriseProjectTypeText.ProjectType = $projection.EnterpriseProjectType
  association [0..*] to I_FunctionalAreaText           as _FunctionalAreaText           on  $projection.FunctionalArea = _FunctionalAreaText.FunctionalArea
  association [1]    to R_AccControlIsUserAuthorized   as _EnterpriseProjectAuthUser    on  _EnterpriseProjectAuthUser.AccCtrlReferencedObjectUUID = project.guid and
                                                                                            _EnterpriseProjectAuthUser.UserID = $session.user                     and
                                                                                            _EnterpriseProjectAuthUser.AccessControlRestrictionCode = 'READ'
{
  key project.guid                                                   as ProjectUUID,
      cast ( project.pspnr as ps_s4_proj_pspnr preserving type )     as ProjectInternalID,
      @Consumption.hidden: true
      project.pro_category                                           as ProjectCategory,
      prps.prart                                                     as EnterpriseProjectType,
      proj.profl                                                     as ProjectProfileCode,
      task.guid                                                      as ProjectSummaryTaskUUID,
      @ObjectModel.text.element: ['ProjectDescription']
      cast ( task.external_id as /s4ppm/project_id preserving type ) as Project,
      @Semantics.text: true
      task.name                                                      as ProjectDescription,
      task.proc_status_own                                           as ProcessingStatus,
      task.planstart_date                                            as PlannedStartDate,
      task.planfinish_date                                           as PlannedEndDate,
      task.actualstart_date                                          as ActualStartDate,
      task.actualfinish_date                                         as ActualFinishDate,
      task.priority                                                  as PriorityCode,
      proj.vbukr                                                     as CompanyCode,
      proj.vkokr                                                     as ControllingArea,
      proj.func_area                                                 as FunctionalArea,
      proj.werks                                                     as Plant,
      proj.prctr                                                     as ProfitCenter,
      prps.fkstl                                                     as ResponsibleCostCenter,
      _EnterpriseProjectResponsible.PersonFullName                   as ProjectManager,
      _EnterpriseProjectResponsible.IsBusinessPurposeCompleted,
      _EnterpriseProjectResponsible.AuthorizationGroup,
      _EnterpriseProjectResponsible.DataControllerSet,
      _EnterpriseProjectResponsible.DataController1,
      _EnterpriseProjectResponsible.DataController2,
      _EnterpriseProjectResponsible.DataController3,
      _EnterpriseProjectResponsible.DataController4,
      _EnterpriseProjectResponsible.DataController5,
      _EnterpriseProjectResponsible.DataController6,
      _EnterpriseProjectResponsible.DataController7,
      _EnterpriseProjectResponsible.DataController8,
      _EnterpriseProjectResponsible.DataController9,
      _EnterpriseProjectResponsible.DataController10,
      _EnterpriseProjectAuthUser.UserID,
      
      _CompanyCode,
      _ProcessingStatusText,
      _ProjectProfileText,
      _CostCenter,
      _profitCenter,
      _PriorityText,
      _EnterpriseProjectTypeText,
      _FunctionalAreaText,
      _EnterpriseProjectResponsible
}