P_BillingDocProcFlowC0

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

@VDM.private: true
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.sqlViewName: 'PBILLGDOCPROCFC0'
@AbapCatalog.preserveKey:true

 // This view reads additional biiling docs in case the focus document

 // was cancelled or a cancellation document exits

 // Only Documents of teh same VBTYP and in case of biiliong plan for

 // the same billing plan item will be read

 
define view P_BillingDocProcFlowC0
  as select distinct from P_BillingDocProcFlowM1 as LevelM1  --> Level -1
  inner join I_SDDocumentProcessFlow        as Level0         --> Level 0
on  LevelM1.LevelM1Document         = Level0.PrecedingDocument   
and LevelM1.LevelM1DocumentItem     = Level0.PrecedingDocumentItem
and LevelM1.LevelM1DocumentCategory = Level0.PrecedingDocumentCategory
and LevelM1.SDDocumentCategory      = Level0.SubsequentDocumentCategory
and LevelM1.BillingDocument        != Level0.SubsequentDocument
and LevelM1.BillingPlan             = Level0.BillingPlan 
and LevelM1.BillingPlanItem         = Level0.BillingPlanItem
{
      //Key

  key Level0.PrecedingDocument           as LevelM1Document,  
  key Level0.PrecedingDocumentItem       as LevelM1DocumentItem,      
  key Level0.PrecedingDocumentCategory   as LevelM1DocumentCategory,             
  key Level0.SubsequentDocument          as LevelC0Document,
  key Level0.SubsequentDocumentItem      as LevelC0DocumentItem,
  key Level0.SubsequentDocumentCategory  as LevelC0DocumentCategory, 

      //Billing Document

  key LevelM1.BillingDocument,
      BillingDocumentType,
      LevelM1.SDDocumentCategory,
      
      LevelM1.BillingPlan,
      LevelM1.BillingPlanItem,

      //Organization

      SalesOrganization
}