P_CABUSINESSPARTNERFRMLINEITM

CDS View

Distinct BP from BP lineitems

P_CABUSINESSPARTNERFRMLINEITM is a CDS View in S/4HANA. Distinct BP from BP lineitems. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_CABusinessPartnerWithVAT view_entity from COMPOSITE Distinct BP with address and tax number 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@VDM.private: true
@VDM.viewType: #COMPOSITE

@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@AccessControl.authorizationCheck: #NOT_REQUIRED

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType:{
  serviceQuality: #A,
  sizeCategory: #XXL,
  dataClass: #TRANSACTIONAL
}

// BPS with transactions for the given period

define view entity P_CABusinessPartnerFrmLineItm
  with parameters
    P_FromPostingDate  : fis_budat_from,
    P_ToPostingDate    : fis_budat_to,
    P_FromFiscalPeriod : fis_period_from,
    P_ToFiscalPeriod   : fis_period_to,
    P_FiscalYear       : fis_gjahr,
    P_CompanyCode      : bukrs
  as select distinct from P_ContrAcctgBPItmPostdClrdRvsd(
                            P_fromPostingDate: $parameters.P_FromPostingDate,
                            P_toPostingDate:   $parameters.P_ToPostingDate,
                            P_CompanyCode:     $parameters.P_CompanyCode
                            )
{

  key BusinessPartner,
      CompanyCode,
      ChartOfAccounts                     as ChartOfAccounts,
      CompanyCodeCurrency,
      @Semantics: { amount : { currencyCode: 'CompanyCodeCurrency' } }
      cast( '0.00' as fis_start_bal_hsl ) as StartingBalanceAmtInCoCodeCrcy,
      @Semantics: { amount : { currencyCode: 'CompanyCodeCurrency' } }
      cast( '0.00' as fis_start_bal_hsl ) as EndingBalanceAmtInCoCodeCrcy
}
where
      CAPostingDate between $parameters.P_FromPostingDate and $parameters.P_ToPostingDate
  and CompanyCode   = $parameters.P_CompanyCode

//BPs which have opening balance but has no transaction for the given period

union all select from I_CABusinessPartnerBalAccount(
                                           P_FromPostingDate:  $parameters.P_FromPostingDate,
                                           P_ToPostingDate:    $parameters.P_ToPostingDate,
                                           P_FromFiscalPeriod: $parameters.P_FromFiscalPeriod,
                                           P_ToFiscalPeriod :  $parameters.P_ToFiscalPeriod,
                                           P_FiscalYear:       $parameters.P_FiscalYear,
                                           P_CompanyCode:      $parameters.P_CompanyCode )

{

  key Partner                               as BusinessPartner,
      CompanyCode,
      ChartOfAccounts,
      CompanyCodeCurrency,
      sum( StartingBalanceAmtInCoCodeCrcy ) as StartingBalanceAmtInCoCodeCrcy,
      sum( EndingBalanceAmtInCoCodeCrcy )   as EndingBalanceAmtInCoCodeCrcy
}
where
        not(
          StartingBalanceAmtInCoCodeCrcy   = 0
          and EndingBalanceAmtInCoCodeCrcy = 0
        )
  and   StartingBalanceAmtInCoCodeCrcy     = EndingBalanceAmtInCoCodeCrcy

group by
  Partner,
  CompanyCode,
  ChartOfAccounts,
  CompanyCodeCurrency

Learn More