P_CABusinessPartnerWithVAT

DDL: P_CABUSINESSPARTNERWITHVAT Type: view_entity COMPOSITE Package: FKK_ID_NO_SAFT

Distinct BP with address and tax number

P_CABusinessPartnerWithVAT is a Composite CDS View that provides data about "Distinct BP with address and tax number" in SAP S/4HANA. It reads from 2 data sources (I_BusinessPartner, P_CABusinessPartnerFrmLineItm) and exposes 19 fields with key field BusinessPartner. Part of development package FKK_ID_NO_SAFT.

2 data source(s) 19 fields

Data Sources (2)

SourceAliasJoin Type
I_BusinessPartner BP inner
P_CABusinessPartnerFrmLineItm P_CABusinessPartnerFrmLineItm from

Parameters (6)

NameTypeDefault
P_FromPostingDate fis_budat_from
P_ToPostingDate fis_budat_to
P_FromFiscalPeriod fis_period_from
P_ToFiscalPeriod fis_period_to
P_FiscalYear fis_gjahr
P_CompanyCode bukrs

Annotations (8)

NameValueLevelField
VDM.private true view
VDM.viewType #COMPOSITE view
AccessControl.authorizationCheck #NOT_REQUIRED view
AccessControl.personalData.blocking #BLOCKED_DATA_INCLUDED view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #XXL view
ObjectModel.usageType.dataClass #MIXED view

Fields (19)

KeyFieldSource TableSource FieldDescription
KEY BusinessPartner FICABP BusinessPartner
Customer FICABP BusinessPartner
NO_SAFTCustomerID
CompanyCode FICABP CompanyCode
ChartOfAccounts FICABP ChartOfAccounts
BPTaxNumber BPTax BPTaxNumber
BPTaxNumberelseendasNO2TaxNumber
BPTaxNumberelseendasNO1TaxNumber
BPTaxNumberelseendasBP0TaxNumber
BusinessPartnerUUID I_BusinessPartner BusinessPartnerUUID
AddressID
BPCustomerName I_BusinessPartner BusinessPartnerName
StreetName
HouseNumber
CityName
PostalCode
Country
Region
RegionNameasRegionName 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@VDM.private: true
@VDM.viewType: #COMPOSITE

@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XXL,
  dataClass: #MIXED
}

define view entity P_CABusinessPartnerWithVAT
  with parameters
    P_FromPostingDate  : fis_budat_from,
    P_ToPostingDate    : fis_budat_to,
    P_FromFiscalPeriod : fis_period_from,
    P_ToFiscalPeriod   : fis_period_to,
    P_FiscalYear       : fis_gjahr,
    P_CompanyCode      : bukrs
  as select from            P_CABusinessPartnerFrmLineItm(
                                       P_FromPostingDate:  $parameters.P_FromPostingDate,
                                       P_ToPostingDate:    $parameters.P_ToPostingDate,
                                       P_FromFiscalPeriod: $parameters.P_FromFiscalPeriod,
                                       P_ToFiscalPeriod :  $parameters.P_ToFiscalPeriod,
                                       P_FiscalYear:       $parameters.P_FiscalYear,
                                       P_CompanyCode:      $parameters.P_CompanyCode ) as FICABP
    inner join              I_BusinessPartner                                          as BP    on FICABP.BusinessPartner = BP.BusinessPartner
    left outer to many join I_Businesspartnertaxnumber                                 as BPTax on BPTax.BusinessPartner = FICABP.BusinessPartner
                                                                                                and(
                                                                                                  BPTax.BPTaxType        = concat(
                                                                                                    (
                                                                                                      substring(
                                                                                                        BPTax.BPTaxType, 1, 2
                                                                                                      )
                                                                                                    ), '0'
                                                                                                  )
                                                                                                  or BPTax.BPTaxType     = 'NO1'
                                                                                                  or BPTax.BPTaxType     = 'NO2'
                                                                                                )



{

  key  FICABP.BusinessPartner                                                   as BusinessPartner,
       FICABP.BusinessPartner                                                   as Customer,
       cast( concat( 'CA_', FICABP.BusinessPartner ) as  saftn_no_customer_id ) as NO_SAFTCustomerID,
       FICABP.CompanyCode,
       FICABP.ChartOfAccounts,

       BPTax.BPTaxNumber                                                        as BPTaxNumber,

       case
        when  BPTax.BPTaxType = 'NO2'
                 then BPTax.BPTaxNumber
        else ''
        end                                                                     as NO2TaxNumber,

       case
        when BPTax.BPTaxType = 'NO1'
          then BPTax.BPTaxNumber
        else ''
       end                                                                      as NO1TaxNumber,

       case
        when BPTax.BPTaxType = concat( substring( BPTax.BPTaxNumber, 1, 2 ) , '0' )
          then BPTax.BPTaxNumber
        else ''
       end                                                                      as BP0TaxNumber,
       BP.BusinessPartnerUUID                                                   as BusinessPartnerUUID,
       BP._CurrentDefaultAddress.AddressID,
       BP.BusinessPartnerName                                                   as BPCustomerName,
       BP._CurrentDefaultAddress._AddressDefaultRepresentation.StreetName       as StreetName,
       BP._CurrentDefaultAddress._AddressDefaultRepresentation.HouseNumber      as HouseNumber,
       BP._CurrentDefaultAddress._AddressDefaultRepresentation.CityName         as CityName,
       BP._CurrentDefaultAddress._AddressDefaultRepresentation.PostalCode       as PostalCode,
       BP._CurrentDefaultAddress._AddressDefaultRepresentation.Country          as Country,
       BP._CurrentDefaultAddress._AddressDefaultRepresentation._Region.Region   as Region,
       BP._CurrentDefaultAddress._AddressDefaultRepresentation._Region.
       _RegionText[1:Language=$session.system_language].RegionName              as RegionName,
       case
         when BP._CurrentDefaultAddress._AddressDefaultRepresentation.POBox is not initial
          then 'PostalAddress'
        else 'StreetAddress'
       end                                                                      as AddressTypeDesc

}

Learn More