P_BillingDocProcFlowC10

@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'PBILLGDOPROCFC10'

@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType: { dataClass: #MIXED, serviceQuality: #C, sizeCategory: #XL }

@VDM.private: true
@VDM.viewType: #CONSUMPTION

define view P_BillingDocProcFlowC10
  as select from           P_BillingDocProcFlowC0  as Level0  -- > Level 0

    inner join             I_SDDocumentProcessFlow as Level1  -- > Level 1
      on  Level0.LevelC0Document         = Level1.PrecedingDocument
      and Level0.LevelC0DocumentItem     = Level1.PrecedingDocumentItem
      and Level0.LevelC0DocumentItem     = Level1.PrecedingDocumentItem
      and Level0.LevelC0DocumentCategory = Level1.PrecedingDocumentCategory
      and (Level1.SubsequentDocumentCategory = 'O' or   -- > Credit Memo
           Level1.SubsequentDocumentCategory = 'P' or   -- > Debit Memo
           Level1.SubsequentDocumentCategory = 'K' or   -- > Credit Memo Request  
           Level1.SubsequentDocumentCategory = 'L' or   -- > Debit Memo Request  
           Level1.SubsequentDocumentCategory = 'H' or   -- > Returns        
           Level1.SubsequentDocumentCategory = '6' or   -- > Intercompany Credit Memo
           Level1.SubsequentDocumentCategory = 'N' or   -- > Invoice Cancellatiom
           Level1.SubsequentDocumentCategory = 'S' or   -- > Credit Memo Cancellation     
           Level1.SubsequentDocumentCategory = 'DPCC'   -- > Down Payment Cancellation     
         )

    left outer to one join I_SalesDocumentBasic    as SalesDocument
      on Level1.SubsequentDocument = SalesDocument.SalesDocument

    left outer to one join I_BillingDocument       as BillingDocument
      on Level1.SubsequentDocument = BillingDocument.BillingDocument

{
      // Key

  key Level0.LevelC0Document         as LevelC0Document,
  key Level0.LevelC0DocumentItem     as LevelC0DocumentItem,
  key Level0.LevelC0DocumentCategory as LevelC0DocumentCategory,
  key Level1.SubsequentDocument      as Level1Document,
  key Level1.SubsequentDocumentItem  as Level1DocumentItem,

  key
   // Category 

      case when
           ((Level1.SubsequentDocumentCategory = 'K' or   -- > Credit Memo Request  
             Level1.SubsequentDocumentCategory = 'L') and   -- > Debit Memo Request
             SalesDocument.SDDocumentCategory is not null)   -- > not archived  
       then SalesDocument.SDDocumentCategory    -- > from header for mixed documents
       when
            ((Level1.SubsequentDocumentCategory = 'O' or   -- > Credit Memo  
              Level1.SubsequentDocumentCategory = 'P') and -- > Debit Memo 
              BillingDocument.SDDocumentCategory is not null)
        then BillingDocument.SDDocumentCategory    -- > from header for mixed documents                 
       else Level1.SubsequentDocumentCategory
      end                            as   Level1DocumentCategory,

  key Level0.BillingDocument,

      Level0.BillingDocumentType,
      Level0.SDDocumentCategory,

      // Organizatio

      Level0.SalesOrganization
}